forked from embulk/embulk-input-jdbc
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
219 lines (192 loc) · 6.65 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
plugins {
id 'com.jfrog.bintray' version '1.8.4'
id 'com.github.jruby-gradle.base' version '1.6.0'
id 'java'
id 'checkstyle'
}
import com.github.jrubygradle.JRubyExec
def bintrayReleaseProjects = [
project(":embulk-input-jdbc"),
project(":embulk-input-mysql"),
project(":embulk-input-postgresql"),
project(":embulk-input-redshift"),
project(":embulk-input-oracle"),
project(":embulk-input-sqlserver"),
project(":embulk-input-db2"),
]
allprojects {
group = 'org.embulk.input.jdbc'
version = '0.10.0'
apply plugin: 'com.jfrog.bintray'
apply plugin: 'maven-publish'
bintray {
// write at your bintray user name and api key to ~/.gradle/gradle.properties file:
// bintray_user=frsyuki
// bintray_api_key=xxxxxxxxxxx
user = project.hasProperty('bintray_user') ? bintray_user : ''
key = project.hasProperty('bintray_api_key') ? bintray_api_key : ''
publications = ['bintrayMavenRelease']
dryRun = !bintrayReleaseProjects.contains(project)
publish = true
pkg {
userOrg = 'embulk-input-jdbc'
repo = 'maven'
name = project.name
desc = 'MySQL, PostgreSQL, Redshift and generic JDBC input plugins for Embulk'
websiteUrl = 'https://github.com/embulk/embulk-input-jdbc'
issueTrackerUrl = 'https://github.com/embulk/embulk-input-jdbc/issues'
vcsUrl = 'https://github.com/embulk/embulk-input-jdbc.git'
licenses = ['Apache-2.0']
labels = ['embulk', 'java']
publicDownloadNumbers = true
version {
name = project.version
}
}
}
}
subprojects {
apply plugin: 'maven' // install jar files to the local repo: $ gradle install
apply plugin: 'java'
apply plugin: 'findbugs'
//apply plugin: 'jacoco'
apply plugin: 'com.github.jruby-gradle.base'
repositories {
mavenCentral()
jcenter()
}
configurations {
provided
defaultJdbcDriver
}
sourceCompatibility = 1.8
targetCompatibility = 1.8
dependencies {
compile 'org.embulk:embulk-core:0.9.12'
provided 'org.embulk:embulk-core:0.9.12'
testCompile 'org.embulk:embulk-test:0.9.12'
}
tasks.withType(JavaCompile) {
options.compilerArgs << "-Xlint:unchecked" //<< "-Xlint:deprecation"
options.encoding = 'UTF-8'
}
tasks.withType(FindBugs) {
reports {
xml.enabled = false
html.enabled = true
}
}
findbugs {
ignoreFailures = true
}
javadoc {
options {
locale = 'en_US'
encoding = 'UTF-8'
}
}
test {
// JDBC input plugins depend on local time zone to parse timestamp without time stamp and datetime types.
jvmArgs "-Duser.country=FI", "-Duser.timezone=Europe/Helsinki"
environment "TZ", "Europe/Helsinki"
}
task classpath(type: Copy, dependsOn: ["jar"]) {
doFirst { file('classpath').deleteDir() }
from (configurations.runtime - configurations.provided - configurations.defaultJdbcDriver + files(jar.archivePath))
into 'classpath'
}
task defaultJdbcDriver(type: Copy, dependsOn: ["jar"]) {
doFirst { file('default_jdbc_driver').deleteDir() }
from (configurations.defaultJdbcDriver)
into 'default_jdbc_driver'
}
clean {
delete 'classpath'
delete 'default_jdbc_driver'
}
checkstyle {
configFile = file("${project.rootDir}/config/checkstyle/checkstyle.xml")
toolVersion = '6.14.1'
}
checkstyleMain {
configFile = file("${project.rootDir}/config/checkstyle/default.xml")
ignoreFailures = true
}
checkstyleTest {
configFile = file("${project.rootDir}/config/checkstyle/default.xml")
ignoreFailures = true
}
task checkstyle(type: Checkstyle) {
classpath = sourceSets.main.output + sourceSets.test.output
source = sourceSets.main.allJava + sourceSets.test.allJava
}
task gem(type: JRubyExec, dependsOn: ['build', 'gemspec', 'classpath', 'defaultJdbcDriver']) {
jrubyArgs "-S"
script "gem"
scriptArgs "build", "${project.projectDir.absolutePath}/build/gemspec"
doLast { ant.move(file: "${project.name}-${project.version}.gem", todir: "${parent.projectDir}/pkg") }
}
javadoc {
options {
locale = 'en_US'
encoding = 'UTF-8'
}
}
// add tests/javadoc/source jar tasks as artifacts to be released
task testsJar(type: Jar, dependsOn: classes) {
classifier = 'tests'
from sourceSets.test.output
}
task sourcesJar(type: Jar, dependsOn: classes) {
classifier = 'sources'
from sourceSets.main.allSource
}
task javadocJar(type: Jar, dependsOn: javadoc) {
classifier = 'javadoc'
from javadoc.destinationDir
}
artifacts {
archives testsJar, sourcesJar, javadocJar
}
publishing {
publications {
bintrayMavenRelease(MavenPublication) {
from components.java
artifact testsJar
artifact sourcesJar
artifact javadocJar
}
}
}
task gemspec {
doLast {
file('build').mkdirs()
file('build/gemspec').write($/
Gem::Specification.new do |spec|
spec.name = "${project.name}"
spec.version = "${project.version}"
spec.authors = ["Sadayuki Furuhashi"]
spec.summary = %[JDBC input plugin for Embulk]
spec.description = %[Selects records from a table.]
spec.email = ["frsyuki@gmail.com"]
spec.licenses = ["Apache 2.0"]
spec.homepage = "https://github.com/embulk/embulk-input-jdbc"
spec.files = `git ls-files`.split("\n") + Dir["classpath/*.jar"] + Dir["default_jdbc_driver/*.jar"]
spec.test_files = spec.files.grep(%r"^(test|spec)/")
spec.require_paths = ["lib"]
end
/$)
}
}
}
task gemPush {
doLast {
"gem push pkg/embulk-input-jdbc-${project.version}.gem".execute().waitFor()
"gem push pkg/embulk-input-mysql-${project.version}.gem".execute().waitFor()
"gem push pkg/embulk-input-postgresql-${project.version}.gem".execute().waitFor()
"gem push pkg/embulk-input-redshift-${project.version}.gem".execute().waitFor()
"gem push pkg/embulk-input-oracle-${project.version}.gem".execute().waitFor()
"gem push pkg/embulk-input-sqlserver-${project.version}.gem".execute().waitFor()
"gem push pkg/embulk-input-db2-${project.version}.gem".execute().waitFor()
}
}