feat: add namespace highlights and tests

queries/highlights.scm

@@ -70,6 +70,41 @@
 (yield_expression "from" @keyword)
 (function_static_declaration "static" @keyword)
 
+; Namespace
+
+(namespace_definition
+  name: (namespace_name
+    (name) @module))
+
+(namespace_name
+  (name) @module)
+
+(namespace_use_clause
+  [
+    (name) @type
+    (qualified_name
+      (name) @type)
+    alias: (name) @type
+  ])
+
+(namespace_use_clause
+  type: "function"
+  [
+    (name) @function
+    (qualified_name
+      (name) @function)
+    alias: (name) @function
+  ])
+
+(namespace_use_clause
+  type: "const"
+  [
+    (name) @constant
+    (qualified_name
+      (name) @constant)
+    alias: (name) @constant
+  ])
+
 ; Variables
 
 (relative_scope) @variable.builtin

test/highlight/keywords.php

@@ -14,7 +14,39 @@
 // <- @keyword
 
 namespace A\B;
-// <- @keyword
+//^^^^^^^ @keyword
+//        ^ @module
+//          ^ @module
+
+use Foo\Baz as Baaz;
+//^ @keyword
+//  ^^^ @module
+//      ^^^ @type
+//          ^^ @keyword
+//             ^^^^ @type
+
+use function Foo\foo as fooo;
+//  ^^^^^^^^ @keyword
+//               ^^^ @function
+//                      ^^^^ @function
+
+use const Foo\FOO as FOOO;
+//  ^^^^^ @keyword
+//            ^^^ @constant
+//                   ^^^^ @constant
+
+use Foo\Baz\{
+//  ^^^ @module
+//      ^^^ @module
+  Bar,
+//^^^ @type
+  function foo,
+//^^^^^^^^ @keyword
+//         ^^^ @function
+  const FOO,
+//^^^^^ @keyword
+//      ^^^ @constant
+};
 
 if ($a and $b or $c xor $d) {} elseif ($b) {} else {}
 // <- @keyword

test/highlight/types.php

@@ -1,10 +1,11 @@
 <?php
 
-function b(int $a, string $b, Person $e): Dog {}
+function b(int $a, string $b, Person $e): Foo\Dog {}
 //         ^^^ @type.builtin
 //                 ^^^^^^ @type.builtin
 //                            ^^^^^^ @type
-//                                        ^^^ @type
+//                                        ^^^ @module
+//                                            ^^^ @type
 
 function a(array $b) {
 //         ^^^^^ @type.builtin