build.gradle

allprojects {
    group 'ch.so.agi' 
	
	apply from: "$rootDir/versioning.gradle"
	
    repositories {
        mavenLocal()
        maven { url "https://jars.interlis.ch" }
        maven { url "https://repo.osgeo.org/repository/release/" }
        mavenCentral()
        maven { url "https://s01.oss.sonatype.org/service/local/repositories/releases/content/" }
        maven { url "https://s01.oss.sonatype.org/service/local/repositories/snapshots/content/" }
        maven {
            url "https://plugins.gradle.org/m2/" 
            content {
                excludeModule("ch.so.agi","gretl")            
            }
        } 
    }    
}

// Eigentlich sollte Gradle nicht mehr die "-notimestamp" Option verwenden.
// Diese ist mit Java 11 Geschichte. Sie wird hier halt explizit ausgeschaltet.
allprojects {
    tasks.withType(Javadoc) {
        options.noTimestamp = false
    }
}

def env(environmentVariableName){
    return env(environmentVariableName, 'UNDEFINED')
}

def env(environmentVariableName, defaultValue) {
    def var = System.getenv(environmentVariableName)
    if (var == null || var.length() == 0) {
        var = defaultValue
    }
    return var;
}