build.gradle

plugins {
    id "java"
    id "checkstyle"
    id "jacoco"
    id "org.embulk.embulk-plugins" version "0.4.2"
    id "maven"
    id 'maven-publish'
    id "signing"
}

repositories {
    mavenCentral()
    jcenter()
}

group = "com.treasuredata.embulk.plugins"
version = "0.3.33"
description = "Embulk output plugin for Mailchimp"

sourceCompatibility = 1.8
targetCompatibility = 1.8

embulkPlugin {
    mainClass = "org.embulk.output.mailchimp.MailChimpOutputPlugin"
    category = "output"
    type = "mailchimp"
}

def embulkVersion = '0.10.32'

dependencies {
    compileOnly "org.embulk:embulk-api:$embulkVersion"
    compileOnly "org.embulk:embulk-spi:$embulkVersion"

    compile('org.embulk:embulk-util-config:0.3.1') {
        // Conflict with Embulk Core
        exclude group: 'com.fasterxml.jackson.core', module: 'jackson-annotations'
        exclude group: 'com.fasterxml.jackson.core', module: 'jackson-core'
        exclude group: 'com.fasterxml.jackson.core', module: 'jackson-databind'
        exclude group: 'com.fasterxml.jackson.datatype', module: 'jackson-datatype-jdk8'
        exclude group: 'javax.validation', module: 'validation-api'
    }

    // Explicit dependencies for embulk-util-* that matches with Embulk 0.10.19
    compile 'com.fasterxml.jackson.core:jackson-core:2.6.7'
    compile 'com.fasterxml.jackson.core:jackson-annotations:2.6.7'
    compile 'com.fasterxml.jackson.core:jackson-databind:2.6.7'
    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.6.7'
    compile 'javax.validation:validation-api:1.1.0.Final'

    compile 'org.embulk:embulk-base-restclient:0.10.1'
    compile 'org.embulk:embulk-util-retryhelper-jetty94:0.9.0'

    compile 'com.google.guava:guava:18.0'
    compile  "com.google.code.findbugs:annotations:3.0.1"

    testCompile "junit:junit:4.10"
    testCompile "org.embulk:embulk-junit4:$embulkVersion"
    testCompile "org.embulk:embulk-core:$embulkVersion"
    testCompile "org.embulk:embulk-core:$embulkVersion:tests"
    testCompile "org.embulk:embulk-deps:$embulkVersion"
    testCompile "org.mockito:mockito-core:2.28.2"
}

test {
    jvmArgs "-XX:MaxPermSize=128M"
    // Set the timezone for testing somewhere other than my machine to increase the chances of catching timezone bugs
    systemProperty 'user.timezone', 'PST'
    testLogging {
        events "passed", "skipped", "failed"
    }
}

checkstyle {
    configFile = file("${project.rootDir}/config/checkstyle/checkstyle.xml")
    toolVersion = '6.14.1'
}
checkstyleMain {
    configFile = file("${project.rootDir}/config/checkstyle/default.xml")
    ignoreFailures = true
}
checkstyleTest {
    configFile = file("${project.rootDir}/config/checkstyle/default.xml")
    ignoreFailures = true
}
task checkstyle(type: Checkstyle) {
    classpath = sourceSets.main.output + sourceSets.test.output
    source = sourceSets.main.allJava + sourceSets.test.allJava
}

jacocoTestReport {
    reports {
        xml.enabled false
        csv.enabled false
        html.destination file("${buildDir}/reports/coverage")
    }
}

gem {
    authors = ["Thang Nguyen", "Vinh Vo", "Huy Le", "Treasure Data"]
    email = ["huy@treasure-data.com", "dev@treasure-data.com"]
    summary = project.description
    homepage = "https://github.com/treasure-data/embulk-output-mailchimp"
    licenses = []
}

tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:deprecation" << "-Xlint:unchecked"
    options.encoding = "UTF-8"
}