Is it possible to create multiple tables with db.create()?

[nicobrix3]

Is it correct to do this?

db.create(0, TABLE_SIZE, (unsigned int)sizeof(logEvent));
db.create(0, TABLE_SIZE, (unsigned int)sizeof(userDetail));
db.create(0, TABLE_SIZE, (unsigned int)sizeof(tempReading));

Thank you!

[giapoldo]

The objects holds header data for one table only. But because pointer arithmetic written in the library is dependent on db.open(table_pointer), you should be able to create new tables within the same memory space/media by offsetting table_pointer like this, if all tables are the same size (in this case):

db.create(0, TABLE_SIZE, (unsigned int)sizeof(logEvent));
db1.create(TABLE_SIZE, TABLE_SIZE, (unsigned int)sizeof(userDetail));
db2.create(2*TABLE_SIZE, TABLE_SIZE, (unsigned int)sizeof(tempReading));

db.open(0);
db1.open(TABLE_SIZE);
db2.open(2*TABLE_SIZE);

[asjdf]

So can't I use this library to create multiple tables of different sizes?

[giapoldo]

My example was with same sized tables, I think it should be ok for different sized tables as long as you are careful to allocate them properly.

[asjdf]

I use SPIFFS as data storage and it works well.I built 2 teble in this program.My board is ESP8266

#include "Arduino.h"
#include <EDB.h>

//Use SPIFFS FS as data storage
#include <FS.h>

#define TABLE1_SIZE 4096
#define TABLE2_SIZE 8192

char* db1_name = "/db/edb_1.db";
char* db2_name = "/db/edb_2.db";
File db1File;
File db2File;

// Arbitrary record definition for this table.
// This should be modified to reflect your record needs.
struct LogMainSetting {
    int id;
    char data[17];
}LogMainSetting;
struct LogExpendSetting {
    int id;
    int data;
}LogExpendSetting;

// 写/读方法
inline void writer1 (unsigned long address, const byte* data, unsigned int recsize) {
    db1File.seek(address, SeekSet);
    db1File.write(data,recsize);
    db1File.flush();
}

inline void reader1 (unsigned long address, byte* data, unsigned int recsize) {
    db1File.seek(address, SeekSet);
    db1File.read(data,recsize);
}

inline void writer2 (unsigned long address, const byte* data, unsigned int recsize) {
    db2File.seek(address, SeekSet);
    db2File.write(data,recsize);
    db2File.flush();
}

inline void reader2 (unsigned long address, byte* data, unsigned int recsize) {
    db2File.seek(address, SeekSet);
    db2File.read(data,recsize);
}

// 创建EDB项目 链接写/读方法
EDB db1(&writer1, &reader1);
EDB db2(&writer2, &reader2);
// Run the demo
void setup()
{
    Serial.begin(9600);
    Serial.println(" Extended Database Library + SPIFFS storage demo");
    Serial.println();

    SPIFFS.begin();
    delay(2000);

    if (SPIFFS.exists(db1_name)) {

        db1File = SPIFFS.open(db1_name, "r+");

        if (db1File) {
            Serial.print("Opening current table1... ");
            EDB_Status result = db1.open(0);
            if (result == EDB_OK) {
                Serial.println("DONE");
            } else {
                Serial.println("ERROR");
                Serial.println("Did not find database in the file " + String(db1_name));
                Serial.print("Creating new table1... ");
                db1.create(0, TABLE1_SIZE, (unsigned int)sizeof(LogMainSetting));
                table1Setup();//保存初始化数据
                Serial.println("DONE");
                return;
            }
        } else {
            Serial.println("Could not open file " + String(db1_name));
            return;
        }
    } else {
        Serial.print("Creating table1... ");
        // create table at with starting address 0
        db1File = SPIFFS.open(db1_name, "w+");
        db1.create(0, TABLE1_SIZE, (unsigned int)sizeof(LogMainSetting));
        Serial.println("DONE");//保存初始化数据
        table1Setup();
    }
    select1All();
    db1File.close();
    if (SPIFFS.exists(db2_name)) {

        db2File = SPIFFS.open(db2_name, "r+");

        if (db2File) {
            Serial.print("Opening current table2... ");
            EDB_Status result = db2.open(0);
            if (result == EDB_OK) {
                Serial.println("DONE");
            } else {
                Serial.println("ERROR");
                Serial.println("Did not find database in the file " + String(db2_name));
                Serial.print("Creating new table2... ");
                db2.create(0, TABLE2_SIZE, (unsigned int)sizeof(LogExpendSetting));
                table2Setup(7);//保存初始化数据
                Serial.println("DONE");
                return;
            }
        } else {
            Serial.println("Could not open file " + String(db2_name));
            return;
        }
    } else {
        Serial.print("Creating table2... ");
        // create table at with starting address 0
        db2File = SPIFFS.open(db2_name, "w+");
        db2.create(0, TABLE2_SIZE, (unsigned int)sizeof(LogExpendSetting));
        Serial.println("DONE");//保存初始化数据
        table2Setup(7);
    }
    select2All();
    db2File.close();

}

