link to ecp components via cmake config targets

CMakeLists.txt

@@ -1,5 +1,5 @@
-PROJECT(SCR)
-CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
+CMAKE_MINIMUM_REQUIRED(VERSION 3.14)
+PROJECT(SCR VERSION 3.0.1)
 
 # Find Packages & Files
 LIST(APPEND CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake")
@@ -11,64 +11,36 @@ INCLUDE(SCR_OPTIONS)
 INCLUDE(CheckIncludeFile)
 
 ## AXL
-FIND_PACKAGE(AXL REQUIRED)
-IF(AXL_FOUND)
-	INCLUDE_DIRECTORIES(${AXL_INCLUDE_DIRS})
-    LIST(APPEND SCR_EXTERNAL_LIBS ${AXL_MPI_LIBRARIES})
-	LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS ${AXL_LIBRARIES})
-	LIST(APPEND SCR_LINK_LINE "-laxl_mpi")
-ENDIF(AXL_FOUND)
+FIND_PACKAGE(axl REQUIRED)
+LIST(APPEND SCR_EXTERNAL_LIBS axl::axl_mpi)
+LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS axl::axl)
 
 ## ER
-FIND_PACKAGE(ER REQUIRED)
-IF(ER_FOUND)
-	INCLUDE_DIRECTORIES(${ER_INCLUDE_DIRS})
-	LIST(APPEND SCR_EXTERNAL_LIBS ${ER_LIBRARIES})
-	LIST(APPEND SCR_LINK_LINE "-ler")
-ENDIF(ER_FOUND)
+FIND_PACKAGE(er REQUIRED)
+LIST(APPEND SCR_EXTERNAL_LIBS er::er)
 
 ## SHUFFILE
-FIND_PACKAGE(SHUFFILE REQUIRED)
-IF(SHUFFILE_FOUND)
-	INCLUDE_DIRECTORIES(${SHUFFILE_INCLUDE_DIRS})
-	LIST(APPEND SCR_EXTERNAL_LIBS ${SHUFFILE_LIBRARIES})
-	LIST(APPEND SCR_LINK_LINE "-lshuffile")
-ENDIF(SHUFFILE_FOUND)
+FIND_PACKAGE(shuffile REQUIRED)
+LIST(APPEND SCR_EXTERNAL_LIBS shuffile::shuffile)
 
 ## REDSET
-FIND_PACKAGE(REDSET REQUIRED)
-IF(REDSET_FOUND)
-	INCLUDE_DIRECTORIES(${REDSET_INCLUDE_DIRS})
-	LIST(APPEND SCR_EXTERNAL_LIBS ${REDSET_LIBRARIES})
-	LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS ${REDSET_BASE_LIBRARIES})
-	LIST(APPEND SCR_LINK_LINE "-lredset")
-ENDIF(REDSET_FOUND)
+FIND_PACKAGE(redset REQUIRED)
+LIST(APPEND SCR_EXTERNAL_LIBS redset::redset)
+LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS redset::redset_base)
 
 ## SPATH
-FIND_PACKAGE(SPATH REQUIRED)
-IF(SPATH_FOUND)
-	INCLUDE_DIRECTORIES(${SPATH_INCLUDE_DIRS})
-	LIST(APPEND SCR_EXTERNAL_LIBS ${SPATH_LIBRARIES})
-	LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS ${SPATH_BASE_LIBRARIES})
-	LIST(APPEND SCR_LINK_LINE "-lspath")
-ENDIF(SPATH_FOUND)
+FIND_PACKAGE(spath REQUIRED)
+LIST(APPEND SCR_EXTERNAL_LIBS spath::spath)
+LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS spath::spath_base)
 
 ## RankStr
-FIND_PACKAGE(RANKSTR REQUIRED)
-IF(RANKSTR_FOUND)
-	INCLUDE_DIRECTORIES(${RANKSTR_INCLUDE_DIRS})
-	LIST(APPEND SCR_EXTERNAL_LIBS ${RANKSTR_LIBRARIES})
-	LIST(APPEND SCR_LINK_LINE "-lrankstr")
-ENDIF(RANKSTR_FOUND)
+FIND_PACKAGE(rankstr REQUIRED)
+LIST(APPEND SCR_EXTERNAL_LIBS rankstr::rankstr)
 
 ## KVTREE
