Missed committing the new files!

data/neurons/mechanisms/Im_ms.mod

@@ -0,0 +1,88 @@
+COMMENT
+Mechanism taken from Doron et al., 2017
+https://senselab.med.yale.edu/ModelDB/ShowModel.cshtml?model=231427&file=/reproduction/Im.mod#tabs-2
+
+Reference :     Adams et al. 1982 - M-currents and other potassium currents in bullfrog sympathetic neurones
+
+corrected rates using q10 = 2.3, target temperature 34, orginal 21
+
+
+ENDCOMMENT
+
+NEURON	{
+	SUFFIX Im_ms
+	USEION k READ ek WRITE ik
+	RANGE gbar, gIm, ik
+
+    USEION PKA READ PKAi VALENCE 0
+    RANGE mod_pka_g_min, mod_pka_g_max, mod_pka_g_half, mod_pka_g_slope 
+    RANGE modulation_factor
+
+}
+
+UNITS	{
+	(S) = (siemens)
+	(mV) = (millivolt)
+	(mA) = (milliamp)
+}
+
+PARAMETER	{
+     gbar = 0.00001 (S/cm2)
+
+    mod_pka_g_min = 1 (1)
+    mod_pka_g_max = 1 (1)
+    mod_pka_g_half = 0.000100 (mM)
+    mod_pka_g_slope = 0.01 (mM)		    
+}
+
+ASSIGNED	{
+	v	(mV)
+	ek	(mV)
+	ik	(mA/cm2)
+	gIm	(S/cm2)
+	mInf
+	mTau
+	mAlpha
+	mBeta
+    PKAi (mM)
+    modulation_factor (1)
+}
+
+STATE	{ 
+	m
+}
+
+BREAKPOINT	{
+     SOLVE states METHOD cnexp
+    modulation_factor=modulation(PKAi, mod_pka_g_min, mod_pka_g_max, mod_pka_g_half, mod_pka_g_slope)	   
+
+	gIm = gbar*m*modulation_factor
+	ik = gIm*(v-ek)
+}
+
+DERIVATIVE states	{
+	rates()
+	m' = (mInf-m)/mTau
+}
+
+INITIAL{
+	rates()
+	m = mInf
+}
+
+PROCEDURE rates(){
+  LOCAL qt
+  qt = 2.3^((34-21)/10)
+
+	UNITSOFF
+		mAlpha = 3.3e-3*exp(2.5*0.04*(v - -35))
+		mBeta = 3.3e-3*exp(-2.5*0.04*(v - -35))
+		mInf = mAlpha/(mAlpha + mBeta)
+		mTau = (1/(mAlpha + mBeta))/qt
+	UNITSON
+}
+
+FUNCTION modulation(conc (mM), mod_min (1), mod_max (1), mod_half (mM), mod_slope (mM)) (1) {
+    : returns modulation factor
+    modulation = mod_min + (mod_max-mod_min) / (1 + exp(-(conc - mod_half)/mod_slope))
+}

data/neurons/mechanisms/NO.mod

@@ -0,0 +1,90 @@
+COMMENT
+Two state kinetic scheme synapse which comes from Expsyn modfile which was fitted with new time constants to describe the effect of nitric oxide coupled to a spike integrating mechanisms (Infire1)
+ENDCOMMENT
+
+NEURON {
+	POINT_PROCESS NO
+	RANGE tau1, tau2, e, i
+	NONSPECIFIC_CURRENT i
+	RANGE g, m
+}
+
+UNITS {
+	(nA) = (nanoamp)
+	(mV) = (millivolt)
+	(uS) = (microsiemens)
+}
+
+PARAMETER {
+	tau1 = 2000 (ms) <1e-9,1e9>
+	tau2 = 3000 (ms) <1e-9,1e9>
+	e=0	(mV)
+	tau = 1000 (ms)
+	refrac = 10 (ms)
+}
+
+ASSIGNED {
+	v (mV)
+	i (nA)
+	g (uS)
+	factor
+	m
+	t0(ms)
+	refractory
+}
+
+STATE {
+	A (uS)
+	B (uS)
+}
+
+INITIAL {
+	LOCAL tp
+	if (tau1/tau2 > 0.9999) {
+		tau1 = 0.9999*tau2
+	}
+	if (tau1/tau2 < 1e-9) {
+		tau1 = tau2*1e-9
+	}
+	A = 0
+	B = 0
+	tp = (tau1*tau2)/(tau2 - tau1) * log(tau2/tau1)
+	factor = -exp(-tp/tau1) + exp(-tp/tau2)
+				     factor = 1/factor
+						     m = 0
+	t0 = t
+	refractory = 0 : 0-integrates input, 1-refractory
+}
+
+BREAKPOINT {
+	SOLVE state METHOD cnexp
+	g = B - A
+	i = g*(v - e)
+}
+
+DERIVATIVE state {
+	A' = -A/tau1
+	B' = -B/tau2
+}
+
+
+NET_RECEIVE(weight (uS)) {
+     if (refractory == 0) { : inputs integrated only when excitable
+		m = m*exp(-(t - t0)/tau)
+		t0 = t
+		m = m + 0.075
+		if (m > 1) {
+			refractory = 1
+			m = 2
+
+			A = A + weight*factor
+			B = B + weight*factor
+
+		}
+	}else if (m==2) { : ready to integrate again
+		t0 = t
+		refractory = 0
+		m = 0
+	}
+
+}

