build.gradle

repositories {
    mavenCentral()
}

wrapper {
    gradleVersion = '5.6.4'
}

allprojects {
    version = '0.1.0'
    group = 'org.openehr'
    ext.gradleScriptDir = "${rootProject.projectDir}/gradle"
    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:all', '-quiet')
    }
}


subprojects {
    apply plugin: 'java'
    apply plugin: 'antlr'

    sourceCompatibility = '1.8'
    targetCompatibility = '1.8'

    compileJava.options.encoding = "UTF-8"
    compileTestJava.options.encoding = "UTF-8"

    repositories {
        mavenCentral()
        maven { url 'https://jitpack.io' }
    }

    ext.antlrVersion = '4.13.1'
    ext.reflectionsVersion = '0.10.2'

    generateGrammarSource { //antlr4
        arguments = ['-encoding', 'utf-8'] + arguments
    }
    classes {
        dependsOn generateGrammarSource
    }
    dependencies {
        antlr 'org.antlr:antlr4:4.13.1'
        api 'org.antlr:antlr4-runtime:4.13.1'
        api 'org.slf4j:slf4j-api:1.7.36'

        implementation "org.reflections:reflections:${reflectionsVersion}"

        implementation ('commons-io:commons-io:2.15.1'){
            exclude group: 'commons-logging', module: 'commons-logging'
        }

        implementation 'org.apache.commons:commons-text:1.11.0'
        implementation 'org.apache.commons:commons-lang3:3.14.0'

        implementation 'com.google.guava:guava:33.0.0-jre'

        implementation 'org.slf4j:slf4j-simple:1.7.36'

        testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.1'
        testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.1'

    }

    test {
        useJUnitPlatform()
    }
}