build.gradle

import java.text.SimpleDateFormat

buildscript {

    ext.commonProps = new Properties()
    file(new File(project.rootProject.projectDir,"config/common.properties")).withInputStream { commonProps.load(it) }
}

plugins {
    // id 'my-plugin' apply false
    id 'com.github.hierynomus.license' version '0.16.1' apply false
}

allprojects {

    repositories {
        maven { url 'https://jitpack.io' }
        mavenCentral()
        mavenLocal()
    }

    apply plugin: 'java'
    apply plugin: 'com.github.hierynomus.license'
    
    sourceCompatibility = 17
    targetCompatibility = 17
    [compileJava, compileTestJava]*.options*.release  = 17
    [compileJava, compileTestJava]*.options*.encoding = 'UTF-8'


    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
        options.encoding = 'UTF-8'
    }
    
    // compileTestJava.options.compilerArgs.add("--enable-preview")
    // compileTestJava.options.compilerArgs.add("-Xlint:preview")

    test {
        // jvmArgs=['--enable-preview']
        failFast = false
        testLogging {
            events "passed", "skipped", "failed", "standardOut", "standardError"
        }
    }

    license {
        header = rootProject.file('config/HEADER')
        strictCheck = true
        ignoreFailures = true

        mapping {
            java   = 'SLASHSTAR_STYLE'
            groovy = 'SLASHSTAR_STYLE'
            fxml   = 'XML_STYLE'
        }

        ext.yearCurrent  = new SimpleDateFormat("yyyy").format(new Date())
        ext.yearSince1   = '2019'
        ext.author1 = 'Michael Hoffer <info@michaelhoffer.de>'

        exclude '**/*.svg'
    }
}


wrapper {
    gradleVersion = '7.6.3'
}