build.gradle

plugins {
    id 'my.java-application-conventions'
    id 'my.java-oldschool-project-structure'
    id 'my.encoding.8859-1'
}
apply from: "${rootProject.rootDir}/gradle/url_file.gradle"
apply from: "${rootProject.rootDir}/gradle/download_swt.gradle"

group 'de.willuhn.jameica'
version '2.8-SNAPSHOT'

application {
    // Define the main class for the application.
    mainClass = 'de.willuhn.jameica.Main'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(8)
    }
}

dependencies {
    implementation project(':lib:util')
    implementation project(':lib:datasource')

    implementation libs.bundles.bouncycastle
    implementation libs.bundles.javaee
    implementation libs.apache.commons.lang
    implementation libs.apache.commons.cli
    implementation libs.apache.velocity
    implementation libs.javax.annotation
    implementation libs.eclipse.jface
    implementation libs.eclipse.ui.forms
    implementation libs.nanoxml
    implementation swt.platform

    // Printing plug-in for SWT. See <https://code.google.com/archive/p/swt-paperclips/> (last update: 2009-08-12)
    implementation urlFile('paperclips-1.0.4', 'https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/swt-paperclips/net.sf.paperclips_1.0.4.200908120926.jar')
}

// solange noch die Logik des ANT-Builds benötigt wird, nutze einen Unterordner
buildDir = file("./build/gradle/")
jar {
    baseName "de_willuhn_${project.name}"
    manifest {
        attributes "Main-Class": "de.willuhn.jameica.Main"
    }
}