build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            url("https://dl.bintray.com/palantir/releases/")
        }
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:2.1.4.RELEASE")
        // https://mvnrepository.com/artifact/com.palantir.gradle.docker/gradle-docker
        classpath(group: 'com.palantir.gradle.docker', name: 'gradle-docker', version: '0.22.1')
    }
}

group = 'rls42'

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'
apply plugin: 'com.palantir.docker'

bootJar {
    baseName = 'metadata-service'
    version =  '1.0.1'
}

repositories {
    mavenCentral()
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

configurations {
    developmentOnly
    runtimeClasspath {
        extendsFrom developmentOnly
    }
}

task unpack(type: Copy) {
    dependsOn bootJar
    from(zipTree(tasks.bootJar.outputs.files.singleFile))
    into("build/dependency")
}

docker {
    name "${project.group}/${bootJar.baseName}:${bootJar.version}"
    copySpec.from(tasks.unpack.outputs).into("dependency")
    buildArgs(['DEPENDENCY': "dependency"])
}

dependencies {
    compile("org.springframework.boot:spring-boot-starter-web")
    compile("org.springframework.boot:spring-boot-starter-actuator")
    // JPA Data (We are going to use Repositories, Entities, Hibernate, etc...)
    compile 'org.springframework.boot:spring-boot-starter-data-jpa'
    compile "org.flywaydb:flyway-core:5.2.4"
    // https://mvnrepository.com/artifact/com.google.guava/guava
    compile group: 'com.google.guava', name: 'guava', version: '28.0-jre'

    // Use MySQL Connector-J
    compile 'mysql:mysql-connector-java'

    testCompile("junit:junit")
    testCompile("org.springframework.boot:spring-boot-starter-test")
}