build.gradle

plugins {
	id 'java'
	id "org.sonarqube" version "5.0.0.4638"
	id 'maven-publish'
	id 'org.jreleaser' version '1.14.0'
}

group = 'cat.bernado'
version = '0.0.1'

java {
	sourceCompatibility = '21'
	withJavadocJar()
	withSourcesJar()
}

repositories {
	mavenCentral()
}

dependencies {
	testImplementation 'org.junit.jupiter:junit-jupiter-api:5.9.2'
	testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.9.2'
	implementation 'io.github.classgraph:classgraph:4.8.154'
	implementation 'org.springframework:spring-context:6.1.12'
	implementation 'org.springframework.boot:spring-boot-autoconfigure:3.3.3'
	implementation 'org.slf4j:slf4j-api:1.7.25'
	testImplementation 'org.mockito:mockito-core:3.7.7'
	testImplementation 'org.mockito:mockito-junit-jupiter:3.7.7'
}

tasks.named('test') {
	useJUnitPlatform()
}

publishing {
	publications {
		maven(MavenPublication) {
			groupId = 'cat.bernado'
			artifactId = 'simplebus'

			from components.java

			pom {
				name = 'SimpleBus'
				description = 'A simple command bus pattern implementation for Spring Boot'
				url = 'https://github.com/orbeji/SimpleBus'
				inceptionYear = '2024'
				licenses {
					license {
						name = 'MIT'
						url = 'https://choosealicense.com/licenses/mit/'
					}
				}
				developers {
					developer {
						id = 'orbeji'
						name = 'orbeji'
					}
				}
				scm {
					connection = 'scm:git:https://github.com/orbeji/SimpleBus.git'
					developerConnection = 'scm:git:ssh://github.com/orbeji/SimpleBus.git'
					url = 'http://github.com/orbeji/SimpleBus'
				}
			}
		}
	}

	repositories {
		maven {
			url = layout.buildDirectory.dir('staging-deploy')
		}
	}
}

jreleaser {
	environment {
		variables = '.jreleaser/config.toml'
	}
	signing {
		active = 'ALWAYS'
		armored = true
	}
	deploy {
		maven {
			/* Portal Publisher API*/
            mavenCentral {
                sonatype {
                    active = 'ALWAYS'
                    url = 'https://central.sonatype.com/api/v1/publisher'
                    stagingRepository('build/staging-deploy')
                }
            }
		}
	}
}