How to use include_directories() and cc.find_library() in generated code?

[nils-werner]

Hey,

I'm trying to port our existing build system to Meson and making very good progress so far. However one component is making me scratch my head a bit: It's a code generator from the Xilinx SDK that I have absolutely no control over. With a single command it generates a source-tree and a Makefile to build some libraries from those sources. I am of course able to run this generator from Meson, and also run the Makefile.

But then I need to find these libraries in the output directory, so I can link against them. And also I am required to have an include_directories() that points to a directory inside the generated code, and I'm struggling to achieve these two steps.

Right now I'm generating the code in my source-dir (which is bad of course) and get the structure to work using a meson.build file like

# Before this works I have to run
#
#    build.sh generated/
#    make -C generated/
# 

bsp_inc = include_directories(
    'generated/ps7_cortexa9_1/include/'
)

bsp_xil = cc.find_library(
    'xil',
    dirs : meson.current_source_dir() / 'generated/ps7_cortexa9_1/lib/'
)

bsp_dep = declare_dependency(
    include_directories : bsp_inc,
    dependencies : [
        bsp_xil,
    ]
)

I of course know how to run custom_target()s, but how would I translate the include dirs and libs to builddir-generation?

[dcbaker]

I don't suppose that external_project modules would fit what you're doing?

[nils-werner]

Unfortunately the builder is not autotools-based, and it doesn't understand prefixes, libdirs or incdirs...

[eli-schwartz]

It's a code generator from the Xilinx SDK that I have absolutely no control over. With a single command it generates a source-tree and a Makefile to build some libraries from those sources. I am of course able to run this generator from Meson, and also run the Makefile.

Are you able to run the generator using a custom current working directory to control the location it is produced in? Does it make sense to run a script as a meson target that both executes the code generator and the Makefile, and from meson's perspective only produces the library itself as an output?

Does the generator emit a complex directory structure of output files or are all produced outputs in the same directory? Are the output filenames predictable?

[nils-werner]

Are you able to run the generator using a custom current working directory to control the location it is produced in?

Yes, using a wrapper-script that moves things where I want them to end up.

Does it make sense to run a script as a meson target that both executes the code generator and the Makefile, and from meson's perspective only produces the library itself as an output?

Yes, but of course I need both the headers and the multiple output lib*.a files.

Does the generator emit a complex directory structure of output files or are all produced outputs in the same directory?

A complex structure with subdirectories.

Are the output filenames predictable?

Yes, but there are many.

[nils-werner]

Also I need access to a few filenames in particular for other build targets...

[nils-werner]

I kind of I got it to work with a build.sh similar to

#!/usr/bin/env bash

gen_src "${tmp_dir}"
make -C "${tmp_dir}"
mv "${tmp_dir}/lib/"* "${out_dir}"
mv "${tmp_dir}/include/"* "${out_dir}"

and a meson.build like

sh_script = find_program('./tools/build.sh')

bsp_libs = [
    'libxil.a',
]

# there are many more headers generated, these are the ones that seemed necessary
bsp_headers = [
    'sleep.h',
    'xil_io.h',
    'xparameters_ps.h',
]

bsp_misc = [
    'wrapper.bit',
]

bsp = custom_target(
    'bsp',
    input : [ hdf_file, 'system.mss' ],
    output : [
        bsp_misc,
        bsp_headers,
        bsp_libs,
    ],
    command : [
        sh_script,
        '@INPUT@',
        '@OUTDIR@'
    ],
)

bitfile = bsp[0]

but I don't really understand and trust it...