build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.bmuschko:gradle-nexus-plugin:2.3.1'
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.8.2'
    }
}

plugins {
    id "java"
    id "jacoco"
    id "org.sonarqube" version "2.6.2"
    id "com.bmuschko.nexus" version "2.3.1"
    id "com.github.kt3k.coveralls" version "2.8.2"
}

group = 'de.kgrupp'
ext.moduleName = 'inoks.java.monads'
def versionStr = System.properties['inoks.java.monads.version']
version = !versionStr ? "LOCAL-VERSION" : versionStr

sourceCompatibility = 11

repositories {
    mavenCentral()
}

dependencies {
    testImplementation('org.junit.jupiter:junit-jupiter-api:5.3.2')
    testRuntime('org.junit.jupiter:junit-jupiter-engine:5.3.2')
}

compileJava {
    inputs.property('moduleName', moduleName)
    doFirst {
        options.compilerArgs = [
                '--module-path', classpath.asPath
        ]
        classpath = files()
    }
}

javadoc {
    options.addStringOption('-module-path', classpath.asPath)
}

test {
    useJUnitPlatform()

    filter {
        exclude '**/module-info.class'
    }
}

sonarqube {
    properties {
        property 'sonar.projectKey', 'inoks-java-monads'
        property 'sonar.projectName', 'inoks-java-monads'
    }
}

modifyPom {
    project {
        name 'inoks-java-monads'
        description 'Utility classes for developing with monads. '
        url 'https://github.com/kgrupp/inoks-java-monads'
        inceptionYear '2017'

        scm {
            url 'https://github.com/kgrupp/inoks-java-monads'
            connection 'scm:https://kgrupp@github.com/kgrupp/inoks-java-monads.git'
            developerConnection 'scm:git://github.com/kgrupp/inoks-java-monads.git'
        }

        licenses {
            license {
                name 'MIT License'
                url 'https://github.com/kgrupp/inoks-java-monads/blob/master/LICENSE'
                distribution 'repo'
            }
        }

        developers {
            developer {
                id 'kgrupp'
                name 'Konstantin Grupp'
                email 'coding@konstantin-grupp.de'
            }
        }
    }
}

extraArchive {
    sources = true
    tests = true
    javadoc = true
}

nexus {
    sign = true
    repositoryUrl = project.hasProperty('nexusUrlRelease') ? nexusUrlRelease : 'http://localhost:8081/repository/maven-releases/'
    snapshotRepositoryUrl = project.hasProperty('nexusUrlSnapshot') ? nexusUrlSnapshot : 'http://localhost:8081/repository/maven-snapshots'
}

jacocoTestReport {
    reports {
        xml.enabled = true // coveralls plugin depends on xml format report
        html.enabled = true
    }
}