prison_mine.txt

Menu(" PRISON MINE ","Enter",2,"New",0,"Stop",3
Lbl 0
DelVar CDelVar HDelVar R0→T
Lbl 1
ᴇ2→B
2B→D
DelVar EDelVar FDelVar M1→P
DelVar UR+1→R
Lbl 2
ClrDraw
1→S
While 1
    If M
        Text(7,0,"MINE ",M
    If P
        Text(13,0,"PEOPLE:",P
    If F
        Text(19,0,"FORTUNE ",F
    If E
        Text(25,0,"EFFICIENCY ",E
    If S
        Text(45,0,RS,"*MULTIPLIER
    If H
        Text(51,0,"HASTE ",H
    Text(57,0,"[S]HOP
    DelVar YRepeat θ or not(D
        If B
            Text(0,0,"BALANCE:",B
        If D<200
            Text(31,0,D,"/200   
        Y+1→Y
        getKey→θ
        If Y≥ᴇ2
            DelVar YPause 
        C+2^(E+H→C
        T+.01→T
        While C≥128
            DelVar CB+2^MSPRrandInt(F+1,2F+1→B
            D-not(randInt(0,2^U-1→D
        End
    End
    While not(D
        ClrDraw
        DelVar EDelVar FDelVar U200→D
    End
    DelVar AIf θ=81
    Then
        Text(7,0,"[N]EXT MINE:",4^M
        Text(13,0,"[I]NVITE:",3^P
        Text(19,0,"[F]ORTUNE:",5^F
        If E<5
            Text(25,0,"[E]FFICIENCY:",6^(E+9
        If U<3
            Text(31,0,"[U]NBREAKING:",14^(U+9
        Text(38,0,"[P]RESTIGE:",⏨^(R+2
        Text(45,0,"[M]ULTIPLIER:",7^S
        If H<2
            Text(51,0,"[H]ASTE:",3^(M+H
        If int(T
            Text(57,0,"[T]NT EXPLOSION:",int(T
        Repeat θ
            Y+2→Y
            If Y>ᴇ3
                DelVar YPause 
            getKey→θ
            If θ=31
                DelVar YDelVar θ1-A→A
            Text(0,71,"[A]LL:",A
        End
        While θ=71 and B≥4^M
            B-4^M→B
            DelVar HM+1→M
            Aθ→θ
        End
        While θ=61 and B≥3^P
            B-3^P→B
            P+1→P
            Aθ→θ
        End
        While θ=53 and B≥5^F
            B-5^F→B
            F+1→F
            Aθ→θ
        End
        While θ=52 and E<5 and B≥6^(E+9
            B-6^(E+9→B
            E+1→E
            Aθ→θ
        End
        While θ=83 and U<3 and B≥14^(U+9
            B-14^(U+9→B
            U+1→U
            Aθ→θ
        End
        If θ=73 and B≥⏨^(R+2
            Goto 1
        While θ=65 and B≥7^S
            B-7^S→B
            S+1→S
            Aθ→θ
        End
        While θ=55 and H<2 and B≥3^(M+H
            B-3^(M+H→B
            H+1→H
            Aθ→θ
        End
        While θ=82 and T≥1
            T-1→T
            B+(F+9)RS3^M→B
            Aθ→θ
        End
        ClrDraw
    End
End
Lbl 3