cmake: Add ccache support

CMakeLists.txt

@@ -57,6 +57,12 @@ set(CMAKE_CXX_EXTENSIONS OFF)
 
 list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake/module)
 
+#=============================
+# Configurable options
+#=============================
+# When adding a new option, end the <help_text> with a full stop for consistency.
+option(WITH_CCACHE "Attempt to use ccache for compiling." ON)
+
 set(configure_warnings)
 
 include(CheckPIESupported)
@@ -178,6 +184,8 @@ target_link_libraries(core_interface INTERFACE
 
 include(cmake/introspection.cmake)
 
+include(cmake/ccache.cmake)
+
 include(ProcessConfigurations)
 set_default_config(RelWithDebInfo)
 
@@ -250,6 +258,7 @@ message("=================")
 message("C++ compiler .......................... ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}, ${CMAKE_CXX_COMPILER}")
 include(FlagsSummary)
 flags_summary()
+message("Use ccache for compiling .............. ${WITH_CCACHE}")
 message("\n")
 if(configure_warnings)
     message("  ******\n")

cmake/ccache.cmake

@@ -0,0 +1,25 @@
+# Copyright (c) 2023-present The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or https://opensource.org/license/mit/.
+
+if(NOT MSVC)
+  find_program(CCACHE_EXECUTABLE ccache)
+  if(CCACHE_EXECUTABLE)
+    execute_process(
+      COMMAND readlink -f ${CMAKE_CXX_COMPILER}
+      OUTPUT_VARIABLE compiler_resolved_link
+      ERROR_QUIET
+      OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+    if(CCACHE_EXECUTABLE STREQUAL compiler_resolved_link)
+      set(WITH_CCACHE "ccache masquerades as the compiler")
+    elseif(WITH_CCACHE)
+      list(APPEND CMAKE_C_COMPILER_LAUNCHER ${CCACHE_EXECUTABLE})
+      list(APPEND CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE_EXECUTABLE})
+    endif()
+  else()
+    set(WITH_CCACHE OFF)
+  endif()
+endif()
+
+mark_as_advanced(CCACHE_EXECUTABLE)