void loop()
{
  //ESP.restart();
}

void deleteOneRecord(int recno)
{
    Serial.print("Deleting recno: ");
    Serial.println(recno);
    db1.deleteRec(recno);
}

void deleteAll()
{
    Serial.print("Truncating table... ");
    db1.clear();
    Serial.println("DONE");
}

void countRecords()
{
    Serial.print("Record Count: ");
    Serial.println(db1.count());
}

void table1Setup()
{
    Serial.print("table setup... ");
    LogMainSetting.id = 1;
    strncpy(LogMainSetting.data, "0123456789012345", 16);
    EDB_Status result = db1.appendRec(EDB_REC LogMainSetting);
    if (result != EDB_OK) printError(result);

    LogMainSetting.id = 2;
    strncpy(LogMainSetting.data, "01234567890123456", 16);
    EDB_Status result1 = db1.appendRec(EDB_REC LogMainSetting);
    if (result != EDB_OK) printError(result1);

    LogMainSetting.id = 3;
    strncpy(LogMainSetting.data, "0.1.0", 16);
    EDB_Status result2 = db1.appendRec(EDB_REC LogMainSetting);
    if (result != EDB_OK) printError(result2);

    Serial.println("DONE");
}

void table2Setup(int num_recs)
{
    Serial.print("Creating Records... ");
    for (int recno = 1; recno <= num_recs; recno++)
    {
        LogExpendSetting.id = recno;
        LogExpendSetting.data = 0;
        EDB_Status result = db2.appendRec(EDB_REC LogExpendSetting);
        if (result != EDB_OK) printError(result);
    }
    Serial.println("DONE");
}

void select1All()
{
    for (int recno = 1; recno <= db1.count(); recno++)
    {
        EDB_Status result = db1.readRec(recno, EDB_REC LogMainSetting);
        if (result == EDB_OK)
        {
            Serial.print("Recno: ");
            Serial.print(recno);
            Serial.print(" ID: ");
            Serial.print(LogMainSetting.id);
            Serial.print(" Data: ");
            Serial.println(LogMainSetting.data);
        }
        else printError(result);
    }
}
void select2All()
{
    for (int recno = 1; recno <= db2.count(); recno++)
    {
        EDB_Status result = db2.readRec(recno, EDB_REC LogExpendSetting);
        if (result == EDB_OK)
        {
            Serial.print("Recno: ");
            Serial.print(recno);
            Serial.print(" ID: ");
            Serial.print(LogExpendSetting.id);
            Serial.print(" Data: ");
            Serial.println(LogExpendSetting.data);
        }
        else printError(result);
    }
}
void printError(EDB_Status err)
{
    Serial.print("ERROR: ");
    switch (err)
    {
        case EDB_OUT_OF_RANGE:
            Serial.println("Recno out of range");
            break;
        case EDB_TABLE_FULL:
            Serial.println("Table full");
            break;
        case EDB_OK:
        default:
            Serial.println("OK");
            break;
    }
}