Add header_map rule

Author: luispadron

apple/header_map.bzl

@@ -0,0 +1,24 @@
+# Copyright 2024 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""
+Rules for creating header maps.
+"""
+
+load(
+    "@build_bazel_rules_apple//apple/internal:header_map.bzl",
+    _header_map = "header_map",
+)
+
+header_map = _header_map

apple/internal/header_map.bzl

@@ -0,0 +1,171 @@
+# Copyright 2024 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Rule for creating header_maps."""
+
+load("@build_bazel_rules_swift//swift:swift.bzl", "swift_common")
+
+HeaderMapInfo = provider(
+    doc = "Provides information about created `.hmap` (header map) files",
+    fields = {
+        "public_header_maps": "depset of paths of any public header maps",
+    },
+)
+
+def _write_header_map(actions, header_map_tool, output, namespace, hdrs_lists):
+    """Makes a binary hmap file by executing the header_map tool.
+
+    Args:
+        actions: a ctx.actions struct
+        header_map_tool: an executable pointing to @bazel_build_rules_ios//rules/hmap:hmaptool
+        output: the output file that will contain the built hmap
+        namespace: the prefix to be used for header imports
+        hdrs_lists: an array of enumerables containing headers to be added to the hmap
+    """
+
+    args = actions.args()
+    if namespace:
+        args.add("--namespace", namespace)
+
+    args.add("--output", output)
+
+    for hdrs in hdrs_lists:
+        args.add_all(hdrs)
+
+    args.set_param_file_format(format = "multiline")
+    args.use_param_file("@%s")
+
+    actions.run(
+        mnemonic = "HmapWrite",
+        arguments = [args],
+        executable = header_map_tool,
+        outputs = [output],
+    )
+
+def _header_map_impl(ctx):
+    """Implementation of the header_map() rule.
+
+    It creates a text file with mappings and creates an action that calls out to the header_map tool
+    to convert it to a binary header_map file.
+    """
+    hdrs_lists = [ctx.files.hdrs] if ctx.files.hdrs else []
+
+    for dep in ctx.attr.deps:
+        found_headers = []
+        if apple_common.Objc in dep:
+            found_headers.append(getattr(dep[apple_common.Objc], "direct_headers", []))
+        if CcInfo in dep:
+            found_headers.append(dep[CcInfo].compilation_context.direct_headers)
+        if not found_headers:
+            fail("Direct header provider: '%s' listed in 'deps' does not have any direct headers to provide." % dep)
+        hdrs_lists.extend(found_headers)
+
+    hdrs_lists = [[h for h in hdrs if h.basename.endswith(".h")] for hdrs in hdrs_lists]
+
+    _write_header_map(
+        actions = ctx.actions,
+        header_map_tool = ctx.executable._hmaptool,
+        output = ctx.outputs.header_map,
+        namespace = ctx.attr.namespace,
+        hdrs_lists = hdrs_lists,
+    )
+
+    return [
+        apple_common.new_objc_provider(),
+        swift_common.create_swift_info(),
+        CcInfo(
+            compilation_context = cc_common.create_compilation_context(
+                headers = depset([ctx.outputs.header_map]),
+            ),
+        ),
+        HeaderMapInfo(
+            public_header_maps = depset([ctx.outputs.header_map]),
+        ),
+    ]
+
+header_map = rule(
+    implementation = _header_map_impl,
+    output_to_genfiles = True,
+    attrs = {
+        "namespace": attr.string(
+            mandatory = False,
+            doc = "The prefix to be used for header imports",
+        ),
+        "hdrs": attr.label_list(
+            mandatory = False,
+            allow_files = True,
+            doc = "The list of headers included in the header_map",
+        ),
+        "deps": attr.label_list(
+            mandatory = False,
+            providers = [[apple_common.Objc], [CcInfo]],
+            doc = "Targets whose direct headers should be added to the list of hdrs and rooted at the namespace",
+        ),
+        "_hmaptool": attr.label(
+            executable = True,
+            cfg = "exec",
+            default = Label("//tools/hmaptool:hmaptool_swift"),
+        ),
+    },
+    outputs = {
+        "header_map": "%{name}.hmap",
+    },
+    doc = """\
+Creates a binary `.hmap` file from the given headers suitable for passing to clang.
+
+Headermaps can be used in `-I` and `-iquote` compile flags (as well as in `includes`) to tell clang where to find headers.
+This can be used to allow headers to be imported at a consistent path regardless of the package structure being used.
+
+For example, if you have a package structure like this:
+
+    ```
+    MyLib/
+        headers/
+            MyLib.h
+        MyLib.c
+        BUILD
+    ```
+
+And you want to import `MyLib.h` from `MyLib.c` using angle bracket imports: `#import <MyLib/MyLib.h>`
+You can create a header map like this:
+
+    ```bzl
+    header_map(
+        name = "MyLib.hmap",
+        hdrs = ["headers/MyLib.h"],
+    )
+    ```
+
+This generates a binary headermap that looks like:
+
+    ```
+    MyLib.h -> headers/MyLib.h
+    MyLib/MyLib.h -> headers/MyLib.h
+    ```
+
+Then update `deps`, `copts` and `includes` to use the header map:
+
+    ```bzl
+    objc_library(
+        name = "MyLib",
+        module_name = "MyLib",
+        srcs = ["MyLib.c"],
+        hdrs = ["headers/MyLib.h"],
+        deps = [":MyLib.hmap"],
+        copts = ["-I.]
+        includes = ["MyLib.hmap"]
+    )
+    ```
+    """,
+)

