-
Notifications
You must be signed in to change notification settings - Fork 6
/
steam.txt
155 lines (131 loc) · 4.36 KB
/
steam.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
%--------------------------------------------------------------------------
% File : PUZ031+1 : TPTP v7.2.0. Released v2.0.0.
% Domain : Puzzles
% Problem : Schubert's Steamroller
% Version : Especial.
% English : Wolves, foxes, birds, caterpillars, and snails are animals, and
% there are some of each of them. Also there are some grains, and
% grains are plants. Every animal either likes to eat all plants
% or all animals much smaller than itself that like to eat some
% plants. Caterpillars and snails are much smaller than birds,
% which are much smaller than foxes, which in turn are much
% smaller than wolves. Wolves do not like to eat foxes or grains,
% while birds like to eat caterpillars but not snails.
% Caterpillars and snails like to eat some plants. Therefore
% there is an animal that likes to eat a grain eating animal.
% Refs : [Pel86] Pelletier (1986), Seventy-five Problems for Testing Au
% : [Hah94] Haehnle (1994), Email to G. Sutcliffe
% Source : [Hah94]
% Names : Pelletier 47 [Pel86]
% Status : Theorem
% Rating : 0.00 v6.3.0, 0.08 v6.2.0, 0.00 v5.5.0, 0.08 v5.4.0, 0.00 v5.3.0, 0.09 v5.2.0, 0.00 v3.7.0, 0.33 v3.5.0, 0.12 v3.4.0, 0.08 v3.3.0, 0.00 v3.2.0, 0.22 v3.1.0, 0.00 v2.5.0, 0.33 v2.4.0, 0.33 v2.2.1, 0.00 v2.1.0
% Syntax : Number of formulae : 21 ( 6 unit)
% Number of atoms : 55 ( 0 equality)
% Maximal formula depth : 10 ( 4 average)
% Number of connectives : 36 ( 2 ~; 4 |; 14 &)
% ( 0 <=>; 16 =>; 0 <=; 0 <~>)
% ( 0 ~|; 0 ~&)
% Number of predicates : 10 ( 0 propositional; 1-2 arity)
% Number of functors : 0 ( 0 constant; --- arity)
% Number of variables : 33 ( 0 sgn; 22 !; 11 ?)
% Maximal term depth : 1 ( 1 average)
% SPC : FOF_THM_RFO_NEQ
% Comments : This problem is named after Len Schubert.
%--------------------------------------------------------------------------
fof(pel47_1_1,axiom,
( ! [X] :
( wolf(X)
=> animal(X) ) )).
fof(pel47_1_2,axiom,
( ? [X1] : wolf(X1) )).
fof(pel47_2_1,axiom,
( ! [X] :
( fox(X)
=> animal(X) ) )).
fof(pel47_2_2,axiom,
( ? [X1] : fox(X1) )).
fof(pel47_3_1,axiom,
( ! [X] :
( bird(X)
=> animal(X) ) )).
fof(pel47_3_2,axiom,
( ? [X1] : bird(X1) )).
fof(pel47_4_1,axiom,
( ! [X] :
( caterpillar(X)
=> animal(X) ) )).
fof(pel47_4_2,axiom,
( ? [X1] : caterpillar(X1) )).
fof(pel47_5_1,axiom,
( ! [X] :
( snail(X)
=> animal(X) ) )).
fof(pel47_5_2,axiom,
( ? [X1] : snail(X1) )).
fof(pel47_6_1,axiom,
( ? [X] : grain(X) )).
fof(pel47_6_2,axiom,
( ! [X1] :
( grain(X1)
=> plant(X1) ) )).
fof(pel47_7,axiom,
( ! [X] :
( animal(X)
=> ( ! [Y] :
( plant(Y)
=> eats(X,Y) )
| ! [Y1] :
( ( animal(Y1)
& much_smaller(Y1,X)
& ? [Z] :
( plant(Z)
& eats(Y1,Z) ) )
=> eats(X,Y1) ) ) ) )).
fof(pel47_8,axiom,
( ! [X,Y] :
( ( bird(Y)
& ( snail(X)
| caterpillar(X) ) )
=> much_smaller(X,Y) ) )).
fof(pel47_9,axiom,
( ! [X,Y] :
( ( bird(X)
& fox(Y) )
=> much_smaller(X,Y) ) )).
fof(pel47_10,axiom,
( ! [X,Y] :
( ( fox(X)
& wolf(Y) )
=> much_smaller(X,Y) ) )).
fof(pel47_11,axiom,
( ! [X,Y] :
( ( wolf(X)
& ( fox(Y)
| grain(Y) ) )
=> ~ eats(X,Y) ) )).
fof(pel47_12,axiom,
( ! [X,Y] :
( ( bird(X)
& caterpillar(Y) )
=> eats(X,Y) ) )).
fof(pel47_13,axiom,
( ! [X,Y] :
( ( bird(X)
& snail(Y) )
=> ~ eats(X,Y) ) )).
fof(pel47_14,axiom,
( ! [X] :
( ( caterpillar(X)
| snail(X) )
=> ? [Y] :
( plant(Y)
& eats(X,Y) ) ) )).
fof(pel47,conjecture,
( ? [X,Y] :
( animal(X)
& animal(Y)
& ? [Z] :
( grain(Z)
& eats(Y,Z)
& eats(X,Y) ) ) )).
%--------------------------------------------------------------------------