ndpi_rgba_to_8bit.ijm

// This script converts NDPI files to 8-bit single color TIFFs

// Enable batch mode to speed up the macro by disabling the display of images during processing.
setBatchMode(true);

// Prompt the user to select the directory containing the images
inputFolder = getDirectory("Select input directory");

// Get a list of NDPI files in the folder
list = getFileList(inputFolder);

// Set the bit depth to 8
bit_depth = 8;

// Prompt the user to enter a letter representing the color channel (R, G, or B)
inputString = getString("Select color channel (R, G, or B):", "B");
// Prompt the user to enter the series
selectedSeries = getNumber("Enter the series you want to select:", 3);
// Convert the input string to a number representing the color channel
colorChannel = -1; // initialize to an invalid value
if (inputString == "R") {
colorChannel = 0;
} else if (inputString == "G") {
colorChannel = 1;
} else if (inputString == "B") {
colorChannel = 2;
} else {
// Show an error message if the input is invalid
showMessage("Invalid input: " + inputString);
}

// Loop through each TIFF file in the input folder
for (i = 0; i < list.length; i++) {
    if (endsWith(list[i], ".ndpi")) {
    	
        // Open the image using the Bio-Formats Importer plugin
        run("Bio-Formats Importer", "open=[" + inputFolder + list[i] + "] autoscale color_mode=Default rois_import=[ROI manager] view=Hyperstack stack_order=XYCZT series_"+(selectedSeries));
  
        // Split the channels of the image
        run("Split Channels");
  
        // Get the titles of the split channel windows
        titles = getList("image.titles");

        // Select the window corresponding to the specified color channel
        selectWindow(titles[colorChannel]);  

        // Construct the output filename by appending the bit depth to the input filename
        outputFilename = replace(list[i], ".tif", "_" + bit_depth + "bit"+inputString+".tif");
        outputPath = inputFolder + outputFilename;

        // Save the selected color channel with the new filename
        saveAs("Tiff", outputPath);

        // Close all images to free up memory, even in batch mode
        close("*");
    }
}

setBatchMode(false);