website.gradle

// The project is built with sbt.
//
// This gradle file builds the website

buildscript {
  repositories {
    mavenCentral()
    maven { url "https://maven.restlet.talend.com" }
  }

  dependencies {
    classpath group: 'org.docbook', name: 'docbook-xslt2', version: docbookXsltVersion
    classpath group: 'com.xmlcalabash', name: 'xmlcalabash1-print', version: '1.1.4'
    classpath group: 'com.xmlcalabash', name: 'xmlcalabash1-gradle', version: '1.1.2'
  }
}

plugins {
  id "scala"
  id "maven"
  id "de.undercouch.download" version "2.0.0"
}

configurations {
  website
}

repositories {
  mavenLocal()
  mavenCentral()
  maven { url "http://maven.restlet.org" }
  maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
}

apply plugin: 'org.docbook.task'
apply plugin: 'com.xmlcalabash.task'

import org.docbook.DocBookTask
import com.xmlcalabash.XMLCalabashTask
import de.undercouch.gradle.tasks.download.Download

project.ext.docbookXslt = "docbook-xslt2-$docbookXsltVersion"

defaultTasks 'website'

// Travis-CI seems to be having trouble downloading from http://cdn.docbook.org
// I wonder if it's refusing to download fro a plain http: URI?
// Anyway, the workaround is just to checkin the artifact for the time being.
task downloadDocBook(type: Copy) {
  from 'src/website/resources'
  into 'build'
}

task reallyDownloadDocBook(type: Download) {
  src docbookXsltBaseUri + '/release/' + docbookXsltVersion + '/' + docbookXslt + '.zip'
  dest new File(buildDir, docbookXslt + '.zip')
}
downloadDocBook.onlyIf { !file("$buildDir/${docbookXslt}.zip").exists() }

task setupDocBook(dependsOn: downloadDocBook, type: Copy) {
  from zipTree(new File(buildDir, docbookXslt + '.zip'))
  //from zipTree(downloadDocBook.dest)
  into { "build" }
  doLast {
    copy {
      from "build/$docbookXslt"
      into 'build/docbook'
    }
  }
}
setupDocBook.onlyIf { !file("$buildDir/docbook").exists() }

// All of the hand-authored pages
def pages = [
             'pages/index',
             'pages/contact',
             'pages/pipelines/index',
             'pages/apis/index',
             'pages/apis/pipelines',
             'pages/apis/vocabulary',
             'pages/apis/steps'
            ]

// Create a task for each page to update it if necessary
pages.each { page ->
  task "$page" (dependsOn: ['menus','gitlog','copyrsrcs','setupDocBook'],
                type: XMLCalabashTask) {
    inputs.file "src/website/${page}.xml"
    inputs.file "srcw/website/etc/menu.xml"
    inputs.file "src/website/style/webpage.xpl"
    inputs.file "src/website/style/webpage.xsl"
    outputs.file "build/menus/PLACEHOLDER.html"
    outputs.file "build/${page}.html"

    input("source", "src/website/${page}.xml")
    output("result", "build/${page}.html")
    pipeline "src/website/style/webpage.xpl"
  }
}

// The task that updates all of the page headers
task menus(type: XMLCalabashTask) {
  inputs.file "src/website/etc/menu.xml"
  inputs.file "src/website/style/menus.xsl"
  inputs.file "src/website/style/menus.xpl"
  outputs.file "build/menus/PLACEHOLDER.html"

  input("source", "src/website/etc/menu.xml")
  output("result", "build/menus/PLACEHOLDER.html")
  pipeline "src/website/style/menus.xpl"
}

task builddirs {
  doFirst {
    mkdir("build")
    mkdir("build/pages")
    mkdir("build/pages/css")
    mkdir("build/pages/images")
    mkdir("build/pages/graphics")
  }
}

// Copy a bunch of files
task copyrsrcs(dependsOn: ['copycss','copyjs','copyimages','copygraphics','copypages']) {
  // nop
}

task copycss(dependsOn: builddirs, type: Copy) {
  from 'src/website/css'
  into 'build/pages/css'
}

task copyjs(dependsOn: builddirs, type: Copy) {
  from 'src/website/js'
  into 'build/pages/js'
}

task copyimages(dependsOn: builddirs, type: Copy) {
  from 'src/website/images'
  into 'build/pages/images'
}

task copygraphics(dependsOn: builddirs, type: Copy) {
  from 'src/website/graphics'
  into 'build/pages/graphics'
}

task copypages(dependsOn: builddirs, type: Copy) {
  from 'src/website/pages'
  into 'build/pages'
}

// Get the current git log in XML
// N.B. The output should go to build/etc but I *cannot* work out how
// to get Gradle to do that. If the directory doesn't exist, it fails.
// It fails before it even runs dependencies that would create the
// directory!?
task gitlog(dependsOn: builddirs, type: Exec) {
  if (System.getProperty('os.name').toLowerCase().contains('windows')) {
    commandLine "cmd", "/c", "perl", "src/website/bin/git-log-summary"
  } else {
    commandLine "src/website/bin/git-log-summary"
  }
  standardOutput = new FileOutputStream(new File("src/website/etc/git-log-summary.xml"))
}

// The default task. It just depends on all the necessary pages
task website(dependsOn: [pages]) {
  // nop
}

// Make the default build target also build the website
build.dependsOn website