build.gradle

plugins {
    id 'java-library'
    id 'com.palantir.git-version' version '0.12.3'
    id 'maven-publish'
}

group 'co.zeroae'
//noinspection GroovyAssignabilityCheck
version gitVersion()

repositories {
    mavenCentral()
}

dependencies {
    implementation 'uk.ac.gate:gate-core:8.6.1'
    implementation 'uk.ac.gate.plugins:format-json:8.7'
    implementation 'uk.ac.gate.plugins:format-twitter:8.7'
    implementation 'uk.ac.gate.plugins:format-mediawiki:8.5'
    implementation 'uk.ac.gate.plugins:format-pubmed:8.5'
    implementation 'uk.ac.gate.plugins:format-fastinfoset:8.5'
    implementation 'uk.ac.gate.plugins:format-datasift:8.5'

    implementation platform('com.amazonaws:aws-xray-recorder-sdk-bom:2.4.0')
    implementation 'com.amazonaws:aws-lambda-java-core:1.2.1'
    implementation 'com.amazonaws:aws-lambda-java-events:2.2.9'
    implementation 'com.amazonaws:aws-xray-recorder-sdk-core'

    implementation 'com.jakewharton:disklrucache:2.0.2'

    runtimeOnly 'com.amazonaws:aws-lambda-java-log4j2:1.2.0'

    testImplementation 'junit:junit:4.13.1'
    testImplementation 'com.github.stefanbirkner:system-lambda:1.1.1'
}

test {
    useJUnit()
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/zeroae/packages")
            credentials {
                username = project.findProperty("github.username") ?: System.getenv("GITHUB_USER")
                password = project.findProperty("github.token") ?: System.getenv("GITHUB_TOKEN")
            }
        }
    }
    publications {
        gate(MavenPublication) {
            from(components.java)
        }
    }
}