How to compile vcpkg libraries using Clang?

[BiliBiliFox]

Dear vcpkg team,

I am currently using vcpkg to manage dependencies for my project, and I must say it is an incredibly useful tool that has greatly enhanced my productivity. However, I have encountered an issue with compiler compatibility that I hope you can assist me with.

Issue Description:

My project requires compilation with the Clang compiler due to bugs I have encountered with MSVC, which prevent successful compilation. When I switch to using Clang, the compilation proceeds without issues. This has led me to conclude that the bugs are indeed with MSVC.

The problem arises when I attempt to link my project. Since my project is compiled with Clang, and the libraries installed via vcpkg are compiled with MSVC by default, I am experiencing ABI incompatibility issues.

My question is: Is there a way to configure vcpkg to use the Clang compiler for building libraries? This would ensure that both my project and the dependencies are compiled with the same compiler, thus avoiding ABI compatibility issues.

If this is not currently a supported feature, I would like to suggest considering adding support for the Clang compiler. This would make vcpkg more versatile and accommodating to a wider range of project requirements.

Thank you very much for your time and assistance!

Feel free to modify and expand on this draft based on your specific situation. Good luck with your issue!

[StarGate-One]

I think your question was answer in #38042.

[0xg0nz0]

The documentation is not at all clear about this and it is a roundabout solution as well, but I finally got this to work today. The solution comes in three parts:

1. Point CMake to a custom triplet directory with VCPKG_OVERLAY_TRIPLETS -- e.g. via CMakePresets.json:

{
    "version": 3,
    "configurePresets": [
        {
            "name": "default",
            "binaryDir": "${sourceDir}/build",
            "generator": "Ninja Multi-Config",
            "cacheVariables": {
                "CMAKE_EXPORT_COMPILE_COMMANDS": "ON",
                "VCPKG_OVERLAY_TRIPLETS": "${sourceDir}/toolchains"
            },
            "toolchainFile": "${sourceDir}/toolchains/bootstrap-toolchain.cmake"
        },
       ...

Note to avoid circular loading of the toolchain for use both in the main project and vcpkg, I needed to indirectly load the build system CMake file with toolchainFile set to bootstrap-toolchain.cmake:

include("${CMAKE_CURRENT_LIST_DIR}/clang-toolchain.cmake")
include("$ENV{VCPKG_ROOT}/scripts/buildsystems/vcpkg.cmake")

This ensures the compilation is done with clang and clang++ for the local project and sets up vcpkg.cmake as per usual.

2. Define a custom triplet that sets VCPKG_CHAINLOAD_TOOLCHAIN_FILE appropriately; because of problems with clang and liburing, below uses PORT to select gcc or clang toolchains:

set(VCPKG_CMAKE_SYSTEM_NAME Linux)
set(VCPKG_TARGET_ARCHITECTURE arm64)
set(VCPKG_CRT_LINKAGE dynamic)
set(VCPKG_LIBRARY_LINKAGE static)

if(${PORT} MATCHES "liburing")
    set(VCPKG_CHAINLOAD_TOOLCHAIN_FILE ${CMAKE_CURRENT_LIST_DIR}/gcc-toolchain.cmake)
else()
    set(VCPKG_CHAINLOAD_TOOLCHAIN_FILE ${CMAKE_CURRENT_LIST_DIR}/clang-toolchain.cmake)
endif()

3. Override your compiler settings in the toolchain file, e.g. for clang-toolchain.cmake:

set(CMAKE_C_COMPILER /usr/bin/clang CACHE FILEPATH "C compiler" FORCE)
set(CMAKE_CXX_COMPILER /usr/bin/clang++ CACHE FILEPATH "C++ compiler" FORCE)

For the vcpkg team: both documentation improvements and a look at liburing compilation failing under clang at the link stage -- it complains about being unable to reference memset as a symbol -- might be helpful to simplify this solution.