DRAFT Правило LostVariable - Затираемая\скрываемая переменная

docs/diagnostics/LostVariable.md

@@ -0,0 +1,149 @@
+# Потерянная переменная (LostVariable)
+
+<!-- Блоки выше заполняются автоматически, не трогать -->
+## Описание диагностики
+<!-- Описание диагностики заполняется вручную. Необходимо понятным языком описать смысл и схему работу -->
+Переменной присваивается значение, которое не используется. Далее переменной еще раз присваивается новое значение.
+Подобный код приводит к снижению читабельности кода, также может приводить к снижению производительности.
+Может возникать при опечатках, "копипасте" или рефакторинге кода, а также из-за проблем в алгоритме.
+
+В текущей реализации возможны "ложно-положительные" срабатывания, т.е. могут выдаваться замечания к правильному коду, т.к. некоторые варианты кода сложно отличить от правильного. Подробнее в примерах, пункт "Примеры исключений".
+
+## Примеры
+<!-- В данном разделе приводятся примеры, на которые диагностика срабатывает, а также можно привести пример, как можно исправить ситуацию -->
+Неверный код - безусловная повторная переустановка значения
+```bsl
+МояПеременная = СтрЗаменить(Текст, " ", ""); // замечание
+МояПеременная = СтрЗаменить(Текст, ";", "");
+```
+Правильный код
+```bsl
+МояПеременная = СтрЗаменить(Текст, " ", "");
+МояПеременная = СтрЗаменить(МояПеременная, ";", "");
+```
+
+Или другой подозрительный код - повторная переустановка значения при некотором условии и только потом переменная используется
+```bsl
+МояПеременная = СтрЗаменить(Текст, " ", ""); // замечание
+Если Условие Тогда
+    МояПеременная = СтрЗаменить(Текст, ";", "");
+    Возврат МояПеременная;
+КонецЕсли;
+```
+
+А вот такой слегка переделанный код уже не будет выявляться правилом
+- т.к. переустановка выполняется не всегда, а только при выполнения условия.
+```bsl
+МояПеременная = СтрЗаменить(Текст, " ", "");
+Если Условие Тогда
+    МояПеременная = СтрЗаменить(Текст, ";", "");
+КонецЕсли;
+Возврат МояПеременная;
+```
+
+Часто встречающаяся "ошибка последней строки"
+```bsl
+ТемаПисьма                             = ДанныеЗаполнения.Тема;// потерялось
+ТекстШаблонаПисьмаHTML                 = ДанныеЗаполнения.ТекстHTML;
+ТекстШаблонаПисьма                     = ДанныеЗаполнения.Текст;
+ТемаПисьма                             = ДанныеЗаполнения.Тема; // а здесь переопредели
+Наименование                           = ДанныеЗаполнения.Тема;
+```
+
+Еще подозрительный код - переменная `Файл` меняется несколько раз, и во втором случае ошибочно.
+```bsl
+Процедура ПолучитьФайлОбработки()
+    Файл = Новый Файл(КаталогФич); // нет замечания
+    Если Не Файл.Существует() Тогда
+        Возврат;
+    КонецЕсли;
+
+    Файл = Новый Файл(КаталогФич); // замечание
+    НачальныйКаталог = КаталогФич;
+
+    Файл = Новый Файл(НачальныйКаталог);
+КонецПроцедуры
+```
+
+Пример подозрительного кода - Инициализация переменных в начале метода
+```bsl
+Функция ПолучитьПутьФайлаВРабочемКаталоге(ДанныеФайла)
+
+	ПутьДляВозврата = "";
+	ПолноеИмяФайла = ""; // замечание
+	ИмяКаталога = РабочийКаталогПользователя();
+
+	// Сперва пытаемся найти такую запись в регистре сведений.
+	ПолноеИмяФайла = ДанныеФайла.ПолноеИмяФайлаВРабочемКаталоге;
+```
+- начальная установка `КэшНастроек` не имеет смысла
+
+**Примеры исключений**
+
+- 1 в коллекцию добавляются разные значения без явного переиспользования
+```bsl
+ВидПрава = ВидыПрав.Добавить(); // будет выдано замечание, хотя код валиден
+ВидПрава = ВидыПрав.Добавить();
+
+НовыйПереход = ТаблицаПереходовНоваяСтрока("Начало"); // будет выдано замечание, хотя код валиден
+НовыйПереход = ТаблицаПереходовНоваяСтрока("НастройкаВыгрузки");
+```
+Код выше вполне валиден, но его можно улучшить и упростить, явно выразив свои намерения, избавившись от присваивания переменным и дублирования имен переменных
+Исправленный код
+```bsl
+ВидыПрав.Добавить();
+ВидыПрав.Добавить();
+
+ТаблицаПереходовНоваяСтрока("Начало");
+ТаблицаПереходовНоваяСтрока("НастройкаВыгрузки");
+```
+
+Пример полезного замечания для подобных дублей добавления в коллекцию - пример из типовой конфигурации
+```bsl
+ВидПрава = ВидыПрав.Добавить(); // вот тут ошибка!
+ВидПрава = "Просмотр"; // т.к. ниже опечатка, автор кода забыл добавить .Имя
+ВидПрава.Интерактивное = Истина;
+
+ВидПрава = ВидыПрав.Добавить();
+ВидПрава.Имя = "Редактирование";
+```
+
+- 2 обработка переменных в блоках Попытка и Исключение
+```bsl
+Процедура УстановитьБлокировку()
+    Блокировка = Новый БлокировкаДанных;
+
+    НачатьТранзакцию();
+    Попытка
+        ЭтоОшибкаБлокировки = Истина; // будет выдано замечание, хотя код валиден
+        Блокировка.Заблокировать(); // здесь возможно исключение, и поэтому до следующей строки выполнение может не дойти
+
+        ЭтоОшибкаБлокировки = Ложь;
+        ЗафиксироватьТранзакцию();
+    Исключение
+        ОтменитьТранзакцию();
+        Если ЭтоОшибкаБлокировки Тогда
+          ОбработкаОшибкиБлокировки();
+        КонецЕсли;
+    КонецПопытки;
+КонецПроцедуры
+```
+
+- 3 одно и то же имя счетчика в соседних циклах, причем счетчик цикла в цикле не используется
+```bsl
+Для НомерЯчейки = 1 По 2 Цикл // будет выдано замечание, хотя код валиден
+    ТабличныйДокумент.Присоединить(ПустаяЯчейка);
+КонецЦикла;
+
+Для НомерЯчейки = 1 По КоличествоЯчеекДляЗаполнения - 2 Цикл
+    ПечатьСтроки(ЗначениеЗаполнения);
+КонецЦикла;
+```
+В этом коде счетчик `НомерЯчейки` фактически используется в обоих циклах.
+Такой код лучше переписать, используя уникальные имена счетчиков в обоих циклах, что повысит читаемость и упростит сопровождение.
+
+## Источники
+<!-- Необходимо указывать ссылки на все источники, из которых почерпнута информация для создания диагностики -->
+* [MITRE, CWE-563 - Assignment to Variable without Use](https://cwe.mitre.org/data/definitions/563.html)
+* [MITRE, CWE-1109 - Use of Same Variable for Multiple Purposes](https://cwe.mitre.org/data/definitions/1109.html)
+* [PVS-Studio.V763. Parameter is always rewritten in function body before being used.](https://pvs-studio.com/ru/docs/warnings/v763)

docs/en/diagnostics/LostVariable.md

@@ -0,0 +1,16 @@
+# Lost variable (LostVariable)
+
+<!-- Блоки выше заполняются автоматически, не трогать -->
+## Description
+<!-- Описание диагностики заполняется вручную. Необходимо понятным языком описать смысл и схему работу -->
+
+## Examples
+<!-- В данном разделе приводятся примеры, на которые диагностика срабатывает, а также можно привести пример, как можно исправить ситуацию -->
+
+## Sources
+<!-- Необходимо указывать ссылки на все источники, из которых почерпнута информация для создания диагностики -->
+<!-- Примеры источников
+
+* Источник: [Стандарт: Тексты модулей](https://its.1c.ru/db/v8std#content:456:hdoc)
+* Полезная информация: [Отказ от использования модальных окон](https://its.1c.ru/db/metod8dev#content:5272:hdoc)
+* Источник: [Cognitive complexity, ver. 1.4](https://www.sonarsource.com/docs/CognitiveComplexity.pdf) -->