build.gradle

plugins {
    id "java"
    id "idea"
    id "org.springframework.boot" version "${springBootVersion}"
    id "org.eclipse.jkube.kubernetes" version "${jkubeVersion}"
    id "com.diffplug.spotless" version "${spotlessVersion}"
    id "jacoco"
}

apply plugin: "io.spring.dependency-management"

repositories {
    mavenCentral()
    mavenLocal()
    maven { url "https://repo.spring.io/release" }
}

spotless {
    java {
        googleJavaFormat()
        trimTrailingWhitespace()
        endWithNewline()
    }

    groovyGradle {
        target "*.gradle", "**/*.gradle"
        trimTrailingWhitespace()
        indentWithSpaces(4)
        endWithNewline()
    }

    format "misc", {
        target "**/*.md", "**/*.yml"
        trimTrailingWhitespace()
        indentWithSpaces(2)
        endWithNewline()
    }

    lineEndings "UNIX"
}

sourceCompatibility = "17"
[compileJava, compileTestJava]*.options*.encoding = "UTF-8"
[compileJava, compileTestJava]*.options*.compilerArgs = ["-Xlint:all"]

dependencies {
    compileOnly "org.projectlombok:lombok"
    annotationProcessor "org.projectlombok:lombok"
    testCompileOnly "org.projectlombok:lombok"
    testAnnotationProcessor "org.projectlombok:lombok"

    implementation "org.springframework.boot:spring-boot-starter-validation"
    implementation "org.springframework.boot:spring-boot-starter-thymeleaf"
    implementation "org.springframework.boot:spring-boot-starter-mail"
    implementation "org.springframework.boot:spring-boot-starter-security"
    implementation "org.springframework.boot:spring-boot-starter-webflux"
    implementation "org.springframework.boot:spring-boot-starter-actuator"
    implementation "org.springframework.boot:spring-boot-starter-data-r2dbc"
    implementation "org.springframework.boot:spring-boot-starter-data-redis-reactive"
    implementation "org.springframework.session:spring-session-data-redis"
    developmentOnly "org.springframework.boot:spring-boot-devtools"
    developmentOnly "org.springframework.boot:spring-boot-docker-compose"

    implementation "com.fasterxml.jackson.module:jackson-module-parameter-names"
    implementation "com.fasterxml.jackson.datatype:jackson-datatype-jdk8"
    implementation "com.fasterxml.jackson.datatype:jackson-datatype-jsr310"
    implementation "com.fasterxml.jackson.dataformat:jackson-dataformat-csv"

    implementation "org.seasar.doma:doma-template:2.58.0"
    implementation "org.modelmapper:modelmapper:3.1.1"
    implementation "io.projectreactor.addons:reactor-extra"

    implementation "org.flywaydb:flyway-core"
    implementation "org.flywaydb:flyway-mysql"

    runtimeOnly "io.asyncer:r2dbc-mysql"
    runtimeOnly "com.mysql:mysql-connector-j"
    // runtimeOnly "io.r2dbc:r2dbc-postgresql"
    // runtimeOnly "org.postgresql:postgresql"

    implementation "nz.net.ultraq.thymeleaf:thymeleaf-layout-dialect"
    implementation "org.thymeleaf.extras:thymeleaf-extras-springsecurity6"
    implementation "org.webjars:webjars-locator-core"
    implementation "org.webjars:bootstrap:4.6.2"
    implementation "org.webjars:jquery:3.6.4"
    implementation "org.webjars:jquery-validation:1.19.5"
    implementation "org.webjars:bootstrap-daterangepicker:3.1"
    implementation "org.webjars:momentjs:2.29.4"
    implementation "org.webjars:AdminLTE:3.2.0"
    implementation "org.webjars:font-awesome:5.15.4"
    implementation "org.webjars:dropzone:5.9.2"

    testImplementation "org.springframework.boot:spring-boot-starter-test"
    testImplementation "org.springframework.boot:spring-boot-starter-data-r2dbc"
    testImplementation "org.springframework.security:spring-security-test"
    testImplementation "io.projectreactor:reactor-test"
    testImplementation "com.h2database:h2"

    testImplementation "org.springframework.boot:spring-boot-testcontainers"
    testImplementation "org.testcontainers:junit-jupiter"
    testImplementation "org.testcontainers:r2dbc"
    testImplementation "org.testcontainers:mysql"
    testImplementation "io.r2dbc:r2dbc-h2"

    testImplementation "org.assertj:assertj-core"
    testImplementation "org.mockito:mockito-core"

    runtimeOnly "org.springframework.boot:spring-boot-properties-migrator"
}

tasks.named("test") {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}

task sourceJar(type: Jar, dependsOn: classes) {
    archiveClassifier.set("sources")
    from sourceSets.main.allSource
}

compileJava.dependsOn "spotlessApply"
k8sBuild.dependsOn "build"
k8sResource.dependsOn "k8sBuild"
k8sApply.dependsOn "k8sResource"
jacocoTestReport.dependsOn "test"