build.gradle

import groovy.swing.SwingBuilder

repositories {
    mavenCentral()
}

configurations {
    sshAntTask
}

dependencies {
    sshAntTask "org.apache.ant:ant-jsch:1.9.3"
    sshAntTask "jsch:jsch:0.1.29"
}

buildscript {

    repositories {
        mavenCentral()
    }

    dependencies {
        classpath "org.apache.ant:ant-jsch:1.9.3"
    }
}

task update {
    def user = System.getenv("USER")
    def home = System.getenv("HOME")
    def folder = "/usr/share/nginx/www/homepage"
    description = "Update files on remote server as $user."

    // Redefine scp Ant task, with the classpath property set to our newly defined
    // sshAntTask configuration classpath.
    ant.taskdef(name: 'scp', classname: 'org.apache.tools.ant.taskdefs.optional.ssh.Scp',
            classpath: configurations.sshAntTask.asPath)

    doLast {
        def console = System.console()
        def passphrase = ''
        if (console) {
            passphrase = console.readPassword("%s: ", "Please enter passphrase for the key file ($home/.ssh/id_rsa)")
        } else {
            new SwingBuilder().edt{
                dialog(modal: true,
                title: 'Enter password',
                alwaysOnTop: true,
                resizable: false,
                locationRelativeTo: null,
                pack: true,
                show: true){
                    vbox {
                        label(text: 'Please enter key passphrase:')
                        input = passwordField()
                        button(defaultButton: true, text: 'OK', actionPerformed: {
                            passphrase = input.password;
                            dispose();
                        })
                    }
                }
            }
        }


        // Invoke the scp Ant task. (Use gradle -i update to see the output of the Ant task.)
        ant.scp(todir: "$user@jackivy.com:$folder",
                keyfile: "$home/.ssh/id_rsa",
                passphrase: passphrase as String, // Use phassphrase entered by the user.
                verbose: 'true') {
            fileset(dir: 'web') {
                include(name: '**/**')
            }
        }
    }
}