bootstrap

#!/usr/bin/env zsh

() {
  # Get the current execution context and move into it
  SCRIPT_DIR=$(cd $(dirname "${(%):-%x}") && pwd)
  cd $SCRIPT_DIR || return

  # Source commons (e.g. logging)
  for libraryFile (_lib/*.zsh); do
    source $libraryFile
  done

  ensure_env

  # Pull in the latest dotfiles
  logger "info" "Pulling latest files from remote ..."
  if ! git pull origin main >/dev/null 2>&1
  then
    logger "warning" "Failed to pull in latest files from source!"
  else
    logger "success" "Successfully pulled in latest files."
  fi

  prompt "This may overwrite existing files in your home directory ..."
  if (( $PROMPT_PROCEED != 0 )); then
    return
  fi

  # Use GNU Stow to link up dotfiles
  mkdir -p $HOME/.config
  if ! stow -t $HOME stow git mackup prefs tmux zsh >/dev/null 2>&1; then
    logger "error" "Failed to link dotfiles!"
    exit 1
  fi
  if ! stow -t $HOME/.config config >/dev/null 2>&1; then
    logger "error" "Failed to link dotfiles!"
    exit 1
  fi

  # Fix any permission issues related to loading auto-completion
  for dir in $(compaudit 2>/dev/null); do
    chmod g-w $dir
  done

  logger "success" "Successfully linked dotfiles."

  logger "info" "Installing Starship ..."

  if [[ $(/usr/bin/uname -m) == "arm64" ]]; then
    export STARSHIP_LOCATION="/opt/starship/bin"
  else
    export STARSHIP_LOCATION="/usr/local/bin"
  fi
  sudo mkdir -p $STARSHIP_LOCATION
  curl -sS https://starship.rs/install.sh | sh -s -- -b $STARSHIP_LOCATION -y >/dev/null
  unset STARSHIP_LOCATION

  logger "success" "Successfully installed Starship."

  # Replace the shell instance with a new one
  exec zsh -l
}