publish.gradle

def publishLocal = true

task sourceJar(type: Jar) {
    classifier "sources"
    from sourceSets.main.allSource
}

artifacts {
    archives jar, sourceJar
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            artifact(sourceJar) {
                classifier = 'sources'
            }

            pom {
                name = 'JsonPathKt'
                description = 'A lighter and more efficient implementation of JsonPath in Kotlin'
                url = 'https://github.com/codeniko/JsonPathKt'
                licenses {
                    license {
                        name = 'BSD-3-Clause'
                        url = 'https://github.com/codeniko/JsonPathKt/blob/master/LICENSE'
                    }
                }
                developers {
                    developer {
                        id = 'codeniko'
                        name = 'Nikolay Feldman'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/codeniko/JsonPathKt.git'
                    developerConnection = 'scm:git:ssh://git@github.com:codeniko/JsonPathKt.git'
                    url = 'https://github.com/codeniko/JsonPathKt'
                }
            }

            if (!publishLocal) {
                // create the sign pom artifact
                pom.withXml {
                    def pomFile = file("${project.buildDir}/generated-pom.xml")
                    writeTo(pomFile)
                    def pomAscFile = signing.sign(pomFile).signatureFiles[0]
                    artifact(pomAscFile) {
                        classifier = null
                        extension = 'pom.asc'
                    }
                }
                // create the signed artifacts
                project.tasks.signArchives.signatureFiles.each {
                    artifact(it) {
                        def matcher = it.file =~ /-(sources|javadoc)\.jar\.asc$/
                        if (matcher.find()) {
                            classifier = matcher.group(1)
                        } else {
                            classifier = null
                        }
                        extension = 'jar.asc'
                    }
                }
            }
        }
    }

    repositories {
        maven {
            if (publishLocal) {
                // publish to local repo
                url = uri("$buildDir/repository")
            } else {
                if (snapshotVersion) {
                    url = "https://oss.sonatype.org/content/repositories/snapshots"
                } else {
                    url = "https://oss.sonatype.org/service/local/staging/deploy/maven2"
                }
                credentials {
                    username sonatypeUsername
                    password sonatypePassword
                }
            }
        }
    }
}

model {
    tasks.generatePomFileForMavenJavaPublication {
        destination = file("$buildDir/generated-pom.xml")
    }
}
if (!publishLocal) {
    model {
        tasks.publishMavenJavaPublicationToMavenLocal {
            dependsOn project.tasks.signArchives
        }
        tasks.publishMavenJavaPublicationToMavenRepository {
            dependsOn project.tasks.signArchives
        }
    }
}

signing {
    required { !snapshotVersion && gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}