Added tests for the finalization exporter

src/IllimaniProfiler-Tests/IllAbstractExporter.extension.st

@@ -0,0 +1,7 @@
+Extension { #name : 'IllAbstractExporter' }
+
+{ #category : '*IllimaniProfiler-Tests' }
+IllAbstractExporter >> baseFileName [
+
+	^ baseFileName
+]

src/IllimaniProfiler-Tests/IllFinalizationExporterTest.class.st

@@ -0,0 +1,68 @@
+"
+An IllFinalizationExporterTest is a test class for testing the behavior of IllFinalizationExporter
+"
+Class {
+	#name : 'IllFinalizationExporterTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'exporter',
+		'header',
+		'mockProfiler',
+		'mockGCMonitor'
+	],
+	#category : 'IllimaniProfiler-Tests',
+	#package : 'IllimaniProfiler-Tests'
+}
+
+{ #category : 'running' }
+IllFinalizationExporterTest >> fakeAllocations [
+
+	| allocatedClasses |
+	allocatedClasses := 'Kernel' asPackage definedClasses asArray first: 10.
+	^ (1 to: 1000) collect: [ :i | IllEphemeron new
+		allocatedObjectClass: allocatedClasses atRandom;
+		sizeInBytes: 100;
+		finalizationTime: Time primUTCMicrosecondsClock;
+		updateStatistics;
+		yourself ]
+]
+
+{ #category : 'running' }
+IllFinalizationExporterTest >> setUp [
+
+	super setUp.
+	mockGCMonitor := IllMockGCMonitor new.
+	mockProfiler := IllMockProfiler new
+		objectAllocations: self fakeAllocations;
+		gcMonitor: mockGCMonitor;
+		yourself.
+	exporter := IllFinalizationExporter new
+		profiler: mockProfiler;
+		yourself
+]
+
+{ #category : 'tests' }
+IllFinalizationExporterTest >> testExportData [
+
+	| readStream csvReader actualHeader line createdFile |
+	header := #( 'finalizationTimeInMicroSeconds' 'sizeInBytes' 'initializationTimeInMicroSeconds'
+		'allocatedObjectClass' 'survivedScavenges' 'survivedFullGCs' 'forcedFinalization' ).
+	exporter exportData.
+
+	createdFile := (exporter baseFileName , '.csv') asFileReference.
+	self assert: createdFile exists.
+
+	readStream := createdFile readStream.
+	csvReader := NeoCSVReader on: readStream.
+
+	actualHeader := csvReader next.
+	line := csvReader next.
+
+	self assert: header equals: actualHeader.
+	self assert: line first asInteger > 100000000.
+	self assert: line second asInteger equals: 100 "size".
+	self assert: (line fourth asClassInEnvironment:Smalltalk globals) isClass.
+	self assert: line last equals: 'false'.
+
+	createdFile delete
+]

src/IllimaniProfiler-Tests/IllMockGCMonitor.class.st

@@ -0,0 +1,13 @@
+Class {
+	#name : 'IllMockGCMonitor',
+	#superclass : 'Object',
+	#instVars : [
+		'allocations'
+	],
+	#category : 'IllimaniProfiler-Tests',
+	#package : 'IllimaniProfiler-Tests'
+}
+
+{ #category : 'exporting' }
+IllMockGCMonitor >> exportData: baseFileName [
+]

src/IllimaniProfiler-Tests/IllMockProfiler.class.st

@@ -0,0 +1,64 @@
+Class {
+	#name : 'IllMockProfiler',
+	#superclass : 'Object',
+	#instVars : [
+		'allocations',
+		'gcMonitor'
+	],
+	#category : 'IllimaniProfiler-Tests',
+	#package : 'IllimaniProfiler-Tests'
+}
+
+{ #category : 'accessing' }
+IllMockProfiler >> gcActivityMonitor [
+
+	^ gcMonitor
+]
+
+{ #category : 'as yet unclassified' }
+IllMockProfiler >> gcMonitor: anIllMockGCMonitor [
+
+	gcMonitor := anIllMockGCMonitor
+]
+
+{ #category : 'accessing' }
+IllMockProfiler >> objectAllocations [
+
+	^ allocations
+]
+
+{ #category : 'accessing' }
+IllMockProfiler >> objectAllocations: aCollection [
+
+	allocations := aCollection
+]
+
+{ #category : 'accessing' }
+IllMockProfiler >> profiledCode [
+
+	^ 'TestProfiler testTheProfiler'
+]
+
+{ #category : 'accessing' }
+IllMockProfiler >> samplingRate [
+
+	^ 100
+]
+
+{ #category : 'accessing' }
+IllMockProfiler >> totalFullGCs [
+
+	^ 2
+]
+
+{ #category : 'accessing' }
+IllMockProfiler >> totalScavenges [
+
+	^ 156
+]
+
+{ #category : 'accessing' }
+IllMockProfiler >> totalTime [
+
+	^ 2000000 "2 microseconds"
+]

src/IllimaniProfiler/IllEphemeron.class.st

@@ -138,10 +138,7 @@ IllEphemeron >> mourn [
 	key := nil.
 
 	finalizationTime := Time primUTCMicrosecondsClock.
-	"When the vm calls the method mourn, it is right before of the collection of the object.
-	So we need to add 1 to the counter of scavenges."
-	survivedScavenges := Smalltalk vm incrementalGCCount - survivedScavenges + 1.
-	survivedFullGC := Smalltalk vm fullGCCount - survivedFullGC
+	self updateStatistics
 ]
 
 { #category : 'printing' }
@@ -175,3 +172,12 @@ IllEphemeron >> survivedScavenges [
 
 	^ survivedScavenges
 ]
+
+{ #category : 'finalization' }
+IllEphemeron >> updateStatistics [
+	"When the vm calls the method mourn, it is right before of the collection of the object.
+	So we need to add 1 to the counter of scavenges."
+
+	survivedScavenges := Smalltalk vm incrementalGCCount - survivedScavenges + 1.
+	survivedFullGC := Smalltalk vm fullGCCount - survivedFullGC
+]

src/IllimaniProfiler/IllFinalizationExporter.class.st

@@ -18,5 +18,5 @@ IllFinalizationExporter class >> on: aProfiler [
 IllFinalizationExporter >> headerOfAllocationModel [ 
 
 	^ #( #finalizationTimeInMicroSeconds #sizeInBytes #initializationTimeInMicroSeconds #allocatedObjectClass
-	     #survivedScavenges #survivedFullGC #forcedFinalization )
+	     #survivedScavenges #survivedFullGCs #forcedFinalization )
 ]