build.gradle

plugins {
    id 'eu.xenit.docker-compose' version '5.5.0' apply false
    id "be.vbgn.ci-detect" version "0.5.0"
    id "org.sonarqube" version "3.5.0.2730"
}

sonarqube {
    properties {
        property "sonar.projectKey", "xenit-eu_alfred-telemetry"
        property "sonar.organization", "xenit-eu"
        property "sonar.host.url", "https://sonarcloud.io"
    }
}


allprojects {
    group = 'eu.xenit.alfred.telemetry'
    version = '1.0.0'

    apply plugin: 'java'
    apply plugin: 'jacoco'

    jacocoTestReport {
        reports {
            xml.enabled true
            html.enabled true
        }
    }
    test.finalizedBy jacocoTestReport
    rootProject.tasks.sonarqube.dependsOn jacocoTestReport

    boolean isRelease = ci.branch?.startsWith("release")
    if (!isRelease) {
        version += "-SNAPSHOT"
    }

    ext {
        micrometerVersion = '1.0.6'
        jvmExtrasVersion = '0.1.2'

        junitJupiterVersion = '5.10.2'
        mockitoVersion = '5.11.0'
        hamcrestVersion = '1.3'
        awaitilityVersion = '4.1.0'
        restAssuredVersion = '5.3.0'
    }


    repositories {
        mavenCentral()
        maven {
            url 'https://artifacts.alfresco.com/nexus/content/groups/public'
        }
        maven {
            url 'https://artifacts.alfresco.com/nexus/content/groups/private'
            credentials {
                username project.property('org.alfresco.maven.nexus.username')
                password project.property('org.alfresco.maven.nexus.password')
            }
        }
    }

    apply from: "${rootProject.projectDir}/publish.gradle"
}