aspvbslib/sample.asp at master · jun1sfukui/aspvbslib · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
<%
Option Explicit
%>
<!--#include file="./aspvbslib/adovbs.inc"-->
<!--#include file="./aspvbslib/aspvbslib-core.inc"-->
<!--#include file="./aspvbslib/aspvbslib-data.inc"-->
<!--#include file="./aspvbslib/aspvbslib-web.inc"-->
<%
' ViewModelクラス
Class ViewModel
    'タイトル
    Public title
    '部署リスト
    Public departments
    '社員リスト
    Public employees
    '選択中の社員番号
    Public empno
    '選択中の部署番号
    public deptno
    '選択中の社員明細
    Public empDetail
End Class

'RequestModelクラス
Class RequestModel
    Public deptno
    Public empno
End Class
' RequestModelクラスのPropNames関数(LoadRequest関数用の定義)
Function RequestModelPropNames
    RequestModelPropNames = Array("deptno", "empno")
End Function

'社員クラス
Class Emp
    '社員番号
    Public empno
    '社員名
    Public empname
    '部署番号
    Public deptno
    '説明
    Public description
End Class

'部署クラス
Class Dept
    '部署番号
    Public deptno
    '部署名
    Public deptname
End Class

Dim vm
Call Main

Sub Main
    Set vm = New ViewModel

    Call LoadViewModel(vm)

    Call RenderHTML(vm)
End Sub

Function LoadViewModel(vm)
    'タイトルの設定
    vm.title = "ArrayListとSqlQueryを使ったサンプル"

    'リクエストの取得
    Dim req: Set req = New RequestModel
    LoadRequest(req)

    vm.deptno = req.deptno
    If Len(vm.deptno) > 0 And ChkNum(vm.deptno) Then
        vm.deptno = CInt(vm.deptno)
    Else
        vm.deptno = ""
    End If

    vm.empno = req.empno
    If Len(vm.empno) > 0 And ChkNum(vm.empno) Then
        vm.empno = CInt(vm.empno)
    Else
        vm.empno = ""
    End If

    'データベース接続
    Dim DbConn
    Set DbConn = Server.CreateObject("ADODB.Connection")
    Dim dbfilepath :dbfilepath = Server.MapPath("aspvbslib_sample.mdb")
    dim dbconnString :dbconnString = "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & dbfilepath & ";"
    DbConn.Open dbconnString

    '部署リストの取得
    Set vm.departments = SqlQuery(DbConn, "Dept", "SELECT * FROM dept")
    if IsNullOrEmpty(vm.deptno) And vm.departments.Count > 0 Then
        vm.deptno = vm.departments(0).deptno
    End If

    '社員リストの取得（部署指定）
    Dim cmd: Set cmd = Server.CreateObject("ADODB.Command")
    cmd.CommandText = "SELECT * FROM emp WHERE deptno=?"
    cmd.parameters.Append cmd.CreateParameter("@deptno", adInteger, adParamInput, , vm.deptno)
    Set vm.employees = SqlQuery(DbConn, "Emp", cmd)

    '選択中のempnoが存在しなければ、現在のリストの先頭を選択する。
    If vm.employees.Where("item.empno = p", vm.empno).Count = 0 Then
        If vm.employees.Count > 0 Then
            vm.empno = vm.employees(0).empno
        Else
            vm.empno = ""
        End If
    End If

    '選択中の社員情報明細を設定
    If vm.empno = "" Then
        '選択されていなければ初期化
        Set vm.empDetail = New Emp
    Else
        Set vm.empDetail = vm.employees.FindFirst("item.empno = p", vm.empno)(0)
    End If

    DbConn.Close
    Set DbConn = Nothing

End Function

Function RenderHTML(vm)
%>
<!doctype html>
<html lang="jp">
<head>
    <meta charset="shift-jis">
    <title><%=vm.title%></title>
    <meta name="description" content="Sample 01">
    <!-- Bootstrap CSS -->
    <link rel="stylesheet" href="https://stackpath.bootstrapcdn.com/bootstrap/4.1.3/css/bootstrap.min.css" integrity="sha384-MCw98/SFnGE8fJT3GXwEOngsV7Zt27NXFoaoApmYm81iuXoPkFOJwJ8ERdknLPMO" crossorigin="anonymous">
    <style>
    </style>
</head>
<body>
<div class="container">
    <h4><%=vm.title%></h4>
    <form method="get">
        <div class="form-group">
            <label for="deptno">部署</label>
            <select class="form-control" name="deptno" id="deptno" onchange="this.form.submit()">
                <% Dim dept: For Each dept In vm.departments.Items %>
                    <option value="<%=dept.deptno%>" <%=write_if("selected", dept.deptno=vm.deptno)%> data="<%=dept.deptno & ":" & vm.deptno & "(" & dept.deptno=vm.deptno & ")"%>"><%=dept.deptname%></option>
                <% Next %>
            </select>
        </div>

        <div class="form-group">
            <label for="empno">社員</label>
            <select class="form-control" name="empno" id="empno" onchange="this.form.submit()">
                <% Dim emp: For Each emp In vm.employees.Items %>
                    <option value="<%=emp.empno%>" <%=write_if("selected", emp.empno=vm.empno)%>><%=emp.empname%></option>
                <% Next %>
            </select>
        </div>

        <div class="form-group">
            <label>詳細</label>
            <div class="card p-3" style="width:18rem">
                <h5 class="card-title"><%=vm.empDetail.empname%></h5>
                <p class="card-text"><%=vm.empDetail.description%>
                </p>
            </div>
        </div>
    </form>
</div>
</body>
</html>
<%
End Function
%>