data/neurons/mechanisms/bk_ch.mod

@@ -0,0 +1,105 @@
+: BK-type Purkinje calcium-activated potassium current
+: Created 8/19/02 - nwg
+
+NEURON {
+       SUFFIX bk_ch
+       USEION k READ ek WRITE ik
+       USEION ca READ cai
+       RANGE gbar, ik, g
+       GLOBAL minf, mtau, hinf, htau, zinf, ztau
+       GLOBAL m_vh, m_k, mtau_y0, mtau_vh1, mtau_vh2, mtau_k1, mtau_k2
+       GLOBAL z_coef, ztau
+       GLOBAL h_y0, h_vh, h_k, htau_y0, htau_vh1, htau_vh2, htau_k1, htau_k2
+}
+
+UNITS {
+      (mV) = (millivolt)
+      (mA) = (milliamp)
+      (mM) = (milli/liter)
+}
+
+PARAMETER {
+          v            (mV)
+          gbar = .007 (mho/cm2)
+
+          m_vh = -28.9           (mV)
+          m_k = 6.2            (mV)
+          mtau_y0 = .000505     (s)
+          mtau_vh1 = -33.3     (mV)
+          mtau_k1 = -10         (mV)
+          mtau_vh2 = 86.4       (mV)
+          mtau_k2 = 10.1        (mV)
+
+          z_coef = .001        (mM)
+          ztau = 1              (ms)
+
+          h_y0 = .085
+          h_vh = -32          (mV)
+          h_k = 5.8             (mV)
+          htau_y0 = .0019      (s)
+          htau_vh1 = -54.2       (mV)
+          htau_k1 = -12.9       (mV)
+          htau_vh2 = 48.5      (mV)
+          htau_k2 = 5.2        (mV)
+
+          ek           (mV)
+          cai          (mM)
+}
+
+ASSIGNED {
+         minf
+         mtau          (ms)
+         hinf
+         htau          (ms)
+         zinf
+	 g	(S/cm2)
+         ik            (mA/cm2)
+}
+
+STATE {
+      m   FROM 0 TO 1
+      z   FROM 0 TO 1
+      h   FROM 0 TO 1
+}
+
+BREAKPOINT {
+     SOLVE states METHOD cnexp
+	   g = gbar * m * m * m * z * z * h
+           ik = g * (v - ek)
+}
+
+DERIVATIVE states {
+        rates(v)
+
+        m' = (minf - m) / mtau
+        h' = (hinf - h) / htau
+        z' = (zinf - z) / ztau
+}
+
+PROCEDURE rates(Vm (mV)) {
+          LOCAL v
+          v = Vm + 5
+          minf = 1 / (1 + exp(-(v - (m_vh)) / m_k))
+          mtau = (1e3) * (mtau_y0 + 1/(exp((v+ mtau_vh1)/mtau_k1) + exp((v+mtau_vh2)/mtau_k2)))
+          zinf = 1/(1 + z_coef / cai)
+          hinf = h_y0 + (1-h_y0) / (1+exp((v - h_vh)/h_k))
+          htau = (1e3) * (htau_y0 + 1/(exp((v + htau_vh1)/htau_k1)+exp((v+htau_vh2)/htau_k2)))
+}
+
+INITIAL {
+        rates(v)
+        m = minf
+        z = zinf
+        h = hinf
+}
+
+COMMENT
+From model:
+Maurice N, Mercer J, Chan CS, Hernandez-Lopez S, Held J, Tkatch T, Surmeier DJ. 
+D2 dopamine receptor-mediated modulation of voltage-dependent Na+ channels 
+reduces autonomous activity in striatal cholinergic interneurons. 
+J Neurosci. 2004 Nov 17;24(46):10289-301. doi: 10.1523/JNEUROSCI.2155-04.2004. 
+PMID: 15548642; PMCID: PMC6730305.
+
+
+ENDCOMMENT

