Examples of Windows kernel drivers built using Meson

[amcnulty-fermat]

Hello Meson community,

I was wondering if anyone knows of a Windows kernel driver that is built with Meson?

For context, I am trying to migrate an old build system (which is a mix of make, cmake, shellscripts on Linux, and Powershell on Windows) to a new build system, one in which everything is built via Meson. The project contains a Windows kernel driver that is currently built via msbuild and a Visual Studio solution file. The old system simply invokes msbuild and lets msbuild conduct the build tasks according to the Visual Studio solution file.

My current approach is to use custom_target to invoke msbuild with the Visual Studio solution file which then handles all the details of the kernel driver build. Ideally I would like to be able to write Meson build definitions to replace the Visual Studio solution file entirely. Does anybody have experience doing something like this, and if so, do they have any advice?

I have toyed with the idea of implementing a function in Meson's Windows module to help generate all the necessary build steps but I figured I would ask the community for advice first. If such a function were to exist, would others find it useful?

Finally, I would like to thank you all for your work on Meson as it has been a very pleasant and conscientious partner in this undertaking.

[xclaesse]

I never built a Windows driver, but any chance this could work?

shared_library('mydriver', ..., link_args: '/DRIVER:WDM')

https://learn.microsoft.com/en-us/cpp/build/reference/driver-windows-nt-kernel-mode-driver

[xclaesse]

Looks like Cargo can do it for Rust drivers, they document a bit the linker args that could be useful: https://codentium.com/guides/windows-dev/windows-drivers-in-rust-hello-world/

[xclaesse]

If we can figure out what are the steps, would be nice to wrap that into a new method in Meson's windows module. Let us know if you can make it work, that Rust example seems to explain every steps including signing.

[amcnulty-fermat]

Thank you for bringing cargo's support for this to my attention. I hadn't thought to look there. I had looked at what exists in CMake for this and there seems to be a FindWDK.cmake in relatively widespread use but it doesn't handle all the tasks that MSBuild does.

I will take a look at cargo's implementation, and try and get a sense of what it would take to implement something similar in Meson.

[xclaesse]

My understanding is that Cargo doesn't do anything special, it just let user specify every linker args manually. Meson can do that too, so it should work the same way. Maybe override_options: 'buildtype=plain' is needed to make sure Meson does not add its own compiler flags which could clash with those you inject manually... it require some testing to be sure.

[amcnulty-fermat]

The WDK headers require a number of extra defines as well as far as I can tell, specifically the target CPU architecture, the version of Windows that one is targeting, and the version of NTDDI.

SergiusTheBest's FindWDK.cmake seems to have a worked out the list of definitions needed.

[nathankidd]

Here is a better-than-nothing example that builds a kernel driver.

• Distilled (untested) from larger tested project.
• Compiler and linker args are based off of an old DDK.7600 project, but are roughly a superset of FindWDK.cmake.
• For modern development it would be preferable to examine the arguments VS gives to a driver project.
• Versions targeted are somewhat odd, because it needed to exactly match another driver's specs

project('mydriver', 'c', 'cpp', meson_version: '>= 0.64.0',
    default_options:['c_std=c99', 'cpp_std=vc++20', 'buildtype=release', 'b_vscrt=static_from_buildtype',
        'bindir=.', 'libdir=.', 'localedir=locale', 'b_ndebug=if-release', 'c_winlibs=', 'warning_level=2',
        'optimization=0'])

if host_machine.system() != 'windows'
    error('This project only builds on windows')
endif
if host_machine.cpu_family() == 'aarch64'
    wdkplat = 'arm64'
elif host_machine.cpu_family() == 'x86_64'
    wdkplat = 'x64'
else
    error('Unsupported platform in meson.build!')
endif

install_dir = meson.project_build_root() / 'driver'

wdkver = get_variable('wdkver', '10.0.19041.0')
wdkroot = get_variable('wdkroot', 'C:\\Program Files (x86)\\Windows Kits\\10')
message('Using WDK ' + wdkver + ' from ' + wdkroot)
wdkinc = [
    include_directories(wdkroot / 'Include' / wdkver / 'shared'),
    include_directories(wdkroot / 'Include' / wdkver / 'km'),
    include_directories(wdkroot / 'Include' / wdkver / 'km/crt'),
]
wdklib = wdkroot / 'Lib' / wdkver / 'km' / wdkplat

plat_cflags = []
if host_machine.cpu_family() == 'aarch64'
    plat_cflags += [
        '/D_WIN64',
        '/D_ARM64_',
        '/DARM64',
    ]
elif host_machine.cpu_family() == 'x86_64'
    plat_cflags += [
        '/D_WIN64',
        '/D_AMD64_',
        '/DAMD64',
        '/Gz',  # default __stdcall
    ]
endif

# These compile and link flags come from old DDK's TARGETTYPE=DRIVER
drv_cflags = [
    '/D_NO_CRT_STDIO_INLINE', # unresolved external symbol __stdio_common_vswprintf on newer DDKs
    '/DWIN32',
    '/DWINVER=0x602',
    '/D_WIN32_WINNT=0x602', # TODO make it match below?
    '/DNTDDI_VERSION=NTDDI_WIN10',
    '/DWIN32_LEAN_AND_MEAN=1',

    '/WX',  # error on warning
    '/GS',  # security checks
    '/GF',  # read-only string pooling
    '/GR-', # no RTTI
    '/Gy',  # separate functions for linker
    '/Zp8', # pack structures
    '/Zl',  # omit default library name in obj
    '/kernel',      # kernel mode binary
    '/FIwarning.h', # disable warnings in WDK headers
]

drv_ldflags = [
    '/MERGE:_PAGE=PAGE',
    '/MERGE:_TEXT=.text',
    '/SECTION:INIT,d',
    '/OPT:REF',
    '/OPT:ICF',
    '/IGNORE:4198,4010,4037,4039,4065,4070,4078,4087,4089,4221,4108,4088,4218,4218,4235',
    '/INCREMENTAL:NO',
    '/release', # TODO debug support
    '/NODEFAULTLIB',
    '/WX',
    '/debug',
    '/debugtype:cv,fixup,pdata',
    '/version:10.0',
    '/osversion:10.0',
    '/functionpadmin:6',
    '/pdbcompress',
    '/STACK:0x40000,0x1000',
    '/driver',
    '/base:0x1C0000000',
    '/LIBPATH:' + wdklib,
    'libcntpr.lib',
    # Original linked with hotpatch.obj, this is no longer provided for Windows 10 lib dirs, so presumably unnecessary    	
    '/entry:GsDriverEntry',
    'ntoskrnl.lib',
    'hal.lib',
    'wmilib.lib',
]

if host_machine.cpu_family() == 'aarch64'
    drv_ldflags += ['BufferOverflowfastfailK.lib']
else
    drv_ldflags += ['BufferOverflowK.lib']
endif

############################################

drv_src = [
  'mydriver.c',
]

drv_inc = [
    wdkinc,
    include_directories('.'),
]

windows = import('windows')
drv_res = windows.compile_resources('mydriver.rc', include_directories: [ drv_inc ])

mydriver = executable('mydriver',
            name_suffix: 'sys',
                sources: [drv_src, drv_res],
    include_directories: drv_inc,
                 c_args: drv_cflags,
              link_with: [],
              link_args: drv_ldflags,
          win_subsystem: 'native,6.01',
            install_dir: install_dir,
                install: true)