apple/internal/header_map_support.bzl

@@ -0,0 +1,80 @@
+# Copyright 2024 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Provides utilities for working with header_maps within macros and rules"""
+
+load("//apple/internal:header_map.bzl", "header_map")
+
+def _create_header_map_context(
+        name,
+        module_name,
+        hdrs,
+        deps):
+    """
+    Creates header_map(s) for the target with the given name.
+
+    Args:
+        name: The name of the target.
+        module_name: The name of the module to use in the header map.
+        hdrs: The public headers to include in the header mapm, these will be rooted
+            under module_name and flattened.
+        deps: The direct dependencies to include in the header map, any headers in the deps will be rooted
+            under this `module_name` and flattened.
+
+    Returns a struct (or `None` if no headers) with the following attributes:
+        copts: The compiler options to use when compiling a C family library with header maps.
+        includes: The includes to use when compiling a C family library with header maps.
+        swift_copts: The compiler options to use when compiling a Swift library with the header map.
+        header_maps: The labels to any generated header maps, these should be the inputs used with the `copts`.
+    """
+
+    public_hdrs_filegroup = name + ".public.hmap_hdrs"
+    public_hmap_name = name + ".public"
+
+    native.filegroup(
+        name = public_hdrs_filegroup,
+        srcs = hdrs,
+    )
+
+    header_map(
+        name = public_hmap_name,
+        namespace = module_name,
+        hdrs = [public_hdrs_filegroup],
+        deps = deps,
+    )
+
+    copts = [
+        "-I.",  # makes the package's bin dir available for use with #import <foo/foo.h>
+    ]
+    includes = [
+        "{}.hmap".format(public_hmap_name),  # propogates the header map include to target and things that depend on it
+    ]
+    header_maps = [
+        ":{}".format(public_hmap_name),
+    ]
+
+    swift_copts = []
+    for copt in copts:
+        swift_copts.extend(["-Xcc", copt])
+
+    return struct(
+        copts = copts,
+        includes = includes,
+        swift_copts = swift_copts,
+        header_maps = header_maps,
+    )
+
+header_map_support = struct(
+    create_header_map_context = _create_header_map_context,
+)

examples/multi_platform/MixedLib/BUILD

@@ -3,16 +3,41 @@ load(
     "swift_library",
 )
 load("//apple:apple.bzl", "experimental_mixed_language_library")
+load("//apple:header_map.bzl", "header_map")
 load("//apple:ios.bzl", "ios_unit_test")
 
+filegroup(
+    name = "MixedAnswer.public_headers.h",
+    srcs = [
+        "MixedAnswer.h",
+    ],
+)
+
 experimental_mixed_language_library(
     name = "MixedAnswer",
     srcs = [
         "MixedAnswer.m",
         "MixedAnswer.swift",
     ],
-    hdrs = ["MixedAnswer.h"],
+    hdrs = [
+        ":MixedAnswer.public_headers.h",
+    ],
     enable_modules = True,
+    includes = [
+        "MixedAnswerHeaderMap.hmap",
+    ],
+    objc_copts = ["-I."],
+    deps = [
+        ":MixedAnswerHeaderMap",
+    ],
+)
+
+header_map(
+    name = "MixedAnswerHeaderMap",
+    hdrs = [
+        ":MixedAnswer.public_headers.h",
+    ],
+    namespace = "MixedAnswer",
 )
 
 swift_library(
@@ -23,6 +48,19 @@ swift_library(
     deps = [":MixedAnswer"],
 )
 
+objc_library(
+    name = "ObjcLibDependingOnMixedLib",
+    srcs = [
+        "ObjcLibDependingOnMixedLib.m",
+    ],
+    hdrs = [
+        "ObjcLibDependingOnMixedLib.h",
+    ],
+    copts = ["-I."],
+    enable_modules = True,
+    deps = [":MixedAnswer"],
+)
+
 experimental_mixed_language_library(
     name = "MixedTestsLib",
     testonly = True,

examples/multi_platform/MixedLib/MixedAnswer.m

@@ -1,4 +1,5 @@
-#import "examples/multi_platform/MixedLib/MixedAnswer.h"
+#import <MixedAnswer/MixedAnswer.h>
+
 #import "examples/multi_platform/MixedLib/MixedAnswer-Swift.h"
 
 @implementation MixedAnswerObjc

examples/multi_platform/MixedLib/ObjcLibDependingOnMixedLib.h

@@ -0,0 +1,7 @@
+@import Foundation;
+
+@interface ObjcLibDependingOnMixedLib : NSObject
+
++ (void)doSomething;
+
+@end

examples/multi_platform/MixedLib/ObjcLibDependingOnMixedLib.m

@@ -0,0 +1,14 @@
+@import Foundation;
+
+#import <MixedAnswer/MixedAnswer.h>
+
+#import "ObjcLibDependingOnMixedLib.h"
+
+@implementation ObjcLibDependingOnMixedLib
+
++ (void)doSomething {
+  MixedAnswerObjc *objcAnswer __unused = [[MixedAnswerObjc alloc] init];
+  return;
+}
+
+@end