Implement and test an Identity earning power calculator

src/calculators/IdentityEarningPowerCalculator.sol

@@ -0,0 +1,40 @@
+// SPDX-License-Identifier: AGPL-3.0-only
+pragma solidity ^0.8.23;
+
+import {IEarningPowerCalculator} from "src/interfaces/IEarningPowerCalculator.sol";
+
+/// @title IdentityEarningPowerCalculator
+/// @author [ScopeLift](https://scopelift.co)
+/// @notice A simple earning power calculator that maps earning power directly to staked amount in
+/// a 1:1 ratio. This implementation is suitable when all stakers should earn rewards proportional
+/// to their stake without any adjustments or weights.
+///
+/// The calculator does not modify earning power based on the staker or delegatee, and is never
+/// qualified for bumping since the earning power calculation is a pure identity function of the
+/// staked amount.
+contract IdentityEarningPowerCalculator is IEarningPowerCalculator {
+  /// @notice Returns earning power equal to the staked amount.
+  /// @param _amountStaked The amount of tokens staked.
+  /// @return The earning power, equal to _amountStaked.
+  function getEarningPower(uint256 _amountStaked, address, /* _staker */ address /* _delegatee */ )
+    external
+    pure
+    returns (uint256)
+  {
+    return _amountStaked;
+  }
+
+  /// @notice Returns earning power equal to the staked amount and always indicates no
+  /// qualification for bumping.
+  /// @param _amountStaked The amount of tokens staked.
+  /// @return The earning power value, equal to _amountStaked.
+  /// @return Always false since this implementation never qualifies for bumping.
+  function getNewEarningPower(
+    uint256 _amountStaked,
+    address, /* _staker */
+    address, /* _delegatee */
+    uint256 /* _oldEarningPower */
+  ) external pure returns (uint256, bool) {
+    return (_amountStaked, false);
+  }
+}

test/BinaryEligibilityOracleEarningPowerCalculator.t.sol

@@ -5,7 +5,7 @@ import {Test, console2} from "forge-std/Test.sol";
 import {
   BinaryEligibilityOracleEarningPowerCalculator as EarningPowerCalculator,
   Ownable
-} from "src/BinaryEligibilityOracleEarningPowerCalculator.sol";
+} from "src/calculators/BinaryEligibilityOracleEarningPowerCalculator.sol";
 
 contract EarningPowerCalculatorTest is Test {
   address public owner;

test/IdentityEarningPowerCalculator.t.sol

@@ -0,0 +1,37 @@
+// SPDX-License-Identifier: AGPL-3.0-only
+pragma solidity ^0.8.23;
+
+import {Test} from "forge-std/Test.sol";
+import {IdentityEarningPowerCalculator} from "src/calculators/IdentityEarningPowerCalculator.sol";
+
+contract IdentityEarningPowerCalculatorTest is Test {
+  IdentityEarningPowerCalculator calculator;
+
+  function setUp() public {
+    calculator = new IdentityEarningPowerCalculator();
+  }
+}
+
+contract GetEarningPower is IdentityEarningPowerCalculatorTest {
+  function testFuzz_ReturnsAmountStaked(uint256 _amountStaked, address _staker, address _delegatee)
+    public
+    view
+  {
+    assertEq(calculator.getEarningPower(_amountStaked, _staker, _delegatee), _amountStaked);
+  }
+}
+
+contract GetNewEarningPower is IdentityEarningPowerCalculatorTest {
+  function testFuzz_ReturnsAmountStakedAndNeverQualifiesForBump(
+    uint256 _amountStaked,
+    address _staker,
+    address _delegatee,
+    uint256 _oldEarningPower
+  ) public view {
+    (uint256 _earningPower, bool _isQualifiedForUpdate) =
+      calculator.getNewEarningPower(_amountStaked, _staker, _delegatee, _oldEarningPower);
+
+    assertEq(_earningPower, _amountStaked);
+    assertEq(_isQualifiedForUpdate, false);
+  }
+}