-
Notifications
You must be signed in to change notification settings - Fork 28
/
Copy pathsnap.ulp
1177 lines (1117 loc) · 42 KB
/
snap.ulp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
//EAGLE ULP "snap.ulp"
//Copyright (c) 2012-07-09 Andreas Weidner
//
//Permission is hereby granted, free of charge, to any person obtaining a copy
//of this software and associated documentation files (the "Software"), to deal
//in the Software without restriction, including without limitation the rights
//to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
//copies of the Software, and to permit persons to whom the Software is
//furnished to do so, subject to the following conditions:
//
//The above copyright notice and this permission notice shall be included in
//all copies or substantial portions of the Software.
//
//THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
//IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
//FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
//AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
//LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
//OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
//SOFTWARE.
#require 5.0600
//Earlier EAGLE versions (from 5.0 upward) MAY be able to run this ULP, but
//were not properly tested
#usage "en: <table width=100% cellpadding=5 cellspacing=0 bgcolor=#E0E0E0>"
"<tr><td><h3>Snap objects to a grid</h3>\n"
"This program <b>moves objects</b> from schematics, boards or libraries, "
"so that their origins (or end points) are on a given grid. The grid "
"size and the objects to snap can be set with a dialog box or the command "
"line.<p>"
"<author>© 2012-07-09 Andreas Weidner</author></td></tr></table>"
"<br><br>"
"<b>Usage:</b><dl>"
"<dt><tt>RUN snap [<i>dx</i> [<i>dy</i>]] [group|sheet] [<i>objects</i>]"
"</tt></dt>"
"<dd>Sets the grid size to <b>dx</b> horizontally and <b>dy</b> "
"vertically. If <b>group</b> is used, only objects inside the current "
"group are moved, if <b>sheet</b> is used, only objects on the current "
"schematics sheet are moved. If no <b>objects</b> are given, a snap "
"dialog pops up. If <b>objects</b> are given, the snapping is done "
"immediately (without a dialog). For a list of allowed objects, see "
"below.</dd></dl>"
"<b>Examples:</b><dl>"
"<dt><tt>RUN snap</tt></dt>"
"<dd>Opens the snap dialog and lets the user set all options.</dd>"
"<dt><tt>RUN snap 0.1 0.2</tt></dt>"
"<dd>Sets the grid size to <b>0.1</b> horizontally and <b>0.2</b> "
"vertically and shows the snap dialog.</dd>"
"<dt><tt>RUN snap 0.05 group all</tt></dt>"
"<dd>Snaps <b>all</b> supported objects belonging to the currently "
"defined <b>group</b> to a grid of <b>0.05</b> in both directions.</dd>"
"</dl>"
"<b>Supported objects:</b><p>"
"<table border=0 cellspacing=2 cellpadding=3>"
"<tr><th bgcolor=#E0E0E0>Editor</th><th bgcolor=#E0E0E0>Objects</th>"
"<th bgcolor=#E0E0E0>Description</th></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=3>Schematic</th><td bgcolor=#EEEEEE><tt>"
"gates</tt></td><td bgcolor=#EEEEEE>Moves <b>gates</b> added from "
"libraries. Junctions and nets connected directly to the gate pins are "
"also moved.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>nets</tt></td><td bgcolor=#EEEEEE>Moves "
"<b>nets</b>, busses and junctions. Cross-reference labels connected "
"directly to net endpoints are also moved.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Moves "
"<b>all</b> of the above supported schematic objects.</td></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=3>Board</th><td bgcolor=#EEEEEE><tt>"
"elements</tt></td><td bgcolor=#EEEEEE>Moves <b>elements</b> added from "
"libraries. Vias and signal wires connected directly to the element pads "
"or SMDs are also moved.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>signals</tt></td><td bgcolor=#EEEEEE>Moves "
"<b>signal</b> wires, vias and polygons.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Moves "
"<b>all</b> of the above supported board objects.</td></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=2>Symbol</th><td bgcolor=#EEEEEE><tt>pins"
"</tt></td><td bgcolor=#EEEEEE>Moves <b>pins</b>. If the pin locations "
"are shared with other objects, these are also moved. If a group is "
"defined, it will be changed during program execution.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Moves "
"<b>all</b> of the above supported symbol objects.</td></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=3>Package</th><td bgcolor=#EEEEEE><tt>"
"pads</tt></td><td bgcolor=#EEEEEE>Moves <b>pads</b>.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>smds</tt></td><td bgcolor=#EEEEEE>Moves <b>"
"SMDs</b>.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Moves "
"<b>all</b> of the above supported package objects.</td></tr>"
"</table><br><br>"
"<b>Hints:</b><ol>"
"<li>The grid size always uses the current editor unit. If you want to "
"use a different unit, use the snap dialog.</li>"
"<li>If no <b>dy</b> is given, the vertical grid is equal to the "
"horizontal one. If no grid size is given, the current grid is used.</li>"
"<li>Objects are snapped irrespective of their current visibility (even "
"objects from hidden layers are moved). If you want to exclude some "
"objects from snapping, first create a group that does <b>not</b> contain "
"them.</li>"
"<li>If <b>group</b> is used, but no group is currently defined, no "
"objects are moved.</li>"
"<li>Options can be abbreviated (e.g., <b>gr</b> instead of <b>group</b>) "
"as long as there is no ambiguity (e.g., <b>g</b> could mean either <b>"
"group</b> or <b>gates</b>).</li>"
"</ol>",
"de: <table width=100% cellpadding=5 cellspacing=0 bgcolor=#E0E0E0>"
"<tr><td><h3>Objekte auf Gitter einrasten</h3>\n"
"Dieses Programm <b>verschiebt Objekte</b> im Schaltplan, auf der Platine "
"oder in Bibliotheken, so daß ihre Nullpunkte (oder Endpunkte) auf einem "
"definierten Raster liegen. Rasterabstand und einzurastende Objekte "
"können per Dialogbox oder mit der Kommandozeile festgelegt werden.<p>"
"<author>© 2012-07-09 Andreas Weidner</author></td></tr></table>"
"<br><br>"
"<b>Aufruf:</b><dl>"
"<dt><tt>RUN snap [<i>dx</i> [<i>dy</i>]] [group|sheet] [<i>Objekte</i>]"
"</tt></dt>"
"<dd>Setzt den Gitterabstand auf <b>dx</b> horizontal und <b>dy</b> "
"vertikal. Ist <b>group</b> angegeben, werden nur Objekte innerhalb der "
"aktuellen Gruppe verschoben, ist <b>sheet</b> angegeben, werden nur "
"Objekte auf der aktuellen Schaltplanseite verschoben. Sind keine "
"<b>Objekte</b> angegeben, wird ein Auswahldialog angezeigt. Werden "
"<b>Objekte</b> verwendet, findet der Rastvorgang sofort (und ohne "
"Dialogfenster) statt. Eine Liste unterstützter Objekte befindet sich "
"unten.</dd></dl>"
"<b>Beispiele:</b><dl>"
"<dt><tt>RUN snap</tt></dt>"
"<dd>Öffnet den Einrastdialog, in dem der Benutzer alle Optionen "
"einstellt.</dd>"
"<dt><tt>RUN snap 0.1 0.2</tt></dt>"
"<dd>Setzt den Gitterabstand auf <b>0.1</b> horizontal und <b>0.2</b> "
"vertikal und zeigt den Einrastdialog an.</dd>"
"<dt><tt>RUN snap 0.05 group all</tt></dt>"
"<dd>Verschiebt <b>alle</b> unterstützten Objekte, die sich in der "
"momentan definierten <b>Gruppe</b> befinden, auf ein Raster von <b>0.05"
"</b> in beiden Richtungen.</dd>"
"</dl>"
"<b>Unterstützte Objekte:</b><p>"
"<table border=0 cellspacing=2 cellpadding=3>"
"<tr><th bgcolor=#E0E0E0>Editor</th><th bgcolor=#E0E0E0>Objekte</th>"
"<th bgcolor=#E0E0E0>Beschreibung</th></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=3>Schaltplan</th><td bgcolor=#EEEEEE><tt>"
"gates</tt></td><td bgcolor=#EEEEEE>Verschiebt aus Bibliotheken "
"eingefügte <b>Gatter</b>. Direkt mit den Gatteranschlüssen verbundene "
"Netze und Kreuzungspunkte werden ebenfalls verschoben.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>nets</tt></td><td bgcolor=#EEEEEE>Verschiebt "
"<b>Netze</b>, Busse und Kreuzungspunkte. Direkt mit Netzenden verbundene "
"Querverweistexte werden ebenfalls verschoben.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Verschiebt "
"<b>alle</b> oben angegebenen Schaltplanobjekte.</td></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=3>Platine</th><td bgcolor=#EEEEEE><tt>"
"elements</tt></td><td bgcolor=#EEEEEE>Verschiebt aus Bibliotheken "
"eingefügte <b>Elemente</b>. Direkt mit den Bauteilanschlüssen verbundene "
"Kupferbahnen und Durchkontaktierungen werden ebenfalls verschoben.</td>"
"</tr>"
"<tr><td bgcolor=#EEEEEE><tt>signals</tt></td><td bgcolor=#EEEEEE>"
"Verschiebt mit <b>Signalen</b> verbundene Kupferbahnen, "
"Durchkontaktierungen und Polygone.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Verschiebt "
"<b>alle</b> oben angegebenen Platinenobjekte.</td></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=2>Symbol</th><td bgcolor=#EEEEEE><tt>pins"
"</tt></td><td bgcolor=#EEEEEE>Verschiebt <b>Gatteranschlüsse</b>. "
"Stimmen deren Positionen mit anderen Objekten überein, werden diese "
"ebenfalls verschoben. Ist eine Gruppe definiert, wird diese während der "
"Programmausführung verändert.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Verschiebt "
"<b>alle</b> oben angegebenen Symbolobjekte.</td></tr>"
"<tr><th bgcolor=#E0E0E0 rowspan=3>Gehäuse</th><td bgcolor=#EEEEEE><tt>"
"pads</tt></td><td bgcolor=#EEEEEE>Verschiebt <b>Lötaugen</b>.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>smds</tt></td><td bgcolor=#EEEEEE>Verschiebt "
"<b>SMD-Lötflächen</b>.</td></tr>"
"<tr><td bgcolor=#EEEEEE><tt>all</tt></td><td bgcolor=#EEEEEE>Verschiebt "
"<b>alle</b> oben angegebenen Gehäuseobjekte.</td></tr>"
"</table><br><br>"
"<b>Hinweise:</b><ol>"
"<li>Der Rasterabstand verwendet immer die aktuelle Editor-Einheit. Zur "
"Benutzung einer anderen Einheit kann der Einrastdialog angezeigt "
"werden.</li>"
"<li>Ist kein <b>dy</b> angegeben, wird das vertikale Raster gleich dem "
"horizontalen gesetzt. Wird gar kein Gitterabstand angegeben, wird "
"das aktuelle Raster verwendet.</li>"
"<li>Objekte werden unabhängig von ihrer aktuellen Sichtbarkeit "
"eingerastet (auch Objekte in ausgeblendeten Ebenen werden verschoben). "
"Wollen Sie einige Objekte vom Einrasten ausnehmen, erzeugen Sie zuerst "
"eine Gruppe <b>ohne</b> sie.</li>"
"<li>Wird <b>group</b> übergeben, wenn momentan keine Gruppe definiert "
"ist, wird kein Objekt verschoben.</li>"
"<li>Die Optionen können abgekürzt werden (z.B. <b>gr</b> statt <b>group"
"</b>), wenn dadurch keine Mißverständnisse entstehen (z.B. könnte <b>g"
"</b> sowohl <b>group</b> als auch <b>gates</b> bedeuten).</li></ol>"
//----- FUNCTIONS COPIED FROM THE INCLUDE FILE 'awtools.inc'
//----- (By default, this program uses several functions from an include file
//----- 'awtools.inc'. To make the ULP independent of any includes for easier
//----- distribution, the necessary function have been copied to this file
//----- (unsorted). If 'awtools.inc' IS available and its usage desired,
//----- uncomment the next line and delete all text up to (and including)
//----- 'END OF TEXT COPIED FROM AWTOOLS.INC'
//#include "awtools.inc"
string AWExitCommand="";
//Global string that takes up script commands to execute after ULP exitting
string AWTrim(string Text) {
//Removes leading and trailing blanks, tabs and line feeds from TEXT
string NewText,Character;
NewText=Text;
//Remove leading blanks and tabs
Character=strsub(NewText,0,1);
while ((Character==" ") || (Character=="\t") || (Character=="\n")) {
NewText=strsub(NewText,1);
Character=strsub(NewText,0,1);
}
//Ditto with trailing ones
Character=strsub(NewText,strlen(NewText)-1);
while ((Character==" ") || (Character=="\t") || (Character=="\n")) {
NewText=strsub(NewText,0,strlen(NewText)-1);
Character=strsub(NewText,strlen(NewText)-1);
}
return NewText;
}
int AWParameterFound(string Name,int Abbreviate) {
//Returns 1 if the ULP was started with the (case-insensitive) command line
//parameter NAME (0 otherwise). If ABBREVIATE<>0, the parameter is also found
//when it was typed abbreviated
int Nr;
string Text;
//Exit if no parameter or no name was given
Name=strupr(AWTrim(Name));
if ((argc<2) || (!Name))
return 0;
//Check all given parameters separately
for (Nr=1;Nr<argc;Nr++) {
Text=strupr(argv[Nr]);
if (((Abbreviate) && (strsub(Name,0,strlen(Text))==Text)) || (Name==Text))
return 1;
}
//Desired parameter not found
return 0;
}
int AWIsGerman() {
//Returns 1, if a German EAGLE version is running (0 otherwise)
if (language()=="de")
return 1;
return 0;
}
string AWLocalise(string EnglishText,string GermanText) {
//Depending on the current EAGLE language, returns ENGLISHTEXT or GERMANTEXT
string Text;
//Select the desired language string
if (AWIsGerman())
Text=GermanText;
else
Text=EnglishText;
return Text;
}
string AWIntToStr(int x) {
//Returns the integer X formatted as string
string Text;
sprintf(Text,"%d",x);
return Text;
}
//----- END OF TEXT COPIED FROM 'AWTOOLS.INC' -----
//----- (DIALOG) GLOBAL VARIABLES -----
real GridX,GridY;
//Desired grid distance in microns
real dlgGridX,dlgGridY;
//Grid distance in the current dialog units
int dlgGridEqual=1;
//1, if both X any Y directions use the SAME grid distance (0 otherwise)
int dlgGridUnit;
//The grid unit selected in the dialog
int OldUnit;
//Used internally to allow automatic number conversion when switching between
//units in the dialog
enum {scopeGroup,scopeAll,scopeSheet};
//Available options for the SCOPE of objects to be snapped: Only objects in
//the current group, ALL objects (on all sheets), all objects from the
//CURRENT sheet (only useful in the schematics)
int dlgScope=scopeAll;
//Object scope selected in the dialog
int dlgSnapPins=1;
//Objects to snap in the symbol editor
int dlgSnapPads=1,dlgSnapSMDs=1;
//Objects to snap in the package editor
int dlgSnapElements=1,dlgSnapSignals=0,dlgSnapSignalsPass2=0;
//Objects to snap in the board editor. PASS2 is NOT available via the GUI,
//but is used internally (the first pass snaps only the vias, and the second
//pass snaps only the signals)
int dlgSnapGates=1,dlgSnapNets=1,dlgSnapNetsPass2=0;
//Objects to snap in the schematics editor. PASS2 is NOT available via the
//GUI, but is used internally (the first pass snaps only the junctions, and
//the second pass snaps only nets and busses)
int NoDialog=0;
//1, if the snap dialog needs NOT be shown (0 otherwise)
//----- SNAPPING MATH FUNCTIONS -----
int OffGridX(int Number) {
//Returns 1 if the X coordinate NUMBER (in editor units) is off grid
//(0 otherwise)
return (abs((u2mic(Number)/GridX)-round(u2mic(Number)/GridX))*GridX>=0.05);
}
int OffGridY(int Number) {
//Returns 1 if the Y coordinate NUMBER (in editor units) is off grid
//(0 otherwise)
return (abs((u2mic(Number)/GridY)-round(u2mic(Number)/GridY))*GridY>=0.05);
}
int PointOffGrid(int x,int y) {
//Returns 1 if the point (X,Y) in editor units is off grid (0 otherwise)
return ((OffGridX(x)) || (OffGridY(y)));
}
int PointNeedsMoving(int x,int y,int Grouped) {
//Returns 1 if the point (X,Y) in editor units must be moved (0 otherwise)
if ((PointOffGrid(x,y)) && ((dlgScope!=scopeGroup) || (Grouped)))
return 1;
else
return 0;
}
real SnapX(int Number) {
//Returns the grid X coordinate (in micron) next to NUMBER (in editor units)
return round(u2mic(Number)/GridX)*GridX;
}
real SnapY(int Number) {
//Returns the grid Y coordinate (in micron) next to NUMBER (in editor units)
return round(u2mic(Number)/GridY)*GridY;
}
string SnapPoint(int x,int y) {
//Returns the script command to snap the point (x,y) in editor units
string Result;
sprintf(Result,"MOVE (%f %f) (%f %f);\n",u2mic(x),u2mic(y),SnapX(x),
SnapY(y));
return Result;
}
string SnapGroupedPoint(int x,int y) {
//Returns the script command to snap EVERYTHING that can be selected at the
//point (x,y) in editor units
string Result;
sprintf(Result,"GROUP (%f %f) (%f %f) (%f %f) (>%f %f);\n"+
"MOVE (>%f %f) (%f %f);\n",
u2mic(x)-0.1,u2mic(y)-0.1,u2mic(x)-0.1,u2mic(y)+0.1,
u2mic(x)+0.1,u2mic(y)+0.1,u2mic(x)+0.1,u2mic(y)-0.1,
u2mic(x),u2mic(y),SnapX(x),SnapY(y));
return Result;
}
//----- GRID CALCULATION FUNCTIONS -----
void SetDialogGrid(int GridUnit) {
//Fills the dialog box entries with the current grid distance (in microns),
//converting it to the desired GRIDUNIT
int IntX,IntY;
IntX=GridX/u2mic(1);
IntY=GridY/u2mic(1);
if (GridUnit==GRID_UNIT_MIC) {
dlgGridX=u2mic(IntX);
dlgGridY=u2mic(IntY);
}
else if (GridUnit==GRID_UNIT_MM) {
dlgGridX=u2mm(IntX);
dlgGridY=u2mm(IntY);
}
else if (GridUnit==GRID_UNIT_MIL) {
dlgGridX=u2mil(IntX);
dlgGridY=u2mil(IntY);
}
else if (GridUnit==GRID_UNIT_INCH) {
dlgGridX=u2inch(IntX);
dlgGridY=u2inch(IntY);
}
dlgGridUnit=GridUnit;
OldUnit=GridUnit;
}
void GetDialogGrid(int GridUnit) {
//Extracts the desired grid distance (in micron) from the dialog settings,
//converting the values from the GRIDUNIT
int IntX,IntY;
if (GridUnit==GRID_UNIT_MIC) {
IntX=dlgGridX/u2mic(1);
IntY=dlgGridY/u2mic(1);
}
else if (GridUnit==GRID_UNIT_MM) {
IntX=dlgGridX/u2mm(1);
IntY=dlgGridY/u2mm(1);
}
else if (GridUnit==GRID_UNIT_MIL) {
IntX=dlgGridX/u2mil(1);
IntY=dlgGridY/u2mil(1);
}
else if (GridUnit==GRID_UNIT_INCH) {
IntX=dlgGridX/u2inch(1);
IntY=dlgGridY/u2inch(1);
}
GridX=u2mic(IntX);
GridY=u2mic(IntY);
}
void GetDefaultGrid() {
//Extracts the desired grid from the grid settings of the current editor
//window and the command line parameters and puts them into the corresponding
//global variables
real Distance;
int DistUnit,IntDistance;
//Get the current grid unit from the active window
if (schematic)
schematic(S) {
dlgGridUnit=S.grid.unit;
DistUnit=S.grid.unitdist;
Distance=S.grid.distance;
}
if (board)
board(B) {
dlgGridUnit=B.grid.unit;
DistUnit=B.grid.unitdist;
Distance=B.grid.distance;
}
if (library)
library(L) {
dlgGridUnit=L.grid.unit;
DistUnit=L.grid.unitdist;
Distance=L.grid.distance;
}
if (DistUnit==GRID_UNIT_MIC)
IntDistance=Distance/u2mic(1);
else if (DistUnit==GRID_UNIT_MM)
IntDistance=Distance/u2mm(1);
else if (DistUnit==GRID_UNIT_MIL)
IntDistance=Distance/u2mil(1);
else if (DistUnit==GRID_UNIT_INCH)
IntDistance=Distance/u2inch(1);
GridX=u2mic(IntDistance);
GridY=GridX;
//Convert the microns above into the current grid unit and put the result
//into the dialog fields
SetDialogGrid(dlgGridUnit);
//Return, if no command line parameters were given
if (argc<2)
return;
//The first parameter (if available and a proper number) is always the grid
//distance in X direction (in the current grid unit)
if (strtod(argv[1]))
dlgGridX=strtod(argv[1]);
//The second (if available and a proper number) is the Y distance (otherwise
//the Y distance is the same as the X distance
if ((argc>=3) && (strtod(argv[2]))) {
dlgGridY=strtod(argv[2]);
dlgGridEqual=0;
}
else
dlgGridY=dlgGridX;
//If the command line parameters have changed the dialog's grid settings,
//convet those back to microns for internal use
GetDialogGrid(dlgGridUnit);
//For later passes, the grid settings are ALWAYS given in CORRECT microns, so
//in this case, just read them again
if (AWParameterFound("microns",0)) {
GridX=strtod(argv[1]);
GridY=strtod(argv[2]);
}
}
//----- SCOPE SETTING FUNCTIONS -----
void GetDefaultScope() {
//Calculates the default SCOPE setting based on the currently defined group
//and the command line parameters. The setting ALL is possible under all
//circumstances
dlgScope=scopeAll;
//For the second and third ULP pass, do NOT change the default scope
//automatically, but ONLY take the scope from the ULP parameters
if (!AWParameterFound("microns",0)) {
//In a schematics, use GROUP if a group is defined, or SHEET otherwise
if (sheet) {
sheet(SH)
if (ingroup(SH))
dlgScope=scopeGroup;
else
dlgScope=scopeSheet;
}
//In a board, use GROUP if a group is defined, or ALL otherwise
if (board)
board(B)
if (ingroup(B))
dlgScope=scopeGroup;
//(In the symbol or package editors, use ALL by default)
}
//If the command line parameters say otherwise, use those settings
if (AWParameterFound("group",1))
dlgScope=scopeGroup;
if ((AWParameterFound("sheet",1)) && (schematic))
dlgScope=scopeSheet;
}
//----- OBJECT SETTING FUNCTIONS -----
void ResetSnapObjects() {
//Switches off the snapping procedures for all supported objects and inhibits
//the display of the snap dialog
dlgSnapPins=0;
dlgSnapPads=0;
dlgSnapSMDs=0;
dlgSnapElements=0;
dlgSnapSignals=0;
dlgSnapSignalsPass2=0;
dlgSnapGates=0;
dlgSnapNets=0;
dlgSnapNetsPass2=0;
NoDialog=1;
}
void GetDefaultObjects() {
//Extracts the objects to snap from the command line parameters and decides,
//whether or not the snap dialog needs to be shown. If any objects ARE given
//in the command line, the dialog needs NOT be shown
if (schematic) {
if (AWParameterFound("all",1) || AWParameterFound("gates",1) ||
AWParameterFound("nets",1) || AWParameterFound("netspass2",0))
ResetSnapObjects();
if (AWParameterFound("all",1) || AWParameterFound("gates",1))
dlgSnapGates=1;
if (AWParameterFound("all",1) || (AWParameterFound("nets",1) &&
!AWParameterFound("netspass2",0)))
dlgSnapNets=1;
if (AWParameterFound("netspass2",0))
dlgSnapNetsPass2=1;
}
if (board) {
if (AWParameterFound("all",1) || AWParameterFound("elements",1) ||
AWParameterFound("signals",1) || AWParameterFound("signalspass2",0))
ResetSnapObjects();
if (AWParameterFound("all",1) || AWParameterFound("elements",1))
dlgSnapElements=1;
if (AWParameterFound("all",1) || (AWParameterFound("signals",1) &&
!AWParameterFound("signalspass2",0)))
dlgSnapSignals=1;
if (AWParameterFound("signalspass2",0))
dlgSnapSignalsPass2=1;
}
//Even if objects ARE given in the command line, show the dialog if the
//desired grid settings are erraneous
if ((GridX<0) || ((GridX<1) && (GridX>0)) || (GridX>500000) || (GridY<0) ||
((GridY<1) && (GridY>0)) || (GridY>500000))
NoDialog=0;
}
//----- DIALOG FUNCTIONS -----
void ChangeUnit() {
//Redisplays the dialog's edit fields if the desired grid unit is changed
GetDialogGrid(OldUnit);
SetDialogGrid(dlgGridUnit);
dlgRedisplay();
}
void ShowDistanceGroup() {
//Creates all dialog elements of the 'GRID DISTANCE' group
dlgGroup(AWLocalise(" GRID DISTANCE: "," RASTERABSTAND: ")) {
dlgHBoxLayout {
dlgLabel("X: ");
dlgRealEdit(dlgGridX,0,1e6);
dlgSpacing(20);
dlgCheckBox("=",dlgGridEqual)
dlgAccept(2);
if (!dlgGridEqual) {
dlgSpacing(12);
dlgLabel("Y: ");
dlgRealEdit(dlgGridY,0,1e6);
}
else
dlgLabel("Y");
}
dlgHBoxLayout {
dlgRadioButton(AWLocalise("Micrometer (mic)","Mikrometer (mic)"),
dlgGridUnit)
ChangeUnit();
dlgRadioButton(AWLocalise("Millimeter (mm)","Millimeter (mm)"),
dlgGridUnit)
ChangeUnit();
dlgRadioButton("Mil (1/1000\")",dlgGridUnit)
ChangeUnit();
dlgRadioButton(AWLocalise("Inch (\")","Zoll (\")"),dlgGridUnit)
ChangeUnit();
}
}
}
void ShowScopeGroup() {
//Creates all dialog elements of the 'OBJECT SCOPE' group plus the following
//'OK' and 'Cancel' buttons
dlgGroup(AWLocalise(" OBJECT SCOPE: "," GELTUNGSBEREICH: ")) {
dlgRadioButton(AWLocalise("Only objects in the current group (if "+
"defined)","Nur Objekte aus der aktuellen Gruppe (wenn definiert)"),
dlgScope);
if (schematic) {
dlgRadioButton(AWLocalise("All objects on all schematic sheets (if "+
"available)","Alle Objekte auf allen Schaltplanseiten"),dlgScope);
dlgRadioButton(AWLocalise("Only objects on the current sheet","Nur "+
"Objekte auf der aktuellen Schaltplanseite"),dlgScope);
}
else
dlgRadioButton(AWLocalise("All objects in the current window","Alle "+
"Objekte im aktuellen Fenster"),dlgScope);
}
dlgHBoxLayout {
dlgStretch(0);
dlgPushButton("+OK") {
if (dlgGridEqual)
dlgGridY=dlgGridX;
GetDialogGrid(dlgGridUnit);
//In case of grid settings problems, complain
if ((GridX<1) || (GridY<1))
dlgMessageBox(AWLocalise(":The grid distance must be larger than 1um.",
":Der Rasterabstand muß größer als 1um sein."));
else if ((GridX>500000) || (GridY>500000))
dlgMessageBox(AWLocalise(":The grid distance must be smaller than "+
"500mm.",":Der Rasterabstand muß kleiner als 500mm sein."));
else
dlgAccept(1);
}
dlgPushButton(AWLocalise("-Cancel","-Abbrechen"))
dlgReject(0);
}
}
//----- SNAPPING PROCEDURES FOR THE SYMBOL EDITOR -----
string SnapPins() {
//Returns the script text necessary to snap the desired pins from the
//current symbol
string Result="",Text;
symbol(S)
S.pins(P)
if (PointNeedsMoving(P.x,P.y,ingroup(P)))
//Unfortunately, pins can only be moved while displaying the 'symbols'
//layer. This can create problems, because instead of the desired pin,
//sometimes the WIRE at this point is moved (especially valid for
//'point' pins). Therefore, build a SMALL group around each pin and
//move it INCLUDING the wire(s)
Result+=SnapGroupedPoint(P.x,P.y);
if (Result)
Result="DISPLAY None Symbols;\n"+
"GRID Mic Finest;\n"+
Result+
"GRID Last;\n"+
"DISPLAY Last;\n";
return Result;
}
void SnapSymbol() {
//Snaps all desired objects in the current symbol editor window
int Result=2;
//Do nothing, if the current window is not the symbol editor
if (!symbol)
return;
//If a dialog is desired, show it as often as necessary (until the user has
//selected all options). The dialog returns 0 for 'cancel', 1 for 'OK' and 2
//for 'not yet finished'
if (NoDialog)
Result=1;
while (Result==2)
Result=dlgDialog(AWLocalise("Snap symbol objects","Symbolobjekte "+
"einrasten")) {
ShowDistanceGroup();
dlgGroup(AWLocalise(" OBJECT TYPES: "," OBJEKTTYPEN: "))
dlgCheckBox("Pins",dlgSnapPins);
ShowScopeGroup();
};
//Exit the ULP, if the dialog was cancelled or no objects were selected
if ((!Result) || (!dlgSnapPins))
exit(0);
//If pins are to be snapped, do just that
if (dlgSnapPins)
AWExitCommand+=SnapPins();
//Process the exit command
exit(AWExitCommand);
}
//----- SNAPPING PROCEDURES FOR THE PACKAGE EDITOR -----
string SnapPadsSMDs(int Pads,int SMDs) {
//Returns the script text necessary to snap the desired pads and SMDs from
//the current package
string Result="",Text;
package(P)
P.contacts(C)
if (PointNeedsMoving(C.x,C.y,ingroup(C)))
if (((Pads) && (C.pad)) || ((SMDs) && (C.smd))) {
sprintf(Text,"MOVE %s (%.1f %.1f);\n",C.name,SnapX(C.x),SnapY(C.y));
Result+=Text;
}
if (Result) {
Result="DISPLAY None Top Bottom Pads;\n"+
"GRID Mic Finest;\n"+
Result+
"GRID Last;\n"+
"DISPLAY Last;\n";
}
return Result;
}
void SnapPackage() {
//Snaps all desired objects in the current package editor window
int Result=2;
//Do nothing, if the current window is not the package editor
if (!package)
return;
//If a dialog is desired, show it as often as necessary (until the user has
//selected all options). The dialog returns 0 for 'cancel', 1 for 'OK' and 2
//for 'not yet finished'
if (NoDialog)
Result=1;
while (Result==2)
Result=dlgDialog(AWLocalise("Snap package objects","Gehäuseobjekte "+
"einrasten")) {
ShowDistanceGroup();
dlgGroup(AWLocalise(" OBJECT TYPES: "," OBJEKTTYPEN: ")) {
dlgHBoxLayout {
dlgCheckBox("Pads",dlgSnapPads);
dlgCheckBox("SMDs",dlgSnapSMDs);
}
}
ShowScopeGroup();
};
//Exit the ULP, if the dialog was cancelled or no objects were selected
if ((!Result) || ((!dlgSnapPads) && (!dlgSnapSMDs)))
exit(0);
//If objects are to be snapped, do just that
if ((dlgSnapPads) || (dlgSnapSMDs))
AWExitCommand+=SnapPadsSMDs(dlgSnapPads,dlgSnapSMDs);
//Process the exit command
exit(AWExitCommand);
}
//----- POINT LIST FUNCTIONS -----
//Snapping vias/wires or junctions/nets is NOT so trivial, because when moving
//ONE (line end) point, several others connected to it might also be moved
//automatically. Therefore, don't move these objects separately, but keep a
//list of POINTS to be moved and do the whole moving in several passes. The
//idea for this method of moving was taken from the CadSoft ULPs
//'snap-on-grid-sch.ulp' and 'cmd-snap-board.ulp' (even though the actual
//source code wasn't)
int PointX[],PointY[],PointLayer[],PointCount=0;
//The point list: (X,Y) coordinates, point layer, list size
int PointLayerUsed[];
//A separate entry for each layer defines whether this layer contains
//objects that need moving (1) or not (0)
int IsNewPoint(int x,int y,int Layer) {
//Returns 1 if the point (X,Y) on the LAYER does NOT yet exist in the point
//list (0 otherwise)
int Nr;
for (Nr=0;Nr<PointCount;Nr++)
if ((PointX[Nr]==x) && (PointY[Nr]==y) && (PointLayer[Nr]==Layer))
return 0;
return 1;
}
int AddPoint(int x,int y,int Layer,int Grouped) {
//Adds the point (X,Y) on the LAYER to the point list, if it is off-grid, may
//be moved and does not already belong to the list. GROUPED defines whether
//or not the point is a member of the current group. Returns 1 if the point
//was added (0 otherwise)
if ((!PointNeedsMoving(x,y,Grouped)) || (!IsNewPoint(x,y,Layer)))
return 0;
PointX[PointCount]=x;
PointY[PointCount]=y;
PointLayer[PointCount]=Layer;
PointLayerUsed[Layer]=1;
PointCount++;
return 1;
}
void AddWirePoints(UL_WIRE W) {
//Adds both end points of the wire W to the point list, if necessary
AddPoint(W.x1,W.y1,W.layer,ingroup(W) & 1);
AddPoint(W.x2,W.y2,W.layer,ingroup(W) & 2);
}
string MoveLayerPoints(int Layer) {
//Returns a script string that moves all off-grid points on the LAYER to
//their new (snapped) positions
string Result;
int Nr;
//Do nothing if there are no movable points in this layer
if (!PointLayerUsed[Layer])
return "";
status(AWLocalise("Processing layers","Verarbeite Ebenen")+": "+
AWIntToStr(Layer)+"...");
//Go through all available points and move them, if they are on the
//desired layer
sprintf(Result,"DISPLAY None %d;\n",Layer);
for (Nr=0;Nr<PointCount;Nr++)
if (PointLayer[Nr]==Layer)
Result+=SnapPoint(PointX[Nr],PointY[Nr]);
Result+="DISPLAY Last;\n";
return Result;
}
//----- SNAPPING PROCEDURES FOR THE BOARD EDITOR -----
string SnapElements() {
//Returns the script text necessary to snap the desired elements from the
//current board
string Result="",Text;
board(B)
B.elements(E)
if (PointNeedsMoving(E.x,E.y,ingroup(E))) {
sprintf(Text,"MOVE %s (%.1f %.1f);\n",E.name,SnapX(E.x),SnapY(E.y));
Result+=Text;
}
if (Result)
Result="DISPLAY None tOrigins bOrigins tDocu bDocu;\n"+
"GRID Mic Finest;\n"+
"SET Optimizing Off;\n"+
Result+
"SET Optimizing On;\n"+
"OPTIMIZE;\n"+
"GRID Last;\n"+
"DISPLAY Last;\n";
return Result;
}
string SnapVias() {
//Returns the script text necessary to snap the desired vias from the current
//board
string Result="";
board(B)
B.signals(S)
S.vias(V)
if (PointNeedsMoving(V.x,V.y,ingroup(V)))
Result+=SnapPoint(V.x,V.y);
if (Result)
Result="DISPLAY None Vias;\n"+
"GRID Mic Finest;\n"+
"SET Optimizing Off;\n"+
Result+
"SET Optimizing On;\n"+
"OPTIMIZE;\n"+
"GRID Last;\n"+
"DISPLAY Last;\n";
return Result;
}
string SnapSignals() {
//Returns the script text necessary to snap the desired signal wires and
//polygons from the current board
string Result="",Text;
int Nr;
//Collect all unique signal wire points in the point list
board(B)
B.signals(S) {
status(AWLocalise("Processing signals: ","Verarbeite Signale: ")+
S.name+"...");
S.wires(W)
AddWirePoints(W);
}
//Move all the points in this list to their new positions
for (Nr=LAYER_TOP;Nr<=LAYER_BOTTOM;Nr++)
Result+=MoveLayerPoints(Nr);
//Create a separate list for all signal polygon wire points and move them
board(B)
B.signals(S)
S.polygons(P) {
PointCount=0;
P.wires(W)
AddWirePoints(W);
Result+=MoveLayerPoints(P.layer);
}
if (Result)
Result="GRID Mic Finest;\n"+
"SET Optimizing Off;\n"+
Result+
"SET Optimizing On;\n"+
"OPTIMIZE;\n"+
"GRID Last;\n";
return Result;
}
void SnapBoard() {
//Snaps all desired objects in the current board editor window
int Result=2;
string Text;
//Do nothing, if the current window is not the board editor
if (!board)
return;
//If a dialog is desired, show it as often as necessary (until the user has
//selected all options). The dialog returns 0 for 'cancel', 1 for 'OK' and 2
//for 'not yet finished'
if (NoDialog)
Result=1;
while (Result==2)
Result=dlgDialog(AWLocalise("Snap board objects","Platinenobjekte "+
"einrasten")) {
ShowDistanceGroup();
dlgGroup(AWLocalise(" OBJECT TYPES: "," OBJEKTTYPEN: "))
dlgGridLayout {
dlgCell(0,0)
dlgCheckBox(AWLocalise("Components (elements)","Bauteile "+
"(elements)"),dlgSnapElements);
dlgCell(0,1)
dlgCheckBox(AWLocalise("Copper tracks (signals, vias, polygons)",
"Kupferbahnen (signals, vias, polygons)"),dlgSnapSignals);
}
ShowScopeGroup();
};
//Exit the ULP, if the dialog was cancelled or no objects were selected
if ((!Result) || ((!dlgSnapElements) && (!dlgSnapSignals) &&
(!dlgSnapSignalsPass2)))
exit(0);
//If elements are to be snapped, do just that
if (dlgSnapElements)
AWExitCommand+=SnapElements();
//If elements AND signals are to be processed, the elements have already been
//snapped here, and the signals should NOT be processed in the same run.
//Therefore, after snapping the elements properly, start this ULP again (with
//all desired options) and snap the signals in the second (and third) run
if (AWExitCommand) {
if (dlgSnapSignals) {
sprintf(Text,"RUN snap %f %f",GridX,GridY);
AWExitCommand+=Text;
if (dlgScope==scopeGroup)
AWExitCommand+=" group";
if (dlgSnapSignals)
AWExitCommand+=" signals";
AWExitCommand+=" microns;\n";
}
exit(AWExitCommand);
}
//If signals are to be snapped, first just snap all vias and then start the
//ULP again (with all desired options) to snap the wires in yet another run
if (dlgSnapSignals) {
AWExitCommand+=SnapVias();
sprintf(Text,"RUN snap %f %f",GridX,GridY);
AWExitCommand+=Text;
if (dlgScope==scopeGroup)
AWExitCommand+=" group";
AWExitCommand+=" signalspass2 microns;\n";
exit(AWExitCommand);
}
//If vias have already been snapped, now snap the signals and polygons in
//the last run
if (dlgSnapSignalsPass2)
AWExitCommand+=SnapSignals();
//Process the exit command
exit(AWExitCommand);
}
//----- SNAPPING PROCEDURES FOR THE SCHEMATIC EDITOR -----
string SnapParts() {
//Returns the exit command necessary for snapping all desired library parts
//in the current schematics editor window
string Result="",Text;
int Moved=0,CurrentSheet;
sheet(SH)
CurrentSheet=SH.number;
schematic(S)
S.sheets(SH)
if ((dlgScope!=scopeSheet) || (SH.number==CurrentSheet)) {
sprintf(Text,"EDIT .s%d;\n",SH.number);
if (dlgScope==scopeAll)
Result+=Text;
SH.parts(P)
P.instances(I)
if (PointNeedsMoving(I.x,I.y,ingroup(I))) {
sprintf(Text,"MOVE %s (%.1f %.1f);\n",I.name,SnapX(I.x),
SnapY(I.y));
Result+=Text;
Moved=1;
}
}
if (!Moved)
return "";
Result="DISPLAY None Symbols;\n"+
"GRID Mic Finest;\n"+
Result+
"GRID Last;\n"+
"DISPLAY Last;\n";
return Result;
}
string SnapJunctions() {
//Returns the exit command necessary for snapping all desired junctions in
//the current schematics editor window
string Result="",Text;
int Moved=0,CurrentSheet;
sheet(SH)