Main.gd

extends Node2D

@export var mob_scene: PackedScene
var score: int


# Called when the node enters the scene tree for the first time.
func _ready():
	var screen_size = get_viewport_rect().size
	
	# Start from center
	$StartPosition.position = screen_size / 2
	
	# Clear all Vector2 points
	$MobPath.curve.clear_points()

	# Set 1st vector
	$MobPath.curve.add_point(Vector2(0,0))
	# Set 2nd vector
	$MobPath.curve.add_point(Vector2(screen_size.x, 0))
	# Set 3rd vector
	$MobPath.curve.add_point(Vector2(screen_size.x, screen_size.y))
	# Set 4th vector
	$MobPath.curve.add_point(Vector2(0, screen_size.y))
	# Set 5th vector
	$MobPath.curve.add_point(Vector2(0, 0))


# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(_delta):
	pass


func game_over():
	$ScoreTimer.stop()
	$MobTimer.stop()
	$HUD.show_game_over()
	
	$Music.stop()
	$DeathSound.play()


func new_game():
	score = 0
	$Player.start($StartPosition.position)
	$StartTimer.start()
	
	$HUD.update_score(score)
	$HUD.show_message("Get Ready")
	
	# Remove old mobs
	get_tree().call_group("mobs", "queue_free")
	
	$Music.play()


func _on_start_timer_timeout():
	$MobTimer.start()
	$ScoreTimer.start()


func _on_score_timer_timeout():
	score += 1
	$HUD.update_score(score)


func _on_mob_timer_timeout():
	# Create a new instance of the Mob scene.
	var mob = mob_scene.instantiate()

	# Choose a random location on Path2D.
	var mob_spawn_location = $MobPath/MobSpawnLocation
	mob_spawn_location.progress_ratio = randf()

	# Set the mob's direction perpendicular to the path direction.
	var direction = mob_spawn_location.rotation + PI / 2

	# Set the mob's position to a random location.
	mob.position = mob_spawn_location.position

	# Add some randomness to the direction.
	direction += randf_range(-PI / 4, PI / 4)
	mob.rotation = direction

	# Choose the velocity for the mob.
	var velocity = Vector2(randf_range(150.0, 250.0), 0.0)
	mob.linear_velocity = velocity.rotated(direction)

	# Spawn the mob by adding it to the Main scene.
	add_child(mob)