-FIND_PACKAGE(KVTREE REQUIRED)
-IF(KVTREE_FOUND)
-	INCLUDE_DIRECTORIES(${KVTREE_INCLUDE_DIRS})
-	LIST(APPEND SCR_EXTERNAL_LIBS ${KVTREE_LIBRARIES})
-	LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS ${KVTREE_BASE_LIBRARIES})
-	LIST(APPEND SCR_LINK_LINE "-lkvtree")
-ENDIF(KVTREE_FOUND)
+FIND_PACKAGE(kvtree REQUIRED)
+LIST(APPEND SCR_EXTERNAL_LIBS kvtree::kvtree)
+LIST(APPEND SCR_EXTERNAL_SERIAL_LIBS kvtree::kvtree_base)
 
 ## libdtcmp
 FIND_PACKAGE(DTCMP REQUIRED)
@@ -113,6 +85,27 @@ ENDIF()
 # Special Install Files
 INSTALL(FILES README.md DESTINATION ${CMAKE_INSTALL_DATADIR}/scr)
 
+# CMake configs
+
+# Install the exports file
+INSTALL(EXPORT scrTargets FILE scrTargets.cmake NAMESPACE scr:: DESTINATION share/scr/cmake)
+
+# Export so we can use in-tree
+EXPORT(EXPORT scrTargets NAMESPACE scr:: FILE scrTargets.cmake)
+
+# Setup the package config
+INCLUDE(CMakePackageConfigHelpers)
+CONFIGURE_PACKAGE_CONFIG_FILE(cmake/scrConfig.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/scrConfig.cmake INSTALL_DESTINATION share/scr/cmake)
+WRITE_BASIC_PACKAGE_VERSION_FILE(${CMAKE_CURRENT_BINARY_DIR}/scrConfigVersion.cmake COMPATIBILITY SameMajorVersion)
+
+# Install package config
+INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/scrConfig.cmake ${CMAKE_CURRENT_BINARY_DIR}/scrConfigVersion.cmake DESTINATION share/scr/cmake)
+INSTALL(FILES cmake/FindDTCMP.cmake DESTINATION share/scr/cmake)
+INSTALL(FILES cmake/FindLWGRP.cmake DESTINATION share/scr/cmake)
+INSTALL(FILES cmake/FindMySQL.cmake DESTINATION share/scr/cmake)
+INSTALL(FILES cmake/FindPDSH.cmake DESTINATION share/scr/cmake)
+INSTALL(FILES cmake/FindYOGRT.cmake DESTINATION share/scr/cmake)
+
 # Package
 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Scalable Checkpoint / Restart Library")
 SET(CPACK_PACKAGE_VENDOR "Lawrence Livermore National Laboratory")

cmake/FindLWGRP.cmake

@@ -0,0 +1,31 @@
+# - Try to find liblwgrp
+# Once done this will define
+#  LWGRP_FOUND - System has liblwgrp
+#  LWGRP_INCLUDE_DIRS - The liblwgrp include directories
+#  LWGRP_LIBRARIES - The libraries needed to use liblwgrp
+
+FIND_PATH(WITH_LWGRP_PREFIX
+    NAMES include/lwgrp.h
+)
+
+FIND_LIBRARY(LWGRP_LIBRARIES
+    NAMES lwgrp
+    HINTS ${WITH_LWGRP_PREFIX}/lib
+)
+
+FIND_PATH(LWGRP_INCLUDE_DIRS
+    NAMES lwgrp.h
+    HINTS ${WITH_LWGRP_PREFIX}/include
+)
+
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LWGRP DEFAULT_MSG
+    LWGRP_LIBRARIES
+    LWGRP_INCLUDE_DIRS
+)
+
+# Hide these vars from ccmake GUI
+MARK_AS_ADVANCED(
+	LWGRP_LIBRARIES
+	LWGRP_INCLUDE_DIRS
+)