data/neurons/mechanisms/bk_fs.mod

@@ -0,0 +1,99 @@
+TITLE BK-type calcium activated K channel (KCa1.1)
+
+UNITS {
+    (molar) = (1/liter)
+    (mV) = (millivolt)
+    (mA) = (milliamp)
+    (mM) = (millimolar)
+    FARADAY = (faraday) (kilocoulombs)
+    R = (k-mole) (joule/degC)
+}
+
+NEURON {
+    SUFFIX bk_fs
+    USEION ca READ cai
+    USEION k READ ek WRITE ik
+    RANGE gbar, ik
+}
+
+PARAMETER {
+    gbar = 0.0 (mho/cm2)
+    k1 = 0.003 (mM)
+    k4 = 0.009 (mM)
+    d1 = 0.84
+    d4 = 1.0
+    q = 1	: body temperature 35 C
+}
+
+ASSIGNED {
+    v (mV)
+    ik (mA/cm2)
+    celsius (degC)
+    cai (mM) 
+    ek (mV)
+    oinf
+    otau (ms)
+}
+
+STATE { o }
+
+BREAKPOINT {
+    SOLVE state METHOD cnexp
+    ik = gbar*o*(v-ek)
+}
+
+DERIVATIVE state {
+    rate(v, cai)
+    o' = (oinf-o)/otau*q
+}
+
+INITIAL {
+    rate(v, cai)
+    o = oinf
+}
+
+PROCEDURE rate(v (mV), ca (mM)) {
+    LOCAL a, b, sum, z
+    UNITSOFF
+    z = 1e-3*2*FARADAY/(R*(celsius+273.15))
+    a = 0.48*ca/(ca+k1*exp(-z*d1*v))
+    b = 0.28/(1+ca/(k4*exp(-z*d4*v)))
+    sum = a+b
+    oinf = a/sum
+    otau = 1/sum
+    UNITSON
+}
+
+COMMENT
+
+Experimental data was obtained from BKCa channels from rat brain injected
+as cRNAs into Xenopus oocytes [1].  Electrophysiological recordings were
+performed at room temperature 22-24 C [1, supporting online material].
+
+Original model [2, model 3 in Tab.1] was implemented by De Schutter
+and adapted by Kai Du.  In the model revisions [3,4] parameters k1 and k4
+[2, channel A in Tab.2] were adjusted to fit rat/Xenopus data
+[1, Fig.3C and Fig.4A, 10 uM Ca] at body temperature 35 C.
+
+NEURON implementation by Alexander Kozlov <akozlov@kth.se>.
+
+[1] Berkefeld H, Sailer CA, Bildl W, Rohde V, Thumfart JO, Eble S,
+Klugbauer N, Reisinger E, Bischofberger J, Oliver D, Knaus HG, Schulte U,
+Fakler B (2006) BKCa-Cav channel complexes mediate rapid and localized
+Ca2+-activated K+ signaling. Science 314(5799):615-20.
+
+[2] Moczydlowski E, Latorre R (1983) Gating kinetics of Ca2+-activated K+
+channels from rat muscle incorporated into planar lipid bilayers. Evidence
+for two voltage-dependent Ca2+ binding reactions. J Gen Physiol
+82(4):511-42.
+
+[3] Evans RC, Morera-Herreras T, Cui Y, Du K, Sheehan T, Kotaleski JH,
+Venance L, Blackwell KT (2012) The effects of NMDA subunit composition on
+calcium influx and spike timing-dependent plasticity in striatal medium
+spiny neurons. PLoS Comput Biol 8(4):e1002493.
+
+[4] Evans RC, Maniar YM, Blackwell KT (2013) Dynamic modulation of
+spike timing-dependent calcium influx during corticostriatal upstates. J
+Neurophysiol 110(7):1631-45.
+
+ENDCOMMENT