Add nix config

.envrc

@@ -0,0 +1 @@
+use nix

.gitignore

@@ -1,10 +1,12 @@
 /target
 .ignore
 .vscode
-fig
+.direnv
+**/fig
 **/*.png
 !filegram-web/images/*.png
 **/*.blb
 **/*.key
 **/dist
+result
 Cargo.lock

default.nix

@@ -0,0 +1,9 @@
+(import (
+  let
+    lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+  in fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+    sha256 = lock.nodes.flake-compat.locked.narHash; }
+) {
+  src =  ./.;
+}).defaultNix

filegram-web/Cargo.toml

@@ -10,7 +10,7 @@ filegram = { path = "../filegram" }
 js-sys = "0.3.68"
 image = { version = "0.24.9", default-features = false }
 web-sys = { version = "0.3.67", default-features = false }
-wasm-bindgen = { default-features = false, version = "0.2.91" }
+wasm-bindgen = { version = "0.2.91", default-features = false }
 yew = { version = "0.21.0", features = ["csr"] }
 gloo-file = "0.3.0"
 gloo-utils = { version = "0.2.0", default-features = false }

filegram-web/src/decode.rs

@@ -175,9 +175,7 @@ impl DecodeComponent {
 
     fn download_file(file_name: &str, url: &ObjectUrl) {
         let download_element = document().create_element("a").unwrap();
-        download_element
-            .set_attribute("href", url)
-            .unwrap();
+        download_element.set_attribute("href", url).unwrap();
         download_element
             .set_attribute("download", file_name)
             .unwrap();

filegram-web/src/encode.rs

@@ -160,9 +160,7 @@ impl EncodeComponent {
 
     fn download_file(file_name: &str, url: &ObjectUrl) {
         let download_element = document().create_element("a").unwrap();
-        download_element
-            .set_attribute("href", url)
-            .unwrap();
+        download_element.set_attribute("href", url).unwrap();
         download_element
             .set_attribute("download", file_name)
             .unwrap();

filegram/src/padding.rs

@@ -13,7 +13,7 @@ pub fn pad_block(data: Vec<u8>) -> Vec<u8> {
     block.to_vec()
 }
 
-pub fn unpad_block(data: &Vec<u8>) -> Result<Vec<u8>, UnpadError> {
+pub fn unpad_block(data: &[u8]) -> Result<Vec<u8>, UnpadError> {
     let mut block: GenericArray<u8, U255> = GenericArray::clone_from_slice(&[0u8; BUFFER_SIZE]);
     let data_len = data.len();
     block[..data_len].copy_from_slice(data);

flake.nix

@@ -0,0 +1,161 @@
+{
+  description = "Filegram project flake.";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+
+    # The version of wasm-bindgen-cli needs to match the version in Cargo.lock
+    # Update this to include the version you need
+    nixpkgs-for-wasm-bindgen.url = "github:NixOS/nixpkgs/807c549feabce7eddbf259dbdcec9e0600a0660d";
+
+    crane = {
+      url = "github:ipetkov/crane";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    flake-utils.url = "github:numtide/flake-utils";
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs = {
+        nixpkgs.follows = "nixpkgs";
+        flake-utils.follows = "flake-utils";
+      };
+    };
+  };
+
+  outputs = { self, nixpkgs, crane, flake-utils, flake-compat, rust-overlay, nixpkgs-for-wasm-bindgen, ... }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = import nixpkgs {
+          inherit system;
+          overlays = [ (import rust-overlay) ];
+        };
+
+        inherit (pkgs) lib;
+
+        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
+          # Set the build targets supported by the toolchain,
+          # wasm32-unknown-unknown is required for trunk.
+          targets = [ "wasm32-unknown-unknown" ];
+        };
+        craneLib = ((crane.mkLib pkgs).overrideToolchain rustToolchain).overrideScope (_final: _prev: {
+          # The version of wasm-bindgen-cli needs to match the version in Cargo.lock. You
+          # can unpin this if your nixpkgs commit contains the appropriate wasm-bindgen-cli version
+          inherit (import nixpkgs-for-wasm-bindgen { inherit system; }) wasm-bindgen-cli;
+        });
+
+        # When filtering sources, we want to allow assets other than .rs files
+        src = lib.cleanSourceWith {
+          src = ./.; # The original, unfiltered source
+          filter = path: type:
+            (lib.hasSuffix "\.html" path) ||
+            (lib.hasSuffix "\.scss" path) ||
+            (lib.hasSuffix "\.css" path) ||
+            # Example of a folder for images, icons, etc
+            (lib.hasInfix "/assets/" path) ||
+            # Default filter from crane (allow .rs files)
+            (craneLib.filterCargoSources path type)
+          ;
+        };
+
+
+        # Arguments to be used by both the client and the server
+        # When building a workspace with crane, it's a good idea
+        # to set "pname" and "version".
+        commonArgs = {
+          inherit src;
+          pname = "filegram";
+          version = "0.2.0";
+          strictDeps = true;
+        };
+
+        # Native packages
+
+        nativeArgs = commonArgs // {
+          pname = "filegram-native";
+        };
+
+        # Build *just* the cargo dependencies, so we can reuse
+        # all of that work (e.g. via cachix) when running in CI
+        cargoArtifacts = craneLib.buildDepsOnly nativeArgs;
+
+        # Filegram CLI
+        filegram-cli = craneLib.buildPackage (nativeArgs // {
+          inherit cargoArtifacts;
+          pname = "filegram-cli";
+          cargoExtraArgs = "--package=filegram-cli";
+        });
+
+        # Wasm packages
+
+        # it's not possible to build the cli on the
+        # wasm32 target, so we only build the web app.
+        wasmArgs = commonArgs // {
+          pname = "filegram-wasm";
+          cargoExtraArgs = "--package=filegram-web";
+          CARGO_BUILD_TARGET = "wasm32-unknown-unknown";
+        };
+
+        cargoArtifactsWasm = craneLib.buildDepsOnly (wasmArgs // {
+          doCheck = false;
+        });
+
+        # Build the frontend of the application.
+        # This derivation is a directory you can put on a webserver.
+        filegram-web = craneLib.buildTrunkPackage (wasmArgs // {
+          pname = "filegram-web";
+          cargoArtifacts = cargoArtifactsWasm;
+          trunkIndexPath = "filegram-web/index.html";
+          wasm-bindgen-cli = pkgs.wasm-bindgen-cli.override {
+            version = "0.2.91";
+          };
+        });
+      in
+      {
+        checks = {
+          # Build the crate as part of `nix flake check` for convenience
+          inherit filegram-cli filegram-web;
+
+          # Run clippy (and deny all warnings) on the crate source,
+          # again, reusing the dependency artifacts from above.
+          #
+          # Note that this is done as a separate derivation so that
+          # we can block the CI if there are issues here, but not
+          # prevent downstream consumers from building our crate by itself.
+          filegram-clippy = craneLib.cargoClippy (commonArgs // {
+            inherit cargoArtifacts;
+            cargoClippyExtraArgs = "--all-targets -- --deny warnings";
+          });
+
+          # Check formatting
+          filegram-fmt = craneLib.cargoFmt commonArgs;
+        };
+
+        packages = rec {
+          cli = filegram-cli;
+          web = filegram-web;
+          default = cli;
+        };
+
+        apps.default = flake-utils.lib.mkApp {
+          name = "filegram-cli";
+          drv = filegram-cli;
+        };
+
+        devShells.default = craneLib.devShell {
+          # Inherit inputs from checks.
+          checks = self.checks.${system};
+
+          # Extra inputs can be added here; cargo and rustc are provided by default.
+          packages = [
+            pkgs.trunk
+          ];
+        };
+      });
+}
+

shell.nix

@@ -0,0 +1,9 @@
+(import (
+  let
+    lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+  in fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+    sha256 = lock.nodes.flake-compat.locked.narHash; }
+) {
+  src =  ./.;
+}).shellNix