-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathqf.ijs
1373 lines (1312 loc) · 45.9 KB
/
qf.ijs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
NB. Orthogonal factorization
NB.
NB. gelqf LQ factorization of a general matrix
NB. geqlf QL factorization of a general matrix
NB. geqrf QR factorization of a general matrix
NB. gerqf RQ factorization of a general matrix
NB.
NB. tzlzf LZ factorization of a trapezoidal matrix
NB. tzzlf ZL factorization of a trapezoidal matrix
NB. tzzrf ZR factorization of a trapezoidal matrix
NB. tzrzf RZ factorization of a trapezoidal matrix
NB.
NB. testgeqf Test gexxf by general matrix
NB. testtzqf Test tzxxf by trapezoidal matrix
NB. testqf Adv. to make verb to test gexxf and tzxxf by
NB. matrix of generator and shape given
NB.
NB. Copyright 2010,2011,2013,2017,2018,2020,2021,2023,2024,
NB. 2025 Igor Zhuravlov
NB.
NB. This file is part of mt
NB.
NB. mt is free software: you can redistribute it and/or
NB. modify it under the terms of the GNU Lesser General
NB. Public License as published by the Free Software
NB. Foundation, either version 3 of the License, or (at your
NB. option) any later version.
NB.
NB. mt is distributed in the hope that it will be useful, but
NB. WITHOUT ANY WARRANTY; without even the implied warranty
NB. of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
NB. See the GNU Lesser General Public License for more
NB. details.
NB.
NB. You should have received a copy of the GNU Lesser General
NB. Public License along with mt. If not, see
NB. <http://www.gnu.org/licenses/>.
NB. =========================================================
NB. Configuration
coclass 'mt'
NB. =========================================================
NB. Local definitions
NB. ---------------------------------------------------------
NB. Blocked code constants
QFNB=: 32 NB. block size limit
QFNX=: 128 NB. crossover point, QFNX ≥ QFNB
NB. ---------------------------------------------------------
NB. gelq2
NB.
NB. Description:
NB. LQ-factorization of the augmented input matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. LQf=. gelq2 eA
NB. where
NB. eA - m×(n+1)-matrix, being A augmented by trash
NB. vector:
NB. eA -: A ,. Trash
NB. A - m×n-matrix, the input to factorize
NB. Trash - m-vector, will be replaced by Tau
NB. LQf - m×(n+1)-matrix, L and Qf combined
NB. L - m×k-matrix, the lower trapezoidal
NB. Qf - k×(n+1)-matrix, the unit upper trapezoidal
NB. (unit diagonal is not stored), represents the Q
NB. in factored form
NB. Q - n×n-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary
NB. reflectors H(i) of order n:
NB. Q = Π{H(i)',i=k-1:0}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i)' * τ(i) * u(i)
NB. k = min(m,n)
NB.
NB. Storage layout for m=3, n=7:
NB. LQf:
NB. ( l v0 v0 v0 v0 v0 v0 τ0 )
NB. ( l l v1 v1 v1 v1 v1 τ1 )
NB. ( l l l v2 v2 v2 v2 τ2 )
NB. L:
NB. ( l 0 0 )
NB. ( l l 0 )
NB. ( l l l )
NB. Qf:
NB. ( 1 v0 v0 v0 v0 v0 v0 τ0 )
NB. ( 0 1 v1 v1 v1 v1 v1 τ1 )
NB. ( 0 0 1 v2 v2 v2 v2 τ2 )
NB. where
NB. l - elements of L
NB. vi - vector v(i)
NB. τi - scalar value conj(τ(i))
NB. (0,...,0,1,vi) - n-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = L * Q
NB. (}:"1 -: ( trl @:(}:"1) mp unglq)@gelq2) eA
NB. NB. A = L * (Q)
NB. (}:"1 -: (unmlqrn trlpick @:(}:"1))@gelq2) eA
NB.
NB. Notes:
NB. - models LAPACK's xGELQ2
NB. - gelq2 and gelqf are topologic equivalents
NB. - if L diagonal's non-negativity is required, then
NB. larfgfc would be replaced by larfpfc
gelq2=: 3 : 0
'pfx sfxT'=. 0 ({."1 ; {.) y
while. -. (0 e. 0 _1 + $) y do.
z=. larfgfc {. y
sfxT=. sfxT , z
y=. ((1) 0} z) larfrnfr }. y
pfx=. pfx ,. sfxT (,&:({."1)) y
sfxT=. (}."1) sfxT
y=. (}."1) y
end.
pfx stitcht sfxT
)
NB. ---------------------------------------------------------
NB. geql2
NB.
NB. Description:
NB. QL-factorization of the augmented input matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. QfL=. geql2 eA
NB. where
NB. eA - (m+1)×n-matrix, being A augmented by trash
NB. vector:
NB. eA -: Trash , A
NB. Trash - n-vector, will be replaced by Tau
NB. A - m×n-matrix, the input to factorize
NB. QfL - (m+1)×n-matrix, Qf and L combined
NB. Qf - (m+1)×k-matrix, the unit upper trapezoidal
NB. (unit diagonal is not stored), represents the Q
NB. in factored form
NB. L - k×n-matrix, the lower trapezoidal
NB. Q - m×m-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary
NB. reflectors H(i) of order m:
NB. Q = Π{H(i),i=k-1:0}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i) * τ(i) * u(i)'
NB. k = min(m,n)
NB.
NB. Storage layout for m=7, n=3:
NB. QfL: Qf: L:
NB. ( τ0 τ1 τ2 ) ( τ0 τ1 τ2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( l v1 v2 ) ( 1 v1 v2 ) ( l 0 0 )
NB. ( l l v2 ) ( 0 1 v2 ) ( l l 0 )
NB. ( l l l ) ( 0 0 1 ) ( l l l )
NB. where
NB. l - elements of L
NB. vi - vector v(i)
NB. τi - scalar value τ(i)
NB. (vi,1,0,...,0) - m-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = Q * L
NB. (}. -: (ungql mp (trl~ -~/@$)@: }. )@geql2) eA
NB. NB. A = (Q) * L
NB. (}. -: (unmqlln (trlpick~ -~/@$)@ }. )@geql2) eA
NB.
NB. Notes:
NB. - models LAPACK's xGEQL2
NB. - geql2 and geqlf are topologic equivalents
NB. - if L diagonal's non-negativity is required, then larfgb
NB. would be replaced by larfpb
geql2=: 3 : 0
'pfxR sfx'=. 0 ({."1 ; {.) y
while. -. (0 e. _1 0 + $) y do.
z=. larfgb ({:"1) y
pfxR=. z ,. pfxR
y=. ((1) _1} z) larflcbc (}:"1) y
sfx=. sfx ,~ y (,&{:) pfxR
y=. }: y
pfxR=. }: pfxR
end.
pfxR appendr sfx
)
NB. ---------------------------------------------------------
NB. geqr2
NB.
NB. Description:
NB. QR-factorization of the augmented input matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. QfR=. geqr2 eA
NB. where
NB. eA - (m+1)×n-matrix, being A augmented by trash
NB. vector:
NB. eA -: A , Trash
NB. A - m×n-matrix, the input to factorize
NB. Trash - n-vector, will be replaced by Tau
NB. QfR - (m+1)×n-matrix, Qf and R combined
NB. Qf - (m+1)×k-matrix, the unit lower trapezoidal
NB. (unit diagonal is not stored), represents the Q
NB. in factored form
NB. R - k×n-matrix, the upper trapezoidal
NB. Q - m×m-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary
NB. reflectors H(i) of order m:
NB. Q = Π{H(i),i=0:k-1}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i) * τ(i) * u(i)'
NB. k = min(m,n)
NB.
NB. Storage layout for m=7, n=3:
NB. QfR: Qf: R:
NB. ( r r r ) ( 1 0 0 ) ( r r r )
NB. ( v0 r r ) ( v0 1 0 ) ( 0 r r )
NB. ( v0 v1 r ) ( v0 v1 1 ) ( 0 0 r )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( τ0 τ1 τ2 ) ( τ0 τ1 τ2 )
NB. where
NB. r - elements of R
NB. vi - vector v(i)
NB. τi - scalar value τ(i)
NB. (0,...,0,1,vi) - m-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = Q * R
NB. (}: -: (ungqr mp tru @: }: )@geqr2) eA
NB. NB. A = (Q) * R
NB. (}: -: (unmqrln trupick @ }: )@geqr2) eA
NB.
NB. Notes:
NB. - models LAPACK's xGEQR2
NB. - geqr2 and geqrf are topologic equivalents
NB. - if R diagonal's non-negativity is required, then larfgf
NB. would be replaced by larfpf
geqr2=: 3 : 0
'pfx sfxL'=. 0 ({. ; {."1) y
while. -. (0 e. _1 0 + $) y do.
z=. larfgf ({."1) y
sfxL=. sfxL ,. z
y=. ((1) 0} z) larflcfc }."1 y
pfx=. pfx , sfxL (,&{.) y
sfxL=. }. sfxL
y=. }. y
end.
pfx , sfxL
)
NB. ---------------------------------------------------------
NB. gerq2
NB.
NB. Description:
NB. RQ-factorization of the augmented input matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. RQf=. gerq2 eA
NB. where
NB. eA - m×(n+1)-matrix, being A augmented by trash
NB. vector:
NB. eA -: Trash ,. A
NB. Trash - m-vector, will be replaced by Tau
NB. A - m×n-matrix, the input to factorize
NB. RQf - m×(n+1)-matrix, R and Qf combined
NB. R - m×k-matrix, the upper trapezoidal
NB. Qf - k×(n+1)-matrix, the unit lower trapezoidal
NB. (unit diagonal is not stored), represents the Q
NB. in factored form
NB. Q - n×n-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary
NB. reflectors H(i) of order n:
NB. Q = Π{H(i)',i=0:k-1}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i)' * τ(i) * u(i)
NB. k = min(m,n)
NB.
NB. Storage layout for m=3, n=7:
NB. RQf:
NB. ( τ0 v0 v0 v0 v0 r r r )
NB. ( τ1 v1 v1 v1 v1 v1 r r )
NB. ( τ2 v2 v2 v2 v2 v2 v2 r )
NB. R:
NB. ( r r r )
NB. ( 0 r r )
NB. ( 0 0 r )
NB. Qf:
NB. ( τ0 v0 v0 v0 v0 1 0 0 )
NB. ( τ1 v1 v1 v1 v1 v1 1 0 )
NB. ( τ2 v2 v2 v2 v2 v2 v2 1 )
NB. where
NB. r - elements of R
NB. vi - vector v(i)
NB. τi - scalar value conj(τ(i))
NB. (vi,1,0,...,0) - n-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = R * Q
NB. (}."1 -: ((tru~ -~/@$)@:(}."1) mp ungrq)@gerq2) eA
NB. NB. A = R * (Q)
NB. (}."1 -: (unmrqrn (trupick~ -~/@$)@:(}."1))@gerq2) eA
NB.
NB. Notes:
NB. - models LAPACK's xGERQ2
NB. - gerq2 and gerqf are topologic equivalents
NB. - if R diagonal's non-negativity is required, then
NB. larfgbc would be replaced by larfpbc
gerq2=: 3 : 0
'pfxB sfx'=. 0 ({. ; {."1) y
while. -. (0 e. 0 _1 + $) y do.
z=. larfgbc {: y
pfxB=. z , pfxB
y=. ((1) _1} z) larfrnbr }: y
sfx=. sfx ,.~ y (,&:({:"1)) pfxB
y=. (}:"1) y
pfxB=. (}:"1) pfxB
end.
pfxB stitchb sfx
)
NB. ---------------------------------------------------------
NB. latlz
NB.
NB. Description:
NB. LZ-factorization of the augmented trapezoidal matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. LZf=. l latlz eA
NB. where
NB. eA - m×(n+1)-matrix, being A augmented by trash
NB. vector:
NB. eA -: Trash ,. iA1 ,. A2 ,. iL
NB. Trash - m-vector, will be replaced by Tau
NB. iA1 - m×(l-1)-matrix, part to be replaced by Zf
NB. A2 - m×(n-m-l+1)-matrix, is not changed
NB. iL - m×m-matrix, the lower triangular
NB. LZf - m×(n+1)-matrix, the unit lower trapezoidal Zf
NB. and the lower trapezoidal L combined:
NB. LZf -: Tau ,. oA1 ,. A2 ,. oL
NB. Tau - m-vector, scalars τ[0:m-1] for Zf
NB. oA1 - m×(l-1)-matrix, rows are vectors v[0:m-1] for
NB. Zf
NB. oL - m×m-matrix, the lower triangular
NB. Zf - m×(n+1)-matrix, the Z represented in factored
NB. form
NB. Z - n×n-matrix, the unitary (orthogonal), which is
NB. defined as the product of m elementary
NB. reflectors H(i) of order n:
NB. Q = Π{H(i)',i=m-1:0}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i)' * τ(i) * u(i)
NB. m ≤ n
NB.
NB. Storage layout for m=3, n=9, l=5:
NB. eA:
NB. ( * a1 a1 a1 a1 a2 a2 il 0 0 )
NB. ( * a1 a1 a1 a1 a2 a2 il li 0 )
NB. ( * a1 a1 a1 a1 a2 a2 il il il )
NB. LZf:
NB. ( τ0 v0 v0 v0 v0 a2 a2 ol 0 0 )
NB. ( τ1 v1 v1 v1 v1 a2 a2 ol ol 0 )
NB. ( τ2 v2 v2 v2 v2 a2 a2 ol ol ol )
NB. L:
NB. ( 0 0 0 0 a2 a2 ol 0 0 )
NB. ( 0 0 0 0 a2 a2 ol ol 0 )
NB. ( 0 0 0 0 a2 a2 ol ol ol )
NB. Zf:
NB. ( τ0 v0 v0 v0 v0 0 0 1 0 0 )
NB. ( τ1 v1 v1 v1 v1 0 0 0 1 0 )
NB. ( τ2 v2 v2 v2 v2 0 0 0 0 1 )
NB. where
NB. * - any scalar value, is not used
NB. a1 - elements of iA1
NB. a2 - elements of A2
NB. il - elements of iL
NB. ol - elements of oL
NB. vi - l-vector v(i)
NB. τi - scalar value conj(τ(i))
NB. (vi,0,...,0,1,0,...,0) - n-vector u(i)
NB.
NB. Notes:
NB. - latlz and tzlzf are topologic equivalents
NB. - in u(i) 0s and 1 are not stored, v(i) is empty for l=0,
NB. 0s and 1 are absent and u(i) is empty when n=0
latlz=: 4 : 0
iso=. < < < (liso4dhs 0 , x) , _1
m=. # y
'sfxR y'=. (- m) ({."1 ; }."1) y
pfx=. 0 {. y
while. # y do.
y=. y (,. {."1) sfxR
sfxR=. 1 1 }. sfxR
z=. {. y
bak=. iso { z
z=. larfgbc 0 iso} z
y=. ((1) _1} z) larzrnfr }. y
pfx=. (pfx ,. 0) , bak iso} z
end.
pfx
)
NB. ---------------------------------------------------------
NB. latzl
NB.
NB. Description:
NB. ZL-factorization of the augmented trapezoidal matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. ZfL=. l latzl eA
NB. where
NB. eA - (m+1)×n-matrix, being A augmented by trash
NB. vector:
NB. eA -: iL , A1 , iA2 , Trash
NB. iL - n×n-matrix, the lower triangular
NB. A1 - (m-n-l+1)×n-matrix, is not changed
NB. iA2 - (l-1)×n-matrix, part to be replaced by Zf
NB. Trash - n-vector, will be replaced by Tau
NB. ZfL - (m+1)×n-matrix, the lower trapezoidal L and the
NB. unit lower trapezoidal Zf combined:
NB. ZfL -: oL , A1 , oA2 , Tau
NB. oL - n×n-matrix, the lower triangular
NB. oA2 - (l-1)×n-matrix, columns are vectors v[0:n-1]
NB. for Zf
NB. Tau - n-vector, scalars τ[0:n-1] for Zf
NB. Zf - (m+1)×n-matrix, the Z represented in factored
NB. form
NB. Z - m×m-matrix, the unitary (orthogonal), which is
NB. defined as the product of n elementary
NB. reflectors H(i) of order m:
NB. Z = Π{H(i),i=n-1:0}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i) * τ(i) * u(i)'
NB. m ≥ n
NB.
NB. Storage layout for m=9, n=3, l=5:
NB. eA: ZfL: Zf: L:
NB. ( il 0 0 ) ( ol 0 0 ) ( 1 0 0 ) ( ol 0 0 )
NB. ( il il 0 ) ( ol ol 0 ) ( 0 1 0 ) ( ol ol 0 )
NB. ( il il il ) ( ol ol ol ) ( 0 0 1 ) ( ol ol ol )
NB. ( a1 a1 a1 ) ( a1 a1 a1 ) ( 0 0 0 ) ( a1 a1 a1 )
NB. ( a1 a1 a1 ) ( a1 a1 a1 ) ( 0 0 0 ) ( a1 a1 a1 )
NB. ( a2 a2 a2 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( a2 a2 a2 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( a2 a2 a2 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( a2 a2 a2 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( * * * ) ( τ0 τ1 τ2 ) ( τ0 τ1 τ2 )
NB. where
NB. il - elements of iL
NB. a1 - elements of A1
NB. a2 - elements of iA2
NB. * - any scalar value, is not used
NB. ol - elements of oL
NB. vi - l-vector v(i)
NB. τi - scalar value τ(i)
NB. (0,...,0,1,0,...,0,vi) - m-vector u(i)
NB. elementary re
NB.
NB. Notes:
NB. - latzl and tzzlf are topologic equivalents
NB. - in u(i) 0s and 1 are not stored, v(i) is empty for l=0,
NB. 0s and 1 are absent and u(i) is empty when n=0
latzl=: 4 : 0
iso=. < < < 0 , liso4dhs _1 , x
n=. c y
'pfxT y'=. n ({. ; }.) y
sfx=. 0 ({."1) y
while. c y do.
y=. ({: pfxT) , y
pfxT=. _1 _1 }. pfxT
z=. ({:"1) y
bak=. iso { z
z=. larfgf 0 iso} z
y=. ((1) 0} z) larzlcbc (}:"1) y
sfx=. (bak iso} z) ,. 0 , sfx
end.
sfx
)
NB. ---------------------------------------------------------
NB. latzr
NB.
NB. Description:
NB. ZR-factorization of the augmented trapezoidal matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. ZfR=. l latzr eA
NB. where
NB. eA - (m+1)×n-matrix, being A augmented by trash
NB. vector:
NB. eA -: Trash , iA1 , A2 , iR
NB. Trash - n-vector, will be replaced by Tau
NB. iA1 - (l-1)×n-matrix, part to be replaced by Zf
NB. A2 - (m-n-l+1)×n-matrix, is not changed
NB. iR - n×n-matrix, the upper triangular
NB. ZfR - (m+1)×n-matrix, the upper trapezoidal R and the
NB. unit upper trapezoidal Zf combined:
NB. ZfR -: Tau , oA1 , A2 , oR
NB. Tau - n-vector, scalars τ[0:n-1] for Zf
NB. oA1 - (l-1)×n-matrix, columns are vectors v[0:n-1]
NB. for Zf
NB. oR - n×n-matrix, the upper triangular
NB. Zf - (m+1)×n-matrix, the Z represented in factored
NB. form
NB. Z - m×m-matrix, the unitary (orthogonal), which is
NB. defined as the product of n elementary
NB. reflectors H(i) of order m:
NB. Z = Π{H(i),i=0:n-1}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i) * τ(i) * u(i)'
NB. m ≥ n
NB.
NB. Storage layout for m=9, n=3, l=5:
NB. eA: ZfR: Zf: R:
NB. ( * * * ) ( τ0 τ1 τ2 ) ( τ0 τ1 τ2 )
NB. ( a1 a1 a1 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( a1 a1 a1 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( a1 a1 a1 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( a1 a1 a1 ) ( v0 v1 v2 ) ( v0 v1 v2 ) ( 0 0 0 )
NB. ( a2 a2 a2 ) ( a2 a2 a2 ) ( 0 0 0 ) ( a2 a2 a2 )
NB. ( a2 a2 a2 ) ( a2 a2 a2 ) ( 0 0 0 ) ( a2 a2 a2 )
NB. ( ir ir ir ) ( or or or ) ( 1 0 0 ) ( or or or )
NB. ( 0 ir ir ) ( 0 or or ) ( 0 1 0 ) ( 0 or or )
NB. ( 0 0 ir ) ( 0 0 or ) ( 0 0 1 ) ( 0 0 or )
NB. where
NB. * - any scalar value, is not used
NB. a1 - elements of iA1
NB. a2 - elements of A2
NB. ir - elements of iR
NB. or - elements of oR
NB. vi - l-vector v(i)
NB. τi - scalar value τ(i)
NB. (vi,0,...,0,1,0,...,0) - m-vector u(i)
NB.
NB. Notes:
NB. - latzr and tzzrf are topologic equivalents
NB. - in u(i) 0s and 1 are not stored, v(i) is empty for l=0,
NB. 0s and 1 are absent and u(i) is empty when n=0
latzr=: 4 : 0
iso=. < < < (liso4dhs 0 , x) , _1
n=. c y
'sfxB y'=. (- n) ({. ; }.) y
pfx=. 0 ({."1) y
while. c y do.
y=. y , {. sfxB
sfxB=. 1 1 }. sfxB
z=. ({."1) y
bak=. iso { z
z=. larfgb 0 iso} z
y=. ((1) _1} z) larzlcfc (}."1) y
pfx=. (pfx , 0) ,. bak iso} z
end.
pfx
)
NB. ---------------------------------------------------------
NB. latrz
NB.
NB. Description:
NB. RZ-factorization of the augmented trapezoidal matrix by
NB. non-blocked version of algorithm
NB.
NB. Syntax:
NB. RZf=. l latrz eA
NB. where
NB. eA - m×(n+1)-matrix, being A augmented by trash
NB. vector:
NB. eA -: iR ,. A1 ,. iA2 ,. Trash
NB. iR - m×m-matrix, the upper triangular
NB. A1 - m×(n-m-l+1)-matrix, is not changed
NB. iA2 - m×(l-1)-matrix, part to be replaced by Zf
NB. Trash - m-vector, will be replaced by Tau
NB. RZf - m×(n+1)-matrix, the upper trapezoidal R and the
NB. unit upper trapezoidal Zf combined:
NB. RZf -: oR ,. A1 ,. oA2 ,. Tau
NB. oR - m×m-matrix, the upper triangular
NB. oA2 - m×(l-1)-matrix, rows are vectors v[0:m-1] for
NB. Zf
NB. Tau - m-vector, scalars τ[0:m-1] for Zf
NB. Zf - m×(n+1)-matrix, the Z represented in factored
NB. form
NB. Z - n×n-matrix, the unitary (orthogonal), which is
NB. defined as the product of m elementary
NB. reflectors H(i) of order n:
NB. Z = Π{H(i)',i=0:m-1}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i)' * τ(i) * u(i)
NB. m ≤ n
NB.
NB. Storage layout for m=3, n=9, l=5:
NB. eA:
NB. ( ir ir ir a1 a1 a2 a2 a2 a2 * )
NB. ( 0 ir ir a1 a1 a2 a2 a2 a2 * )
NB. ( 0 0 ir a1 a1 a2 a2 a2 a2 * )
NB. RZf:
NB. ( or or or a1 a1 v0 v0 v0 v0 τ0 )
NB. ( 0 or or a1 a1 v1 v1 v1 v1 τ1 )
NB. ( 0 0 or a1 a1 v2 v2 v2 v2 τ2 )
NB. R:
NB. ( or or or a1 a1 0 0 0 0 )
NB. ( 0 or or a1 a1 0 0 0 0 )
NB. ( 0 0 or a1 a1 0 0 0 0 )
NB. Zf:
NB. ( 1 0 0 0 0 v0 v0 v0 v0 τ0 )
NB. ( 0 1 0 0 0 v1 v1 v1 v1 τ1 )
NB. ( 0 0 1 0 0 v2 v2 v2 v2 τ2 )
NB. where
NB. ir - elements of iR
NB. a1 - elements of A1
NB. a2 - elements of iA2
NB. * - any scalar value, is not used
NB. or - elements of oR
NB. vi - l-vector v(i)
NB. τi - scalar value conj(τ(i))
NB. (0,...,0,1,0,...,0,vi) - n-vector u(i)
NB.
NB. Notes:
NB. - models LAPACK's xLATRZ with the following difference:
NB. - v(i) is stored instead of conj(v(i))
NB. - conj(τ(i)) is stored instead of τ(i)
NB. to keep consistency with gexxf
NB. - latrz and tzrzf are topologic equivalents
NB. - in u(i) 0s and 1 are not stored, v(i) is empty for l=0,
NB. 0s and 1 are absent and u(i) is empty when n=0
latrz=: 4 : 0
iso=. < < < 0 , liso4dhs _1 , x
m=. # y
'pfxL y'=. m ({."1 ; }."1) y
sfx=. 0 {. y
while. # y do.
y=. (({:"1) pfxL) ,. y
pfxL=. _1 _1 }. pfxL
z=. {: y
bak=. iso { z
z=. larfgfc 0 iso} z
y=. ((1) 0} z) larzrnbr }: y
sfx=. (bak iso} z) , 0 ,. sfx
end.
sfx
)
NB. =========================================================
NB. Interface
NB. ---------------------------------------------------------
NB. gelqf
NB.
NB. Description:
NB. LQ factorization of a general matrix
NB.
NB. Syntax:
NB. LQf=. gelqf A
NB. where
NB. A - m×n-matrix, the input to factorize
NB. LQf - m×(n+1)-matrix, L and Qf combined
NB. L - m×k-matrix, the lower trapezoidal
NB. Qf - k×(n+1)-matrix, the unit upper trapezoidal (unit
NB. diagonal is not stored), represents the Q in
NB. factored form
NB. Q - n×n-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary
NB. reflectors H(i) of order n:
NB. Q = Π{H(i)',i=k-1:0}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i)' * τ(i) * u(i)
NB. k = min(m,n)
NB.
NB. Storage layout for m=3, n=7:
NB. LQf:
NB. ( l v0 v0 v0 v0 v0 v0 τ0 )
NB. ( l l v1 v1 v1 v1 v1 τ1 )
NB. ( l l l v2 v2 v2 v2 τ2 )
NB. L:
NB. ( l 0 0 )
NB. ( l l 0 )
NB. ( l l l )
NB. Qf:
NB. ( 1 v0 v0 v0 v0 v0 v0 τ0 )
NB. ( 0 1 v1 v1 v1 v1 v1 τ1 )
NB. ( 0 0 1 v2 v2 v2 v2 τ2 )
NB. where
NB. l - elements of L
NB. vi - vector v(i)
NB. τi - scalar value conj(τ(i))
NB. (0,...,0,1,vi) - n-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = L * Q
NB. ( -: ( trl @:(}:"1) mp unglq)@gelqf) A
NB. NB. A = L * (Q)
NB. ( -: (unmlqrn trlpick @:(}:"1))@gelqf) A
NB.
NB. Notes:
NB. - models LAPACK's xGELQF
NB. - gelq2 and gelqf are topologic equivalents
gelqf=: 3 : 0
y=. y ,. 0
'pfx sfxT'=. 0 ({."1 ; {.) y
while. -. 0 e. QFNX (< 0 _1 + $) y do.
nb=. (<./) QFNB (, 0 _1 + $) y
Z=. gelq2 nb {. y
sfxT=. sfxT , Z
y=. (tru1 Z) larfbrnfr nb }. y
pfx=. pfx ,. sfxT ,&(nb&({."1)) y
sfxT=. nb (}."1) sfxT
y=. nb (}."1) y
end.
pfx ,. sfxT , gelq2 y
)
NB. ---------------------------------------------------------
NB. geqlf
NB.
NB. Description:
NB. QL factorization of a general matrix
NB.
NB. Syntax:
NB. QfL=. geqlf A
NB. where
NB. A - m×n-matrix, the input to factorize
NB. QfL - (m+1)×n-matrix, Qf and L combined
NB. Qf - (m+1)×k-matrix, the unit upper trapezoidal (unit
NB. diagonal is not stored), represents the Q in
NB. factored form
NB. L - k×n-matrix, the lower trapezoidal
NB. Q - m×m-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary
NB. reflectors H(i) of order m:
NB. Q = Π{H(i),i=k-1:0}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i) * τ(i) * u(i)'
NB. k = min(m,n)
NB.
NB. Storage layout for m=7, n=3:
NB. QfL: Qf: L:
NB. ( τ0 τ1 τ2 ) ( τ0 τ1 τ2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( l v1 v2 ) ( 1 v1 v2 ) ( l 0 0 )
NB. ( l l v2 ) ( 0 1 v2 ) ( l l 0 )
NB. ( l l l ) ( 0 0 1 ) ( l l l )
NB. where
NB. l - elements of L
NB. vi - vector v(i)
NB. τi - scalar value τ(i)
NB. (vi,1,0,...,0) - m-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = Q * L
NB. ( -: (ungql mp (trl~ -~/@$)@: }. )@geqlf) A
NB. NB. A = (Q) * L
NB. ( -: (unmqlln (trlpick~ -~/@$)@ }. )@geqlf) A
NB.
NB. Notes:
NB. - models LAPACK's xGEQLF
NB. - geql2 and geqlf are topologic equivalents
geqlf=: 3 : 0
y=. 0 , y
'pfxR sfx'=. 0 ({."1 ; {.) y
while. -. 0 e. QFNX (< _1 0 + $) y do.
nb=. - (<./) QFNB (, _1 0 + $) y
Z=. geql2 nb ({."1) y
pfxR=. Z ,. pfxR
y=. ((tru1~ -~/@$) Z) larfblcbc nb (}."1) y
sfx=. sfx ,~ y ,.&(nb&{.) pfxR
y=. nb }. y
pfxR=. nb }. pfxR
end.
sfx ,~ pfxR ,.~ geql2 y
)
NB. ---------------------------------------------------------
NB. geqrf
NB.
NB. Description:
NB. QR factorization of a general matrix
NB.
NB. Syntax:
NB. QfR=. geqrf A
NB. where
NB. A - m×n-matrix, the input to factorize
NB. QfR - (m+1)×n-matrix, Qf and R combined
NB. Qf - (m+1)×k-matrix, the unit lower trapezoidal (unit
NB. diagonal is not stored), represents the Q in
NB. factored form
NB. R - k×n-matrix, the upper trapezoidal
NB. Q - m×m-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary reflectors
NB. H(i) of order m:
NB. Q = Π{H(i),i=0:k-1}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i) * τ(i) * u(i)'
NB. k = min(m,n)
NB.
NB. Storage layout for m=7, n=3:
NB. QfR: Qf: R:
NB. ( r r r ) ( 1 0 0 ) ( r r r )
NB. ( v0 r r ) ( v0 1 0 ) ( 0 r r )
NB. ( v0 v1 r ) ( v0 v1 1 ) ( 0 0 r )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( v0 v1 v2 ) ( v0 v1 v2 )
NB. ( τ0 τ1 τ2 ) ( τ0 τ1 τ2 )
NB. where
NB. r - elements of R
NB. vi - vector v(i)
NB. τi - scalar value τ(i)
NB. (0,...,0,1,vi) - m-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = Q * R
NB. ( -: (ungqr mp tru @: }: )@geqrf) A
NB. NB. A = (Q) * R
NB. ( -: (unmqrln trupick @ }: )@geqrf) A
NB.
NB. Notes:
NB. - models LAPACK's xGEQRF
NB. - geqr2 and geqrf are topologic equivalents
geqrf=: 3 : 0
y=. y , 0
'pfx sfxL'=. 0 ({. ; {."1) y
while. -. 0 e. QFNX (< _1 0 + $) y do.
nb=. (<./) QFNB , (_1 0 + $) y
Z=. geqr2 nb ({."1) y
sfxL=. sfxL ,. Z
y=. (trl1 Z) larfblcfc nb (}."1) y
pfx=. pfx , sfxL ,.&(nb&{.) y
sfxL=. nb }. sfxL
y=. nb }. y
end.
pfx , sfxL ,. geqr2 y
)
NB. ---------------------------------------------------------
NB. gerqf
NB.
NB. Description:
NB. RQ factorization of a general matrix
NB.
NB. Syntax:
NB. RQf=. gerqf A
NB. where
NB. A - m×n-matrix, the input to factorize
NB. RQf - m×(n+1)-matrix, R and Qf combined
NB. R - m×k-matrix, the upper trapezoidal
NB. Qf - k×(n+1)-matrix, the unit lower trapezoidal (unit
NB. diagonal is not stored), represents the Q in
NB. factored form
NB. Q - n×n-matrix, the unitary (orthogonal), which is
NB. defined as the product of k elementary reflectors
NB. H(i) of order n:
NB. Q = Π{H(i)',i=0:k-1}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i)' * τ(i) * u(i)
NB. k = min(m,n)
NB.
NB. Storage layout for m=3, n=7:
NB. RQf:
NB. ( τ0 v0 v0 v0 v0 r r r )
NB. ( τ1 v1 v1 v1 v1 v1 r r )
NB. ( τ2 v2 v2 v2 v2 v2 v2 r )
NB. R:
NB. ( r r r )
NB. ( 0 r r )
NB. ( 0 0 r )
NB. Qf:
NB. ( τ0 v0 v0 v0 v0 1 0 0 )
NB. ( τ1 v1 v1 v1 v1 v1 1 0 )
NB. ( τ2 v2 v2 v2 v2 v2 v2 1 )
NB. where
NB. r - elements of R
NB. vi - vector v(i)
NB. τi - scalar value conj(τ(i))
NB. (vi,1,0,...,0) - n-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = R * Q
NB. ( -: ((tru~ -~/@$)@:(}."1) mp ungrq)@gerqf) A
NB. NB. A = R * (Q)
NB. ( -: (unmrqrn (trupick~ -~/@$)@:(}."1))@gerqf) A
NB.
NB. Notes:
NB. - models LAPACK's xGERQF
NB. - gerq2 and gerqf are topologic equivalents
gerqf=: 3 : 0
y=. 0 ,. y
'pfxB sfx'=. 0 ({. ; {."1) y
while. -. 0 e. QFNX (< 0 _1 + $) y do.
nb=. - (<./) QFNB (, 0 _1 + $) y
Z=. gerq2 nb {. y
pfxB=. Z , pfxB
y=. ((trl1~ -~/@$) Z) larfbrnbr nb }. y
sfx=. sfx ,.~ y ,&(nb&({."1)) pfxB
y=. nb (}."1) y
pfxB=. nb (}."1) pfxB
end.
sfx ,.~ pfxB ,~ gerq2 y
)
NB. ---------------------------------------------------------
NB. tzlzf
NB.
NB. Description:
NB. LZ-factorization of the trapezoidal matrix
NB.
NB. Syntax:
NB. LZf=. tzlzf A
NB. where
NB. A - m×n-matrix:
NB. A -: iA0 ,. iL
NB. iA0 - m×(n-m)-matrix, part to be replaced by Zf
NB. iL - m×m-matrix
NB. LZf - m×(n+1)-matrix, the lower trapezoidal L and unit
NB. lower trapezoidal Zf combined:
NB. LZf -: Tau ,. oA0 ,. oL
NB. Tau - m-vector, scalars τ[0:m-1] for Zf
NB. oA0 - m×(n-m)-matrix, rows are vectors v[0:m-1] for Zf
NB. oL - m×m-matrix, the lower triangular
NB. Zf - m×(n+1)-matrix, the Z represented in factored
NB. form
NB. Z - n×n-matrix, the unitary (orthogonal), which is
NB. defined as the product of m elementary reflectors
NB. H(i) of order n:
NB. Z = Π{H(i)',i=m-1:0}
NB. H(i) ≡ H(u(i),τ(i)) := I - u(i)' * τ(i) * u(i)
NB. m ≤ n
NB.
NB. Storage layout for m=3, n=7:
NB. A:
NB. ( a0 a0 a0 a0 il * * )
NB. ( a0 a0 a0 a0 il il * )
NB. ( a0 a0 a0 a0 il il il )
NB. LZf:
NB. ( τ0 v0 v0 v0 v0 ol 0 0 )
NB. ( τ1 v1 v1 v1 v1 ol ol 0 )
NB. ( τ2 v2 v2 v2 v2 ol ol ol )
NB. L:
NB. ( 0 0 0 0 ol 0 0 )
NB. ( 0 0 0 0 ol ol 0 )
NB. ( 0 0 0 0 ol ol ol )
NB. Zf:
NB. ( τ0 v0 v0 v0 v0 1 0 0 )
NB. ( τ1 v1 v1 v1 v1 0 1 0 )
NB. ( τ2 v2 v2 v2 v2 0 0 1 )
NB. where
NB. a0 - elements of iA0
NB. il - elements of iL
NB. ol - elements of oL
NB. vi - l-vector v(i)
NB. τi - scalar value conj(τ(i))
NB. (vi,0,...,0,1,0,...,0) - n-vector u(i)
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. NB. A = L * Z
NB. (-: (({."1~ -@#) mp unglz)@tzlzf) A
NB. NB. A = L * (Z)
NB. (-: (unmlzrn ((1 - c) {."1 ({."1~ -@#)))@tzlzf) A
NB.
NB. Notes:
NB. - latlz and tzlzf are topologic equivalents
NB. - in u(i) 0s and 1 are not stored, v(i) is empty for l=0,
NB. 0s and 1 are absent and u(i) is empty when n=0
NB. - strict upper triangle of iL is ignored
tzlzf=: 3 : 0
y=. 0 ,. y
l=. (-~/) 'm n1'=. $ y
'sfxR y'=. (- m) ({."1 ; }."1) y
pfx=. 0 {. y
nb=. QFNB <. # y
I=. idmat nb
O=. (2 # nb) $ 0
while. QFNX < # y do.
y=. y ,. nb ({."1) sfxR
sfxR=. (2 # nb) }. sfxR
Z=. l latlz nb {. y
y=. (I ,.~ l ({."1) Z) larzbrnfr nb }. y
I=. O ,. I
pfx=. pfx appendl Z
end.
pfx appendl l latlz y ,. sfxR
)
NB. ---------------------------------------------------------
NB. tzzlf