-
Notifications
You must be signed in to change notification settings - Fork 6
/
mo_pumpingtests.f90
3233 lines (2477 loc) · 130 KB
/
mo_pumpingtests.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
MODULE mo_pumpingtests
! This module serves different solutions for the groundwater-flow equation,
! containing the classical Thiem and Theis solutions as well as
! the effektive well-flow solution for the effectiv Coarse-Graining Conductivity.
! These kinds of solution are implemented:
! -Thiem's solution for steady-state and homogeneous aquifer : thiem
! -Theis' solution for transient flow and homogenous aquifer : theis
! -the extended thiem's solution for steady state and heterogeneous aquifer in 2D : ext_thiem2d
! -the extended thiem's solution for steady state and heterogeneous aquifer and
! anisotropical impact in 3D : ext_thiem3d
! -the extended theis' solution for transient flow and heterogeneous aquifer and
! anisotropical impact in 2D : ext_theis2d
! -the extended theis' solution for transient flow and heterogeneous aquifer and
! anisotropical impact in 3D : ext_theis3d
!
! Written Sebastian Mueller, Jun 2014 - Jun 2016
! License
! -------
! This file is part of the JAMS Fortran package, distributed under the MIT License.
!
! Copyright (c) 2014-2016 Sebastian Mueller
!
! Permission is hereby granted, free of charge, to any person obtaining a copy
! of this software and associated documentation files (the "Software"), to deal
! in the Software without restriction, including without limitation the rights
! to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
! copies of the Software, and to permit persons to whom the Software is
! furnished to do so, subject to the following conditions:
!
! The above copyright notice and this permission notice shall be included in all
! copies or substantial portions of the Software.
!
! THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
! IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
! FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
! AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
! LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
! OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
! SOFTWARE.
! If you use this routine in your work, you should cite the following reference
! Zech A, C L Schneider, and S Attinger (2012)
! The Extended Thiem's solution: Including the impact of heterogeneity,
! Water Resources Research 48, W10535, doi:10.1029/2012WR011852
! Note on Numerical Recipes License
! ---------------------------------
! Be aware that some code is under the Numerical Recipes License 3rd
! edition <http://www.nr.com/aboutNR3license.html>
! The Numerical Recipes Personal Single-User License lets you personally
! use Numerical Recipes code ("the code") on any number of computers,
! but only one computer at a time. You are not permitted to allow anyone
! else to access or use the code. You may, under this license, transfer
! precompiled, executable applications incorporating the code to other,
! unlicensed, persons, providing that (i) the application is
! noncommercial (i.e., does not involve the selling or licensing of the
! application for a fee), and (ii) the application was first developed,
! compiled, and successfully run by you, and (iii) the code is bound
! into the application in such a manner that it cannot be accessed as
! individual routines and cannot practicably be unbound and used in
! other programs. That is, under this license, your application user
! must not be able to use Numerical Recipes code as part of a program
! library or "mix and match" workbench.
! Businesses and organizations that purchase the disk or code download,
! and that thus acquire one or more Numerical Recipes Personal
! Single-User Licenses, may permanently assign those licenses, in the
! number acquired, to individual employees. Such an assignment must be
! made before the code is first used and, once made, it is irrevocable
! and can not be transferred.
! If you do not hold a Numerical Recipes License, this code is only for
! informational and educational purposes but cannot be used.
USE mo_kind, ONLY: i4, i8, sp, dp
USE mo_constants, ONLY: PI_D, PI
USE mo_utils, ONLY: eq, le, ne, ge
IMPLICIT NONE
PUBLIC :: thiem ! thiem's solution for the steady-state and homogeneous aquifer
PUBLIC :: theis ! theis' solution for transient-flow and homogeneous aquifer
PUBLIC :: ext_thiem2d ! the extended thiem's solution for the steady-state and heterogeneous aquifer in 2D
PUBLIC :: ext_thiem3d ! the extended thiem's solution for the steady-state and heterogeneous aquifer in 3D
PUBLIC :: ext_theis2d ! the extended theis' solution for the transient-flow and heterogeneous aquifer in 2D
PUBLIC :: ext_theis3d ! the extended theis' solution for the transient-flow and heterogeneous aquifer in 3D
! ------------------------------------------------------------------
! NAME
! thiem
! PURPOSE
! Calculates the thiem solution h(r) for the steady-state and homogenous aquifers.
! CALLING SEQUENCE
! out = thiem(rad, params, inits)
! INTENT(IN)
! REAL(sp/dp),[DIMENSION(:)] :: rad : input radius in m
! REAL(sp/dp), DIMENSION(1) :: params Parameters
! params(1) : hydraulic conductivity in m/s
! REAL(sp/dp), DIMENSION(4) :: inits Initial values
! inits(1) : reference point radius R in m
! inits(2) : reference head H in m
! inits(3) : pumping rate at the well Q in m^3/s
! inits(4) : aquifer thickness L in m
! INTENT(INOUT)
! None
! INTENT(OUT)
! None
! INTENT(IN), OPTIONAL
! None
! INTENT(INOUT), OPTIONAL
! None
! INTENT(OUT), OPTIONAL
! None
! RETURNS
!> \return REAL(sp/dp) :: thiem hydraulic head in m
! RESTRICTIONS
! 1) Input values must be floating points.
! 2) rad > 0 [radius]
! 3) inits(1) > 0 [reference radius]
! 4) params(1) > 0 [conductivity]
! 5) inits(4) > 0 [aqifer thickness]
! EXAMPLE
! rad = 0.5
! inits = (/ 32.0 , 0.0 , -0.001 , 1.0 /)
! params = (/ 0.0001 /)
! h = thiem(rad, inits, params )
! -> see also example in test directory
! LITERATURE
! None
! HISTORY
! Written, Sebastian Mueller, Apr 2014
INTERFACE thiem
MODULE PROCEDURE thiem_sp, thiem_dp, thiem_d1_sp, thiem_d1_dp
END INTERFACE thiem
! ------------------------------------------------------------------
! NAME
! theis
! PURPOSE
! Calculates the theis solution h(r) for transient flow and homogenous aquifers.
! Use either unstructured Radius-Time-points with "grid" or get a structured Radius-Time grid with "rad" and "time".
! CALLING SEQUENCE
! out = theis(rad, time, params, inits) or
! out = theis(grid, params, inits)
! INTENT(IN)
! [REAL(sp/dp),DIMENSION(:,2) :: grid Grid-Points : input radius-time-points in (m,s)]
! REAL(sp/dp),[DIMENSION(:)] :: rad Radius : input radius in m
! REAL(sp/dp),[DIMENSION(:)] :: time Time : input time in s
! REAL(sp/dp), DIMENSION(2) :: params Parameters
! params(1) : specific storage-coef. S in m^3
! params(2) : hydraulic conductivity K in m/s
! REAL(sp/dp), DIMENSION(2) :: inits Initial values
! inits(1) : pumping rate at the well Q in m^3/s
! inits(2) : aquifer thickness L in m
! INTENT(INOUT)
! None
! INTENT(OUT)
! None
! INTENT(IN), OPTIONAL
! None
! INTENT(INOUT), OPTIONAL
! None
! INTENT(OUT), OPTIONAL
! None
! RETURNS
!> \return REAL(sp/dp) :: theis hydraulic head in m
! RESTRICTIONS
! 1) Input values must be floating points.
! 2) rad > 0 [radius]
! 3) time > 0 [time]
! 4) params(1) > 0 [storage coefficient]
! 5) params(2) > 0 [conductivity]
! 6) inits(2) > 0 [aqifer thickness]
! EXAMPLE
! rad = 0.5
! time = 0.5
! inits = (/ -0.001 , 1.0 /)
! params = (/ 0.001 , 0.0001 /)
! h = theis(rad, time, inits, params )
! -> see also example in test directory
! LITERATURE
! None
! HISTORY
! Written, Sebastian Mueller, Apr 2014
INTERFACE theis
MODULE PROCEDURE theis_sp, theis_dp, theis_d1_sp, theis_d1_dp, theis_grid_sp, theis_grid_dp
END INTERFACE theis
! ------------------------------------------------------------------
! NAME
! ext_thiem2d
! PURPOSE
! Calculates the extended Thiem solution h(r) steady-state and heterogenous aquifers
! in 2 dimensions.
! CALLING SEQUENCE
! out = ext_thiem2d(rad, params, inits, prop)
! INTENT(IN)
! REAL(sp/dp),[DIMENSION(:)] :: rad Radius : input radius in m
! REAL(sp/dp), DIMENSION(3) :: params Parameters
! params(1) : geom-mean transmissivity T_G in m^2/s
! params(2) : variance of log-trans.
! params(3) : correlation length l in m
! REAL(sp/dp), DIMENSION(3) :: inits Initial values
! inits(1) : reference point radius R in m
! inits(2) : reference head H in m
! inits(3) : pumping rate at the well Q in m^3/s
! INTENT(INOUT)
! None
! INTENT(OUT)
! None
! INTENT(IN), OPTIONAL
! REAL(sp/dp) :: prop proportionality factor
! default=2.0
! INTENT(INOUT), OPTIONAL
! None
! INTENT(OUT), OPTIONAL
! None
! RETURNS
!> \return REAL(sp/dp) :: ext_thiem2d hydraulic head in m
! RESTRICTIONS
! 1) Input values must be floating points.
! 2) rad > 0 [radius]
! 3) inits(1) > 0 [reference radius]
! 4) params(1) > 0 [transmissivity]
! 5) params(2) > 0 [variance]
! 6) params(3) > 0 [correlation length]
! EXAMPLE
! rad = 0.5
! inits = (/ 32.0 , 0.0 , -0.001 /)
! params = (/ 0.0001 , 1.0 , 10.0 /)
! h = ext_thiem2d(rad, inits, params )
! -> see also example in test directory
! LITERATURE
! [1] Zech et al. 2012 The extended Thiem's solution -Including the Impact
! of heterogeneity, WRR
! HISTORY
! Written, Sebastian Mueller, Apr 2014
INTERFACE ext_thiem2d
MODULE PROCEDURE ext_thiem2d_sp, ext_thiem2d_dp, ext_thiem2d_d1_sp, ext_thiem2d_d1_dp
END INTERFACE ext_thiem2d
! ------------------------------------------------------------------
! NAME
! ext_thiem3d
! PURPOSE
! Calculates the extended Thiem solution h(r) steady-state and heterogenous aquifers
! in 3 dimensions with anisotropical impact.
! CALLING SEQUENCE
! out = ext_thiem3d(rad, params, inits, BC, prop)
! INTENT(IN)
! REAL(sp/dp),[DIMENSION(:)] :: rad Radius : input radius in m
! REAL(sp/dp), DIMENSION(4) :: params Parameters
! params(1) : geom.-mean conductivity K_G in m^2/s
! params(2) : variance of log-cond.
! params(3) : correlation length l in m
! params(4) : anisotropy ratio e
! REAL(sp/dp), DIMENSION(4) :: inits Initial values
! inits(1) : reference point radius R in m
! inits(2) : reference head H in m
! inits(3) : pumping rate at the well Q in m^3/s
! inits(4) : aquifer thickness L in m
! INTENT(INOUT)
! None
! INTENT(OUT)
! None
! INTENT(IN), OPTIONAL
! REAL(sp/dp) :: prop prop-factor for harmonic boundary-condition
! the arithmetic case will be automatically corrected
! default=1.6
! LOGICAL :: BC kind of the boundary-condition
! (harmonic: true[default]; arithmetic: false)
! INTENT(INOUT), OPTIONAL
! None
! INTENT(OUT), OPTIONAL
! None
! RETURNS
!> \return REAL(sp/dp) :: ext_thiem3d hydraulic head in m
! RESTRICTIONS
! 1) Input values must be floating points.
! 2) rad > 0 [radius]
! 3) inits(1) > 0 [reference radius]
! 4) params(1) > 0 [conductivity]
! 5) params(2) > 0 [variance]
! 6) params(3) > 0 [correlation length]
! 7) params(4) in [0,1] [anisotropy ratio]
! 8) inits(4) > 0 [aquifer thickness]
! EXAMPLE
! rad = 0.5
! inits = (/ 32.0 , 0.0 , -0.001 , 1.0 /)
! params = (/ 0.0001 , 1.0 , 10.0 , 1.0 /)
! h = ext_thiem3d(rad, inits, params )
! -> see also example in test directory
! LITERATURE
! [1] Zech et al. 2012 The extended Thiem's solution -Including the Impact
! of heterogeneity, WRR
! HISTORY
! Written, Sebastian Mueller, Apr 2014
INTERFACE ext_thiem3d
MODULE PROCEDURE ext_thiem3d_sp, ext_thiem3d_dp, ext_thiem3d_d1_sp, ext_thiem3d_d1_dp
END INTERFACE ext_thiem3d
! ------------------------------------------------------------------
! NAME
! ext_theis3d
! PURPOSE
! Calculates the extended Theis solution h(r) transient-state and heterogenous aquifers
! in 3 dimensions with anisotropical impact. Use either unstructured Radius-Time-points
! with "grid" or get a structured Radius-Time grid with "rad" and "time".
! CALLING SEQUENCE
! out = ext_theis3d(rad, time, params, inits, BC, prop, grad, steh_n, output) or
! out = ext_theis3d(grid, params, inits, BC, prop, grad, steh_n, output)
! INTENT(IN)
! [REAL(sp/dp),DIMENSION(:,2) :: grid Grid-Points : input radius-time-points in (m,s)]
! REAL(sp/dp),[DIMENSION(:)] :: rad Radius : input radius in m
! REAL(sp/dp),[DIMENSION(:)] :: time Time : input radius in m
! REAL(sp/dp), DIMENSION(5) :: params Parameters
! params(1) : geometric mean conductivity in m^2/s
! params(2) : variance of log-conductivity
! params(3) : correlation length in m
! params(4) : specific storage coefficient in m^3
! params(5) : anisotropy ratio
! REAL(sp/dp), DIMENSION(2) :: inits Initial values
! inits(1) : pumping rate at the well in m^3/s
! inits(2) : aquifer thickness in m
! INTENT(INOUT)
! None
! INTENT(OUT)
! None
! INTENT(IN), OPTIONAL
! REAL(sp/dp) :: prop prop-factor for harmonic boundary-condition
! the arithmetic case will be automatically corrected
! default=1.6
! LOGICAL :: BC kind of the boundary-condition
! (harmonic: true[default]; arithmetic: false)
! LOGICAL :: output gives information about the calculation during the computation
! default=false
! INTEGER(i4) :: grad limit of the series expansion for the analytical functions
! default=40 (recommended)
! INTEGER(i4) :: steh_n boundary-value for the stehfest-algorithm (numerical laplace-inversion)
! default=6 (recommended, for fast computation)
! INTENT(INOUT), OPTIONAL
! None
! INTENT(OUT), OPTIONAL
! None
! RETURNS
!> \return REAL(sp/dp) :: ext_theis3d hydraulic head in m
! RESTRICTIONS
! 1) Input values must be floating points.
! 2) rad > 0 [radius]
! 3) time > 0 [time]
! 4) inits(1) < 0 [pumping rate]
! 5) inits(2) > 0 [aquifer thickness]
! 6) params(1) > 0 [conductivity]
! 7) params(2) > 0 [variance]
! 8) params(3) > 0 [correlation length]
! 9) params(4) > 0 [storage coefficient]
! 10) params(5) in [0,1] [anisotropy ratio]
! EXAMPLE
! rad = 0.5
! time = 50.0
! inits = (/-0.001, 1.0/)
! params = (/0.0001, 1.0, 10.0, 0.001, 1.0/)
! h = ext_theis3d(rad, time, inits, params )
! -> see also example in test directory
! LITERATURE
! [1] ?
! HISTORY
! Written, Sebastian Mueller, Oct 2015
! Modified, Matthias Cuntz, Sep 2016 - move g3D_dp outside of function
INTERFACE ext_theis3d
MODULE PROCEDURE ext_theis3d_sp, ext_theis3d_dp, ext_theis3d_sp_d1, ext_theis3d_dp_d1, ext_theis3d_grid_sp, ext_theis3d_grid_dp
END INTERFACE ext_theis3d
! ------------------------------------------------------------------
! NAME
! ext_theis2d
! PURPOSE
! Calculates the extended Theis solution h(r) transient-state and heterogenous aquifers in 2 dimensions.
! Use either unstructured Radius-Time-points with "grid" or get a structured Radius-Time grid with "rad" and "time".
! CALLING SEQUENCE
! out = ext_theis2d(rad, time, params, inits, prop, grad, steh_n, output) or
! out = ext_theis2d(grid, params, inits, prop, grad, steh_n, output)
! INTENT(IN)
! [REAL(sp/dp),DIMENSION(:,2) :: grid Grid-Points : input radius-time-points in (m,s)]
! REAL(sp/dp),[DIMENSION(:)] :: rad Radius : input radius in m
! REAL(sp/dp),[DIMENSION(:)] :: time Time : input radius in m
! REAL(sp/dp), DIMENSION(4) :: params Parameters
! params(1) : geometric mean transmissivity in m^2/s
! params(2) : variance of log-conductivity
! params(3) : correlation length in m
! params(4) : specific storage coefficient in m^3
! REAL(sp/dp), DIMENSION(1) :: inits Initial values
! inits(1) : pumping rate at the well in m^3/s
! INTENT(INOUT)
! None
! INTENT(OUT)
! None
! INTENT(IN), OPTIONAL
! REAL(sp/dp) :: prop proportionality-factor
! default=2.0
! LOGICAL :: output gives information about the calculation during the computation
! default=false
! INTEGER(i4) :: grad limit of the series expansion for the analytical functions
! default=40 (recommended)
! INTEGER(i4) :: steh_n boundary-value for the stehfest-algorithm (numerical laplace-inversion)
! default=6 (recommended, for fast computation)
! INTENT(INOUT), OPTIONAL
! None
! INTENT(OUT), OPTIONAL
! None
! RETURNS
!> \return REAL(sp/dp) :: ext_theis2d hydraulic head in m
! RESTRICTIONS
! 1) Input values must be floating points.
! 2) rad > 0 [radius]
! 3) time > 0 [time]
! 4) params(1) > 0 [transmissivity]
! 5) params(2) > 0 [variance]
! 6) params(3) > 0 [correlation length]
! 7) params(4) > 0 [storage coefficient]
! EXAMPLE
! rad = 0.5
! time = 50.0
! inits = (/ -0.001 /)
! params = (/0.0001, 1.0, 10.0, 0.001/)
! h = ext_theis2d(rad, time, inits, params )
! -> see also example in test directory
! LITERATURE
! [1] ?
! HISTORY
! Written, Sebastian Mueller, Oct 2015
! Modified, Matthias Cuntz, Sep 2016 - move g2D_dp outside of function
INTERFACE ext_theis2d
MODULE PROCEDURE ext_theis2d_sp, ext_theis2d_dp, ext_theis2d_sp_d1, ext_theis2d_dp_d1, ext_theis2d_grid_sp, ext_theis2d_grid_dp
END INTERFACE ext_theis2d
! ------------------------------------------------------------------
PRIVATE
! ------------------------------------------------------------------
CONTAINS
!thiem solution
FUNCTION thiem_sp(rad, params, inits)
IMPLICIT NONE
REAL(sp), INTENT(IN) :: rad
REAL(sp), DIMENSION(1), INTENT(IN) :: params !params=(K)
REAL(sp), DIMENSION(4), INTENT(IN) :: inits !inits=(Ref,href,Qw,L)
REAL(sp) :: thiem_sp
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (le(rad, 0.0_sp)) stop 'Radius must be positiv!'
if (le(inits(1), 0.0_sp)) stop 'Reference point must be at a positiv radius.'
if (le(params(1), 0.0_sp)) stop 'The conductivity must be positiv.'
if (le(inits(4), 0.0_sp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
thiem_sp = (-inits(3)/(2.0_sp*PI*inits(4)*params(1))) * log(rad/inits(1)) + inits(2)
END FUNCTION thiem_sp
FUNCTION thiem_dp(rad, params, inits)
IMPLICIT NONE
REAL(dp), INTENT(IN) :: rad
REAL(dp), DIMENSION(1), INTENT(IN) :: params !params=(K)
REAL(dp), DIMENSION(4), INTENT(IN) :: inits !inits=(Ref,href,Qw,L)
REAL(dp) :: thiem_dp
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (le(rad, 0.0_dp)) stop 'Radius must be positiv!'
if (le(inits(1), 0.0_dp)) stop 'Reference point must be at a positiv radius.'
if (le(params(1), 0.0_dp)) stop 'The conductivity must be positiv.'
if (le(inits(4), 0.0_dp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! setting of the intern variables
! ------------------------------------------------------------------
thiem_dp = (-inits(3)/(2.0_dp*PI_D*inits(4)*params(1))) * log(rad/inits(1)) + inits(2)
END FUNCTION thiem_dp
FUNCTION thiem_d1_sp(rad, params, inits)
IMPLICIT NONE
REAL(sp), DIMENSION(:), INTENT(IN) :: rad
REAL(sp), DIMENSION(1), INTENT(IN) :: params !params=(K)
REAL(sp), DIMENSION(4), INTENT(IN) :: inits !inits=(Ref,href,Qw,L)
REAL(sp), DIMENSION(size(rad)) :: thiem_d1_sp
INTEGER(i4) :: i
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (.not. all(rad>0.0_sp)) stop 'Radius must be positiv!'
if (le(inits(1), 0.0_sp)) stop 'Reference point must be at a positiv radius.'
if (le(params(1), 0.0_sp)) stop 'The conductivity must be positiv.'
if (le(inits(4), 0.0_sp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
do i=1_i4, size(rad)
thiem_d1_sp(i) = thiem_sp(rad(i), params, inits)
end do
END FUNCTION thiem_d1_sp
FUNCTION thiem_d1_dp(rad, params, inits)
IMPLICIT NONE
REAL(dp), DIMENSION(:), INTENT(IN) :: rad
REAL(dp), DIMENSION(1), INTENT(IN) :: params !params=(K)
REAL(dp), DIMENSION(4), INTENT(IN) :: inits !inits=(Ref,href,Qw,L)
REAL(dp), DIMENSION(size(rad)) :: thiem_d1_dp
INTEGER(i4) :: i
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (.not. all(rad>0.0_dp)) stop 'Radius must be positiv!'
if (le(inits(1), 0.0_dp)) stop 'Reference point must be at a positiv radius.'
if (le(params(1), 0.0_dp)) stop 'The conductivity must be positiv.'
if (le(inits(4), 0.0_dp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
do i=1_i4, size(rad)
thiem_d1_dp(i) = thiem_dp(rad(i), params, inits)
end do
END FUNCTION thiem_d1_dp
!theis solution
FUNCTION theis_sp(rad, time, params, inits)
USE mo_nr, ONLY: expint
IMPLICIT NONE
REAL(sp), INTENT(IN) :: rad, time
REAL(sp), DIMENSION(2), INTENT(IN) :: params !params=(S,K)
REAL(sp), DIMENSION(2), INTENT(IN) :: inits !inits=(Qw,L)
REAL(sp) :: theis_sp
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (le(rad, 0.0_sp)) stop 'The radius must be positiv.'
if (time .LT. 0.0_sp) stop 'The time must be non-negativ.'
if (le(params(1), 0.0_sp)) stop 'The specific storage coefficient must be positiv.'
if (le(params(2), 0.0_sp)) stop 'The conductivity must be positiv.'
if (le(inits(2), 0.0_sp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
if (.not. eq(time, 0.0_sp)) then
theis_sp = (inits(1)/(4.0_sp*PI*inits(2)*params(2))) &
* expint(1_i4,((rad**2_i4)*params(1))/(4.0_sp*params(2)*time))
else
theis_sp = 0.0_sp
end if
END FUNCTION theis_sp
FUNCTION theis_dp(rad, time, params, inits)
USE mo_nr, ONLY: expint
IMPLICIT NONE
REAL(dp), INTENT(IN) :: rad, time
REAL(dp), DIMENSION(2), INTENT(IN) :: params !params=(S,K)
REAL(dp), DIMENSION(2), INTENT(IN) :: inits !inits=(Qw,L)
REAL(dp) :: theis_dp
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (le(rad, 0.0_dp)) stop 'The radius must be positiv.'
if (time .LT. 0.0_dp) stop 'The time must be non-negativ.'
if (le(params(1), 0.0_dp)) stop 'The specific storage coefficient must be positiv.'
if (le(params(2), 0.0_dp)) stop 'The conductivity must be positiv.'
if (le(inits(2), 0.0_dp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
if (.not. eq(time, 0.0_dp)) then
theis_dp = (inits(1)/(4.0_dp*PI_D*inits(2)*params(2))) &
* expint(1_i4,((rad**2_i4)*params(1))/(4.0_dp*params(2)*time))
else
theis_dp = 0.0_dp
end if
END FUNCTION theis_dp
FUNCTION theis_d1_sp(rad, time, params, inits)
IMPLICIT NONE
REAL(sp), DIMENSION(:), INTENT(IN) :: rad
REAL(sp), DIMENSION(:), INTENT(IN) :: time
REAL(sp), DIMENSION(2), INTENT(IN) :: params !params=(S,K)
REAL(sp), DIMENSION(2), INTENT(IN) :: inits !inits=(Qw,L)
REAL(sp), DIMENSION(size(rad),size(time)) :: theis_d1_sp
INTEGER(i4) :: i, j
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (.not. all(rad>0.0_sp)) stop 'The radius must be positiv.'
if ( any(time<0.0_sp)) stop 'The time must be non-negativ.'
if (le(params(1), 0.0_sp)) stop 'The specific storage coefficient must be positiv.'
if (le(params(2), 0.0_sp)) stop 'The conductivity must be positiv.'
if (le(inits(2), 0.0_sp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
do i=1_i4, size(rad)
do j=1_i4, size(time)
theis_d1_sp(i,j) = theis_sp(rad(i), time(j), params, inits)
end do
end do
END FUNCTION theis_d1_sp
FUNCTION theis_d1_dp(rad, time, params, inits)
IMPLICIT NONE
REAL(dp), DIMENSION(:), INTENT(IN) :: rad
REAL(dp), DIMENSION(:), INTENT(IN) :: time
REAL(dp), DIMENSION(2), INTENT(IN) :: params !params=(S,K)
REAL(dp), DIMENSION(2), INTENT(IN) :: inits !inits=(Qw,L)
REAL(dp), DIMENSION(size(rad),size(time)) :: theis_d1_dp
INTEGER(i4) :: i, j
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (.not. all(rad>0.0_dp)) stop 'The radius must be positiv.'
if ( any(time<0.0_dp)) stop 'The time must be non-negativ.'
if (le(params(1), 0.0_dp)) stop 'The specific storage coefficient must be positiv.'
if (le(params(2), 0.0_dp)) stop 'The conductivity must be positiv.'
if (le(inits(2), 0.0_dp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
do i=1_i4, size(rad)
do j=1_i4, size(time)
theis_d1_dp(i,j) = theis_dp(rad(i), time(j), params, inits)
end do
end do
END FUNCTION theis_d1_dp
FUNCTION theis_grid_sp(grid, params, inits)
IMPLICIT NONE
REAL(sp), DIMENSION(:,:), INTENT(IN) :: grid !Radius-Time points
REAL(sp), DIMENSION(2), INTENT(IN) :: params !params=(S,K)
REAL(sp), DIMENSION(2), INTENT(IN) :: inits !inits=(Qw,L)
REAL(sp), DIMENSION(size(grid(:,1))) :: theis_grid_sp
INTEGER(i4) :: i
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (size(grid(1,:)) .ne. 2_i4) stop 'grid should contain 2 information: radius and time'
if (.not. all(grid(:,1)>0.0_sp)) stop 'The radius must be positiv.'
if ( any(grid(:,2)<0.0_sp)) stop 'The time must be non-negativ.'
if (le(params(1), 0.0_sp)) stop 'The specific storage coefficient must be positiv.'
if (le(params(2), 0.0_sp)) stop 'The conductivity must be positiv.'
if (le(inits(2), 0.0_sp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
do i=1_i4, size(theis_grid_sp)
theis_grid_sp(i) = theis_sp(grid(i,1), grid(i,2), params, inits)
end do
END FUNCTION theis_grid_sp
FUNCTION theis_grid_dp(grid, params, inits)
IMPLICIT NONE
REAL(dp), DIMENSION(:,:), INTENT(IN) :: grid !Radius-Time points
REAL(dp), DIMENSION(2), INTENT(IN) :: params !params=(S,K)
REAL(dp), DIMENSION(2), INTENT(IN) :: inits !inits=(Qw,L)
REAL(dp), DIMENSION(size(grid(:,1))) :: theis_grid_dp
INTEGER(i4) :: i
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (size(grid(1,:)) .ne. 2_i4) stop 'grid should contain 2 information: radius and time'
if (.not. all(grid(:,1)>0.0_dp)) stop 'The radius must be positiv.'
if ( any(grid(:,2)<0.0_dp)) stop 'The time must be non-negativ.'
if (le(params(1), 0.0_dp)) stop 'The specific storage coefficient must be positiv.'
if (le(params(2), 0.0_dp)) stop 'The conductivity must be positiv.'
if (le(inits(2), 0.0_dp)) stop 'The aquifer thickness must be positiv.'
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
do i=1_i4, size(theis_grid_dp)
theis_grid_dp(i) = theis_dp(grid(i,1), grid(i,2), params, inits)
end do
END FUNCTION theis_grid_dp
!extended thiems solution
!2D
FUNCTION ext_thiem2d_sp(rad, params, inits, prop)
USE mo_nr, ONLY: ei, expint
IMPLICIT NONE
REAL(sp), INTENT(IN) :: rad
REAL(sp), DIMENSION(3), INTENT(IN) :: params, inits !params=(TG,var,corr); inits=(Ref,href,Qw)
REAL(sp), OPTIONAL, INTENT(IN) :: prop !proportionality factor [default=2]
REAL(sp) :: ext_thiem2d_sp
REAL(sp) :: sub1, sub2, pr
! sub1/2: are just substitutions to make the formula a bit shorter
! pr: is the intern proportionality factor
! ------------------------------------------------------------------
! input tests
! ------------------------------------------------------------------
if (le(rad, 0.0_sp)) stop 'Radius must be positiv.'
if (le(inits(1), 0.0_sp)) stop 'Reference point must be at a positiv radius.'
if (le(params(1), 0.0_sp)) stop 'The transmissivity must be positiv.'
if (le(params(2), 0.0_sp)) stop 'The variance must be positiv.'
if (le(params(3), 0.0_sp)) stop 'The correlation length must be positiv.'
if (present(prop)) then
if (le(prop, 0.0_sp)) stop 'The proportionality factor must be positiv.'
pr = prop
else
pr = 2.0_sp
endif
! ------------------------------------------------------------------
! setting of the intern variables
! ------------------------------------------------------------------
sub1 = (params(2)/2.0_sp)/( 1.0_sp+(pr*rad/params(3))**2_i4 )
sub2 = (params(2)/2.0_sp)/( 1.0_sp+(pr*inits(1)/params(3))**2_i4 )
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
ext_thiem2d_sp = -(inits(3)/(4.0_sp*PI*params(1)))*&
(&
( ei( ((pr*rad/params(3))**2_i4)*sub1 ) -&
ei( ((pr*inits(1)/params(3))**2_i4)*sub2 )&
) + &
exp(params(2)/2.0_sp)*&
(&
expint( 1_i4, sub1 ) -&
expint( 1_i4, sub2 )&
)&
)&
+ inits(2)
END FUNCTION ext_thiem2d_sp
FUNCTION ext_thiem2d_dp(rad, params, inits, prop)
USE mo_nr, ONLY: ei, expint
IMPLICIT NONE
REAL(dp), INTENT(IN) :: rad
REAL(dp), DIMENSION(3), INTENT(IN) :: params, inits !params=(TG,var,corr); inits=(Ref,href,Qw)
REAL(dp), OPTIONAL, INTENT(IN) :: prop !proportionality factor [default=2]
REAL(dp) :: ext_thiem2d_dp
REAL(dp) :: sub1, sub2, pr
! sub1/2: are just substitutions to make the formula a bit shorter
! pr: is the intern proportionality factor
! ------------------------------------------------------------------
! Input tests
! ------------------------------------------------------------------
if (le(rad, 0.0_dp)) stop 'Radius must be positiv.'
if (le(inits(1), 0.0_dp)) stop 'Reference point must be at a positiv radius.'
if (le(params(1), 0.0_dp)) stop 'The transmissivity must be positiv.'
if (le(params(2), 0.0_dp)) stop 'The variance must be positiv.'
if (le(params(3), 0.0_dp)) stop 'The correlation length must be positiv.'
if (present(prop)) then
if (le(prop, 0.0_dp)) stop 'The proportionality factor must be positiv.'
pr = prop
else
pr = 2.0_dp
endif
! ------------------------------------------------------------------
! setting of the intern variables
! ------------------------------------------------------------------
sub1 = (params(2)/2.0_dp)/( 1.0_dp+(pr*rad/params(3))**2_i4 )
sub2 = (params(2)/2.0_dp)/( 1.0_dp+(pr*inits(1)/params(3))**2_i4 )
! ------------------------------------------------------------------
! calculate the head
! ------------------------------------------------------------------
ext_thiem2d_dp = -(inits(3)/(4.0_dp*PI_D*params(1)))*&
(&
( ei( ((pr*rad/params(3))**2_i4)*sub1 ) -&
ei( ((pr*inits(1)/params(3))**2_i4)*sub2 )&
) + &
exp(params(2)/2.0_dp)*&
(&
expint( 1_i4, sub1 ) -&
expint( 1_i4, sub2 )&
)&
)&
+ inits(2)
END FUNCTION ext_thiem2d_dp