build.gradle

subprojects {
    apply plugin: 'java'
    apply plugin: 'groovy'
    apply plugin: 'maven'
    apply plugin: 'project-report'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    group = "com.opsgenie.integration"
    version = "2.13.7"

    repositories {
        mavenCentral()
        maven {
            url "https://packages.atlassian.com/maven-3rdparty/"
        }
    }

    test {
        maxHeapSize = '1024m'
        ignoreFailures = true
        workingDir = project.rootProject.rootDir
        filter {
            exclude "**/**TestCase**"
        }
        testLogging.showStandardStreams = true
    }

    jar {
        manifest {
            attributes("Built-By": "http://www.opsgenie.com",
                    "Specification-Title": project.name[0].toUpperCase() + project.name[1..-1],
                    "Specification-Product": project.name,
                    "Specification-Version": project.version,
                    "Specification-Vendor": "http://www.opsgenie.com",
                    "Implementation-Title" : project.name[0].toUpperCase() + project.name[1..-1],
                    "Implementation-Product": project.name,
                    "Implementation-Vendor":"http://www.opsgenie.com",
                    "Implementation-Version":project.version,
            )
        }
    }

    task listJars << {
        configurations.compile.sort().each { File file -> println file.name }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.2'
}