feat: add tiptap repository

Author: Robbert

team-members.tf

@@ -542,3 +542,19 @@ resource "github_team_members" "nora-committer" {
     username = data.github_user.RGRMdesign.username
   }
 }
+
+resource "github_team_members" "tiptap-committer" {
+  team_id = github_team.tiptap-committer.id
+
+  members {
+    username = data.github_user.ali-kadhim.username
+  }
+
+  members {
+    username = data.github_user.danny-hoek.username
+  }
+
+  members {
+    username = data.github_user.stephan-meijer.username
+  }
+}

team.tf

@@ -491,3 +491,15 @@ resource "github_team" "nora-committer" {
   parent_team_id = github_team.nora.id
   privacy        = "closed"
 }
+
+resource "github_team" "tiptap" {
+  name        = "tiptap"
+  privacy     = "closed"
+  description = "Tiptap Editor contributors"
+}
+
+resource "github_team" "tiptap-committer" {
+  name           = "tiptap-committer"
+  parent_team_id = github_team.tiptap.id
+  privacy        = "closed"
+}

tiptap.tf

@@ -0,0 +1,130 @@
+resource "github_repository" "tiptap" {
+  name                        = "tiptap"
+  description                 = "NL Design System Tiptap Editor packages"
+  allow_merge_commit          = false
+  allow_rebase_merge          = true
+  allow_squash_merge          = true
+  allow_auto_merge            = true
+  delete_branch_on_merge      = true
+  has_issues                  = true
+  has_downloads               = false
+  has_projects                = false
+  has_wiki                    = false
+  vulnerability_alerts        = true
+  homepage_url                = "https://nl-design-system.github.io/tiptap/"
+  squash_merge_commit_title   = "PR_TITLE"
+  squash_merge_commit_message = "PR_BODY"
+  topics                      = ["nl-design-system"]
+
+  template {
+    owner                = "nl-design-system"
+    repository           = "example"
+    include_all_branches = false
+  }
+
+  security_and_analysis {
+    secret_scanning {
+      status = "enabled"
+    }
+    secret_scanning_push_protection {
+      status = "enabled"
+    }
+  }
+
+  pages {
+    build_type = "workflow"
+  }
+
+  lifecycle {
+    prevent_destroy = true
+  }
+}
+
+resource "github_repository_ruleset" "tiptap-main" {
+  name        = "main"
+  repository  = github_repository.tiptap.name
+  target      = "branch"
+  enforcement = "active"
+
+  conditions {
+    ref_name {
+      include = ["refs/heads/main"]
+      exclude = []
+    }
+  }
+
+  rules {
+    pull_request {
+      dismiss_stale_reviews_on_push     = true
+      required_approving_review_count   = 1
+      required_review_thread_resolution = true
+    }
+    required_linear_history = true
+
+    required_status_checks {
+      required_check {
+        context = "build"
+      }
+      required_check {
+        context = "install"
+      }
+      required_check {
+        context = "lint"
+      }
+      required_check {
+        context = "test"
+      }
+    }
+  }
+
+  bypass_actors {
+    actor_id    = github_team.kernteam-ci.id
+    actor_type  = "Team"
+    bypass_mode = "always"
+  }
+}
+
+resource "github_repository_collaborators" "tiptap" {
+  repository = github_repository.tiptap.name
+
+  team {
+    permission = "admin"
+    team_id    = github_team.kernteam-admin.slug
+  }
+
+  team {
+    permission = "maintain"
+    team_id    = github_team.kernteam-maintainer.slug
+  }
+
+  team {
+    permission = "push"
+    team_id    = github_team.kernteam-committer.slug
+  }
+
+  team {
+    permission = "triage"
+    team_id    = github_team.kernteam-triage.slug
+  }
+
+  team {
+    permission = "triage"
+    team_id    = github_team.kernteam-dependabot.slug
+  }
+}
+
+
+resource "vercel_project" "tiptap" {
+  name             = github_repository.tiptap.name
+  output_directory = "packages/storybook/dist/"
+  ignore_command   = "[[ $(git log -1 --pretty=%an) == 'dependabot[bot]' ]]"
+
+  git_repository = {
+    type = "github"
+    repo = "${data.github_organization.nl-design-system.orgname}/${github_repository.tiptap.name}",
+  }
+
+  vercel_authentication = {
+    deployment_type = "none"
+  }
+}

user.tf

@@ -256,4 +256,12 @@ data "github_user" "RGRMdesign" {
 
 data "github_user" "sjimbonator" {
   username = "sjimbonator"
-}
+}
+
+data "github_user" "danny-hoek" {
+  username = "ZwaarContrast"
+}
+
+data "github_user" "stephan-meijer" {
+  username = "StephanMeijer"
+}