build.gradle

plugins {
    id "java"
    id "maven-publish"
    id "org.embulk.embulk-plugins" version "0.4.2"
    id "com.palantir.git-version" version "0.12.3"
    id "com.diffplug.spotless" version "5.15.0"
    id "com.adarshr.test-logger" version "3.0.0"
}
repositories {
    mavenCentral()
}

group = "io.trocco"
version = versionDetails().lastTag
description = "Dumps records to Snowflake."

sourceCompatibility = 1.8
targetCompatibility = 1.8

dependencies {
    compileOnly "org.embulk:embulk-api:0.10.31"
    compileOnly "org.embulk:embulk-spi:0.10.31"

    compile("org.embulk:embulk-util-config:0.3.0") {
        // They conflict with embulk-core. They are once excluded here,
        // and added explicitly with versions exactly the same with embulk-core:0.10.19.
        exclude group: "com.fasterxml.jackson.core", module: "jackson-annotations"
        exclude group: "com.fasterxml.jackson.core", module: "jackson-core"
        exclude group: "com.fasterxml.jackson.core", module: "jackson-databind"
        exclude group: "com.fasterxml.jackson.datatype", module: "jackson-datatype-jdk8"
        exclude group: "javax.validation", module: "validation-api"
    }

    // They are once excluded from transitive dependencies of other dependencies,
    // and added explicitly with versions exactly the same with embulk-core:0.10.19.
    compile "com.fasterxml.jackson.core:jackson-annotations:2.6.7"
    compile "com.fasterxml.jackson.core:jackson-core:2.6.7"
    compile "com.fasterxml.jackson.core:jackson-databind:2.6.7"
    compile "com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.6.7"
    compile "javax.validation:validation-api:1.1.0.Final"

    compile("org.embulk:embulk-util-json:0.1.0") {
        exclude group: "org.msgpack", module: "msgpack-core"  // Included in embulk-api.
    }
    testImplementation "junit:junit:4.+"
    testImplementation "org.embulk:embulk-junit4:0.10.31"
    testImplementation "org.embulk:embulk-core:0.10.31"
    testImplementation "org.embulk:embulk-core:0.10.31:tests"
    testImplementation "org.embulk:embulk-deps:0.10.31"
    testImplementation "org.embulk:embulk-input-file:0.10.31"
    testImplementation "org.embulk:embulk-parser-csv:0.10.31"

    compile "org.embulk:embulk-output-jdbc:0.10.2"
    compile "net.snowflake:snowflake-jdbc:3.13.26"
}
embulkPlugin {
    mainClass = "org.embulk.output.SnowflakeOutputPlugin"
    category = "output"
    type = "snowflake"
}
// This Gradle plugin's POM dependency modification works for "maven-publish" tasks.
//
// Note that "uploadArchives" is no longer supported. It is deprecated in Gradle 6 to be removed in Gradle 7.
// https://github.com/gradle/gradle/issues/3003#issuecomment-495025844
publishing {
    publications {
        embulkPluginMaven(MavenPublication) {  // Publish it with "publishEmbulkPluginMavenPublicationToMavenRepository".
            from components.java  // Must be "components.java". The dependency modification works only for it.
        }
    }
    repositories {
        maven {
            url = "${project.buildDir}/mavenPublishLocal"
        }
    }
}
gem {
    from("LICENSE.txt")
    authors = [ "giwa" ]
    email = [ "ugw.gi.world@gmail.com" ]
    summary = "Snowflake output plugin for Embulk"
    homepage = "https://github.com/trocco-io/embulk-output-snowflake"
    licenses = [ "MIT" ]
}
gemPush {
    host = "https://rubygems.org"
}
spotless {
    java {
        importOrder()
        removeUnusedImports()
        googleJavaFormat()
    }
}