-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
231 lines (187 loc) · 5.3 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
{
inputs = {
nixpkgs = {
type = "github";
owner = "nixos";
repo = "nixpkgs";
ref = "nixos-unstable";
};
crane = {
type = "github";
owner = "ipetkov";
repo = "crane";
ref = "v0.18.0";
inputs.nixpkgs.follows = "nixpkgs";
};
fenix = {
type = "github";
owner = "nix-community";
repo = "fenix";
inputs.nixpkgs.follows = "nixpkgs";
};
nix-filter = {
type = "github";
owner = "numtide";
repo = "nix-filter";
};
flake-utils = {
type = "github";
owner = "numtide";
repo = "flake-utils";
};
identity-context = {
url = "https://w3c.credential.nexus/identity.jsonld";
flake = false;
};
placeholder-image = {
url = "https:/picsum.photos/id/0/200/300";
flake = false;
};
thumbnail-image = {
url = "https:/picsum.photos/id/1/128/128";
flake = false;
};
};
outputs = {
nixpkgs,
crane,
fenix,
nix-filter,
flake-utils,
identity-context,
placeholder-image,
thumbnail-image,
...
}:
flake-utils.lib.eachDefaultSystem (
system: let
pkgs = import nixpkgs {
inherit system;
};
src = nix-filter.lib.filter {
root = ./.;
include = [
./crates
./Cargo.toml
./Cargo.lock
];
};
rustToolchain = with fenix.packages.${system};
combine [
stable.rustc
stable.cargo
stable.clippy
stable.rustfmt
targets.wasm32-unknown-unknown.stable.rust-std
];
craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;
rustPlatform = pkgs.makeRustPlatform {
cargo = rustToolchain;
rustc = rustToolchain;
};
wasm-snip = pkgs.callPackage ./nix/wasm-snip.nix {
inherit rustPlatform;
};
commonArgs = {
inherit src;
pname = "teddybear";
strictDeps = true;
CARGO_NET_GIT_FETCH_WITH_CLI = "true";
};
nativeArgs =
commonArgs
// {
cargoExtraArgs = "--all-features --locked";
};
cargoArtifacts = craneLib.buildDepsOnly nativeArgs;
# https://webassembly.org/features
# https://github.com/rust-lang/rust/blob/master/compiler/rustc_target/src/target_features.rs#L323-L337
enabledWasmFeatures = [
"bulk-memory"
"mutable-globals"
"nontrapping-fptoint"
"sign-ext"
"simd128"
];
# Potentially, some unused code may be introduced into the resulting WASM blob,
# unnecessarily increasing its size. Using `wasm-snip` it's possible to replace
# function bodies with a trap opcode, optimizing out both the function itself
# and its callers.
wasmSnipPatterns = [
".*bmff_io.*"
".*gif_io.*"
".*svg_io.*"
];
wasmArgs =
commonArgs
// {
RUSTFLAGS = let
fmt = pkgs.lib.concatMapStringsSep "," (f: "+${f}") enabledWasmFeatures;
in "-C target-feature=${fmt}";
CARGO_BUILD_TARGET = "wasm32-unknown-unknown";
};
wasmCargoArtifacts = craneLib.buildDepsOnly (wasmArgs
// {
doCheck = false;
cargoExtraArgs = "-p teddybear-js --locked";
});
mkPackage = buildForNode:
pkgs.callPackage ./nix/package.nix {
inherit
buildForNode
craneLib
wasmArgs
wasmCargoArtifacts
wasmSnipPatterns
wasm-snip
;
};
esm = mkPackage false;
cjs = mkPackage true;
uni = pkgs.callPackage ./nix/uni.nix {
inherit cjs esm;
};
docs = pkgs.callPackage ./nix/docs.nix {
src = uni;
};
in {
devShells = {
default = pkgs.mkShell {
buildInputs = [rustToolchain pkgs.nodejs pkgs.yarn pkgs.twiggy];
inputsFrom = [esm];
};
ci = pkgs.mkShell {
buildInputs = [rustToolchain pkgs.cargo-edit];
};
};
packages = {
inherit cjs esm docs;
default = uni;
};
checks = {
inherit cjs esm uni docs;
e2e-test = pkgs.callPackage ./nix/e2e-testing/vm.nix {
inherit identity-context placeholder-image thumbnail-image;
certificate = ./nix/e2e-testing/crt.der;
placeholder-pdf = ./nix/e2e-testing/blank.pdf;
runner = pkgs.callPackage ./nix/e2e-testing/runner.nix {
inherit uni;
src = ./tests;
yarnLockHash = "sha256-Om6VzFh/qKP7rYs0ihW66sq7fOv0oqA956wpIMDavg8=";
};
};
unit-test = craneLib.cargoTest (nativeArgs
// {
inherit cargoArtifacts;
});
clippy = craneLib.cargoClippy (nativeArgs
// {
inherit cargoArtifacts;
cargoClippyExtraArgs = "--all-targets -- --deny warnings";
});
fmt = craneLib.cargoFmt commonArgs;
};
formatter = pkgs.alejandra;
}
);
}