Fix Boxed Boolean is getter methods are not properly mocked in Groovy <= 3

Added tests to verify that boolean is getter work according to Groovy rules.

Fixes #2131

Author: AndreasTu

docs/release_notes.adoc

@@ -111,6 +111,7 @@ spockPull:2112[]
 * Fix several bugs in cross-multiplication implementation spockPull:2123[]
 * Fix filter blocks with shared fields and derived data variables spockPull:2088[]
 * Fix combined labels with comments being ignored spockPull:2121[]
+* Fix Boxed Boolean is getter methods are not properly mocked in Groovy <= 3 spockIssue:2131[]
 
 Thanks to all the contributors to this release: Andreas Turban, Björn Kautler, Christoph Loy, Marcin Zajączkowski, Pavlo Shevchenko
 

spock-core/src/main/java/org/spockframework/runtime/GroovyRuntimeUtil.java

@@ -137,8 +137,10 @@ public static String getterMethodToPropertyName(String methodName, List<Class<?>
     if (methodName.startsWith(GET))
       return getPropertyName(methodName, 3);
 
-    if (methodName.startsWith(IS)
-        && returnType == boolean.class) // Boolean.class is not allowed
+    if (methodName.startsWith(IS) && (
+      returnType == boolean.class // Boolean.class is not allowed for Groovy >= 4
+        || (MAJOR_VERSION <= 3 && returnType == Boolean.class) // In Groovy <= 3 a isGetter can also be a boxed Boolean.
+    ))
       return getPropertyName(methodName, 2);
 
     return null;

spock-specs/src/test/groovy/org/spockframework/runtime/GroovyRuntimeUtilSpec.groovy

@@ -15,6 +15,7 @@
 package org.spockframework.runtime
 
 import org.codehaus.groovy.runtime.typehandling.GroovyCastException
+import spock.lang.Requires
 import spock.lang.Specification
 
 import static org.spockframework.runtime.GroovyRuntimeUtil.propertyToBooleanGetterMethodName
@@ -48,6 +49,28 @@ class GroovyRuntimeUtilSpec extends Specification {
     "setFoo"          | void       | null
   }
 
+  @Requires({ GroovyRuntimeUtil.MAJOR_VERSION <= 3 })
+  def "getterMethodToPropertyName Groovy <= 3"() {
+    expect:
+    GroovyRuntimeUtil.getterMethodToPropertyName(methodName, [], returnType) == propertyName
+
+    where:
+    methodName | returnType | propertyName
+    "isEmpty"  | Boolean    | "empty"
+    "isEmpty"  | boolean    | "isEmpty"
+  }
+
+  @Requires({ GroovyRuntimeUtil.MAJOR_VERSION >= 4 })
+  def "getterMethodToPropertyName Groovy >= 4"() {
+    expect:
+    GroovyRuntimeUtil.getterMethodToPropertyName(methodName, [], returnType) == propertyName
+
+    where:
+    methodName | returnType | propertyName
+    "isEmpty"  | Boolean    | null //In Groovy >= 4 not a property anymore, see https://issues.apache.org/jira/browse/GROOVY-9382
+    "isEmpty"  | boolean    | "empty"
+  }
+
   def "propertyToGetterMethodName"() {
     expect:
     propertyToGetterMethodName("prop") == "getProp"

spock-specs/src/test/groovy/org/spockframework/smoke/mock/GroovyMocksForInterfaces.groovy

@@ -16,7 +16,10 @@
 package org.spockframework.smoke.mock
 
 import org.spockframework.mock.CannotCreateMockException
+import org.spockframework.runtime.GroovyRuntimeUtil
 import org.spockframework.runtime.model.parallel.Resources
+import spock.lang.Issue
+import spock.lang.Requires
 import spock.lang.ResourceLock
 import spock.lang.Specification
 
@@ -126,11 +129,160 @@ class GroovyMocksForInterfaces extends Specification {
     ex.message == "Cannot create mock for interface java.lang.Runnable. Global mocking is only possible for classes, but not for interfaces."
   }
 
+  @Issue("https://github.com/spockframework/spock/issues/2131")
+  def "Boolean is getters shall be mockable"() {
+    expect:
+    m.booleanValue
+    m.isBooleanValue()
+
+    where:
+    m << [
+      Stub(BooleanGetters) {
+        booleanValue >> true
+      },
+      Stub(BooleanGetters) {
+        isBooleanValue() >> true
+      }
+    ]
+  }
+
+  /**
+   * Verify that a boxed Boolean is getter does not have a property representation in Groovy >= 4.
+   */
+  @Requires({ GroovyRuntimeUtil.MAJOR_VERSION >= 4 })
+  def "Boolean boxed is getters Groovy >=4 semantic check"() {
+    given:
+    def m = createBooleanGetterInterfaceObjPlain()
+
+    expect:
+    m.isBooleanValueBoxed()
+
+    when:
+    m.booleanValueBoxed
+    then:
+    thrown(MissingPropertyException)
+    //The property for a boxed Boolean does not exist in Groovy >=4
+  }
+
+  /**
+   * Verify that a boxed Boolean is getter does have a property representation in Groovy <= 3.
+   */
+  @Requires({ GroovyRuntimeUtil.MAJOR_VERSION <= 3 })
+  def "Boolean boxed is getters Groovy <= 3 semantic check"() {
+    given:
+    def m = createBooleanGetterInterfaceObjPlain()
+
+    expect:
+    m.booleanValueBoxed
+    m.isBooleanValueBoxed()
+  }
+
+  @Issue("https://github.com/spockframework/spock/issues/2131")
+  @Requires({ GroovyRuntimeUtil.MAJOR_VERSION >= 4 })
+  def "Boolean boxed is getters is not mockable Groovy >= 4"() {
+    given:
+    def m = Stub(BooleanGetters) {
+      isBooleanValueBoxed() >> true
+    }
+
+    expect:
+    m.isBooleanValueBoxed()
+
+    when:
+    m.booleanValueBoxed
+    then:
+    thrown(MissingPropertyException)
+    //According to Groovy >=4 rules the property for a boxed Boolean is getter does not exist.
+  }
+
+  @Issue("https://github.com/spockframework/spock/issues/2131")
+  @Requires({ GroovyRuntimeUtil.MAJOR_VERSION <= 3 })
+  def "Boolean boxed is getters shall be mockable Groovy <= 3"() {
+    expect:
+    //Groovy <= 3 does not throw an MissingProperty exception
+    m.booleanValueBoxed
+    m.isBooleanValueBoxed()
+
+    where:
+    m << [
+      Stub(BooleanGetters) {
+        booleanValueBoxed >> true
+      },
+      Stub(BooleanGetters) {
+        isBooleanValueBoxed() >> true
+      }
+    ]
+  }
+
+  @Issue("https://github.com/spockframework/spock/issues/2131")
+  def "Boolean get getters shall be mockable"() {
+    expect:
+    m.isBooleanValue
+    m.getIsBooleanValue()
+
+    where:
+    m << [
+      Stub(BooleanGetters) {
+        isBooleanValue >> true
+      },
+      Stub(BooleanGetters) {
+        getIsBooleanValue() >> true
+      }
+    ]
+  }
+
+  @Issue("https://github.com/spockframework/spock/issues/2131")
+  def "Boolean boxed get getters shall be mockable"() {
+    expect:
+    m.isBooleanValueBoxed
+    m.getIsBooleanValueBoxed()
+
+    where:
+    m << [
+      Stub(BooleanGetters) {
+        isBooleanValueBoxed >> true
+      },
+      Stub(BooleanGetters) {
+        getIsBooleanValueBoxed() >> true
+      }
+    ]
+  }
+
   interface Person {
     String getName()
 
     void setName(String name)
 
     void sing(String song)
   }
+
+  interface BooleanGetters {
+    boolean isBooleanValue()
+
+    Boolean isBooleanValueBoxed()
+
+    boolean getIsBooleanValue()
+
+    Boolean getIsBooleanValueBoxed()
+  }
+
+  private BooleanGetters createBooleanGetterInterfaceObjPlain() {
+    new BooleanGetters() {
+      boolean isBooleanValue() {
+        true
+      }
+
+      Boolean isBooleanValueBoxed() {
+        true
+      }
+
+      boolean getIsBooleanValue() {
+        true
+      }
+
+      Boolean getIsBooleanValueBoxed() {
+        true
+      }
+    }
+  }
 }