Config.cmake.in

@PACKAGE_INIT@

set(_control_libraries_supported_components state_representation dynamical_systems robot_model controllers)
set(control_libraries_LIBRARIES "@INSTALL_INTERFACE_LINK_LIBRARIES@")

include(CMakeFindDependencyMacro)
find_dependency(Eigen3)

# Find robot model dependencies if it is in the interface library list and no components are explicitly listed
if ("robot_model" IN_LIST control_libraries_LIBRARIES AND NOT control_libraries_FIND_COMPONENTS)
  find_dependency(pinocchio)
  find_dependency(OsqpEigen)
  find_dependency(osqp)
endif()

foreach(_comp ${control_libraries_FIND_COMPONENTS})
  if (${_comp} IN_LIST _control_libraries_supported_components)
    set(control_libraries_${_comp}_FOUND True)
  else()
    set_and_check(control_libraries_FOUND False)
    set_and_check(control_libraries_NOT_FOUND_MESSAGE "Unsupported component: ${_comp}")
  endif()

  # Find robot model dependencies if the corresponding components are explicitly listed
  if (${_comp} STREQUAL "controllers" OR ${_comp} STREQUAL "robot_model")
    find_dependency(pinocchio)
    find_dependency(OsqpEigen)
    find_dependency(osqp)
  endif()

  include("${CMAKE_CURRENT_LIST_DIR}/control_libraries_${_comp}_targets.cmake")
endforeach()

check_required_components(control_libraries)