[Spoilers] Advent of Code 2023 Day 1

[razetime]

A friend wanted a solution to refer to, so i wrote this solution that covers the problem.

:- use_module(library(dcgs)).
:- use_module(library(charsio)).
:- use_module(library(lambda)).

d(X)-->[Y],{char_type(Y,numeric),number_chars(X,[Y])}.

n(1),"ne"-->"one".
n(2),"wo"-->"two".
n(3),"hree"-->"three".
n(4),"our"-->"four".
n(5),"ive"-->"five".
n(6),"ix"-->"six".
n(7),"even"-->"seven".
n(8),"ight"-->"eight".
n(9),"ine"-->"nine".

p2([X|Y])-->d(X),p2(Y).
p2([X|Y])-->n(X),p2(Y).
p2(Y)-->[_],p2(Y).
p2([])-->[].
p1([X|Y])-->d(X),p1(Y).
p1(Y)-->[_],p1(Y).
p1([])-->[].

% The Power of Prolog DCG Primer
lines([])     --> call(eos), !.
lines([L|Ls]) --> line(L), lines(Ls).

line([])     --> ( "\n" | call(eos) ), !.
line([C|Cs]) --> [C], line(Cs).

eos([], []).

fl(L,S):-[F|_]=L,length(L,B),nth1(B,L,E),S is E+F*10.
pt(X,Y,Z):-phrase(lines(L),Y),
  once(maplist(X+\R^S^(call(X,A,R,[]),fl(A,S)),L,K)), sum_list(K,Z).

i("two1nine\neightwothree\nabcone2threexyz\nxtwone3four\n4nineeightseven2\nzoneight234\n7pqrstsixteen").

Usage: pt(p1,String,Result) or pt(p2,String,Result).

I think I can improve how I handle lines in this one, but i'm not sure how. I'd like to use a dcg containing p1 or p2 using phrase_to_file, but when i tried earlier it made the interpreter unresponsive.

[aarroyoc]

Mine is way less compact. I followed a different strategy for part two, duplicating the string, and the first part parsing just until the first "written number" and the second starting in reverse. Then I concat them because what only matters is the first and last one, it doesn't matter that we duplicate the string if we keep the first and last to be the same: https://github.com/aarroyoc/advent-of-code-2023/blob/main/day1/main.pl

[Mousaka]

Hi! I had this strategy:
Parse until first number but keep that number in the string, then parse backwards for the first digit.

keep_first_digit(N), [N] --> first_digit(N).
keep_first_digit(N) --> digit(N). 

first_digit(N) --> digit(N), ... .
first_digit(N) --> letter, first_digit(N).

last_digit(N) --> ..., digit(N).
last_digit(N) --> last_digit(N),letter.

concat_first_and_last_digit(N) --> keep_first_digit(N1), last_digit(N2), {number_chars(N, [N1,N2])}.

Note that my last_digit is not optimal since it finds other paths after the correct parsing (suggestions wanted for fixing that). Full solution: https://github.com/Mousaka/advent-of-code-2023/blob/main/1/1.pl

[emummel20]

Oh hell yeah, thanks for this. I've been on the aoc subreddit solution megathreads looking for prolog solutions but it's inconsistent. Ideally we'd have some motivated folks here to provide them so those of us learning can have a reference.

[infogulch]

I'm posting my AoC 2023 solutions here: https://github.com/infogulch/aoc

It's got solutions for day 1,2,4, and day5 part1. I'm having trouble with day3...