v5.0.1

What's Changed

• fix naked records by @tcarrondo in #29

Full Changelog: v5.0.0...v5.0.1

v5.0.0

What's Changed

• Upgrade cloudflare provider to version 5 by @tcarrondo in #26

Full Changelog: v4.3.0...v5.0.0

Some help when upgrading from v4.x:

terraform state rm module.domain.cloudflare_record.domain_ipv4
terraform state rm module.domain.cloudflare_record.domain_www
terraform state rm module.domain.cloudflare_record.records
terraform state rm module.domain.cloudflare_zone_settings_override.domain

and:

locals {
  zone_settings = {
    ssl                      = "full"
    always_use_https         = "on"
    automatic_https_rewrites = "on"
    cache_level              = "aggressive"
    development_mode         = "off"
  }
}

data "cloudflare_zone" "main" {
  filter = {
    name = local.domain
  }
}

import {
  for_each = local.zone_settings
  id       = "${data.cloudflare_zone.main.zone_id}/${each.key}"
  to       = module.domain.cloudflare_zone_setting.all[each.key]
}

data "cloudflare_dns_record" "ipv4" {
  zone_id = data.cloudflare_zone.main.zone_id
  filter = {
    name = {
      exact = local.domain
    }
    type = "A"
  }
}

import {
  id = "${data.cloudflare_zone.main.zone_id}/${data.cloudflare_dns_record.ipv4.dns_record_id}"
  to = module.domain.cloudflare_dns_record.domain_ipv4[0]
}

data "cloudflare_dns_record" "www" {
  zone_id = data.cloudflare_zone.main.zone_id
  filter = {
    name = {
      exact = "www.${local.domain}"
    }
    type = "CNAME"
  }
}

import {
  id = "${data.cloudflare_zone.main.zone_id}/${data.cloudflare_dns_record.www.dns_record_id}"
  to = module.domain.cloudflare_dns_record.domain_www[0]
}

locals {
  final_records = { for record in local.dns_records :
    "${record.name}_${record.type}" => record
  }
}

data "cloudflare_dns_record" "records" {
  for_each = local.final_records
  zone_id  = data.cloudflare_zone.main.zone_id
  filter = {
    name = {
      exact = "${each.value.name}.${data.cloudflare_zone.main.name}"
    }
    type = each.value.type
  }
}

import {
  for_each = local.final_records
  id       = "${data.cloudflare_zone.main.zone_id}/${data.cloudflare_dns_record.records[each.key].dns_record_id}"
  to       = module.domain.cloudflare_dns_record.records[each.key]
}

4.3.0

• Improve record management
• Bump to Cloudflare provider v4

4.1.0

Merge pull request #20 from tcarrondo/bump-to-cloudflare-v3.32

fix var type

Upgrade to terraform v1.0

• Upgrade to terraform v1.0
• Improve extra records management (breaking change)

Upgrade to terraform v0.13

This version is compatible with terraform v0.13

Zone id output

v2.2

fix output to zone_id

Add NS output

v2.1

Add NS output.

Upgrade to terraform 0.12

Upgrade to terraform 0.12

The basics

This is the starting point and already does a lot!